From 08bfa3f8ec685ab603d0c1995d79d00a1a0fbe1a Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Sat, 18 Jul 2026 03:04:45 -0500
Subject: Adding metadata

---
 dev-tex/pythontex/Manifest              |  1 +
 dev-tex/pythontex/pythontex-0.19.ebuild | 52 +++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 dev-tex/pythontex/pythontex-0.19.ebuild

(limited to 'dev-tex/pythontex')

diff --git a/dev-tex/pythontex/Manifest b/dev-tex/pythontex/Manifest
index 53f9d9407b5c..5f717cb4890b 100644
--- a/dev-tex/pythontex/Manifest
+++ b/dev-tex/pythontex/Manifest
@@ -1 +1,2 @@
 DIST pythontex-0.18_p20251112.tar.gz 1808282 BLAKE2B 25265a10716b3a409f8998b73e9011897932730d983796d98cb0c354fc432134a2f987f6c803ff389d43073de1022e7b812087e666d5ade51651c9f3aa474232 SHA512 e29082f885c2183b1243bf3d4525ab0bede4d14d80fc90df1f10fbbf29f0cfcdb4b03e8124209491a3bcfd5cf022abc81f6a573d818db0a4e187bb0b130c379b
+DIST pythontex-0.19.tar.gz 1818996 BLAKE2B a17d63b15e036f7abf5eefa368ceecd0c32e4468ba05f9c3b5be0e2c4e18364e68613679d327b77d458f1c813e2e7b686991dab9e97d340afc2a8c8f16369807 SHA512 e7e90de43fe3d405c78b01277429c465bf8496c563635f8d1d5f289d3d4a5b3a5a34ca4090a3d3b4a30b21f73fee5330f6380f6a228b4b7292deed4aa78bfe34
diff --git a/dev-tex/pythontex/pythontex-0.19.ebuild b/dev-tex/pythontex/pythontex-0.19.ebuild
new file mode 100644
index 000000000000..66934820df9f
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.19.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit latex-package python-r1
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LPPL-1.3 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+IUSE="doc highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-texlive/texlive-latexextra-2023
+	dev-tex/pgf
+"
+RDEPEND="${DEPEND}
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+}
+
+src_install() {
+	dodoc *rst
+	use doc && dodoc ${PN}_quickstart/*pdf ${PN}/*pdf
+
+	cd ${PN} || die
+
+	installation() {
+		python_domodule {de,}${PN}3.py
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall sty
+}
-- 
cgit v1.3