From ba4c1875f8c9ddf19f301d06ec0b76f59ea23a2a Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 18 Oct 2025 07:04:23 +0000
Subject: Adding metadata

---
 dev-util/numdiff/numdiff-5.9.0-r1.ebuild | 44 ++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-util/numdiff/numdiff-5.9.0-r1.ebuild

(limited to 'dev-util/numdiff')

diff --git a/dev-util/numdiff/numdiff-5.9.0-r1.ebuild b/dev-util/numdiff/numdiff-5.9.0-r1.ebuild
new file mode 100644
index 000000000000..c4772c604487
--- /dev/null
+++ b/dev-util/numdiff/numdiff-5.9.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="File comparision, ignoring small numeric differences and formats"
+HOMEPAGE="https://www.nongnu.org/numdiff/"
+SRC_URI="https://savannah.nongnu.org/download/numdiff/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+nls +gmp"
+
+RDEPEND="
+	gmp? ( dev-libs/gmp:0= )
+	nls? ( sys-devel/gettext )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.9.0-fix-build-system.patch
+	"${FILESDIR}"/${PN}-5.9.0-fix-autoconf-2.71.patch
+)
+
+src_prepare() {
+	default
+	# yes, it really only needs eautoconf, due to the
+	# config.h being hand-written, which would be bulldozered
+	# when running eautoreconf (due to it invoking autoheader)
+	eautoconf
+}
+
+src_configure() {
+	local -x CONFIG_SHELL="${BROOT}/bin/bash"
+	econf \
+		--enable-optimization \
+		$(use_enable gmp) \
+		$(use_enable nls)
+
+	# make install also needs to use bash
+	sed -i "s#SHELL=/bin/sh#SHELL=${BROOT}/bin/bash#g" Makefile || die
+}
-- 
cgit v1.3