From ecdac123787b96ce6649f0f91da12ea6458cc2b1 Mon Sep 17 00:00:00 2001
From: Palica <palica+gitlab@liguros.net>
Date: Tue, 23 Jun 2020 22:35:08 +0200
Subject: Updating liguros repo

---
 dev-tex/pythontex/pythontex-0.17.ebuild | 50 +++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-tex/pythontex/pythontex-0.17.ebuild

(limited to 'dev-tex/pythontex/pythontex-0.17.ebuild')

diff --git a/dev-tex/pythontex/pythontex-0.17.ebuild b/dev-tex/pythontex/pythontex-0.17.ebuild
new file mode 100644
index 000000000000..31f770632569
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.17.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit latex-package python-r1
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/pythontex/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LPPL-1.3 BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-texlive/texlive-latexextra-2016
+	dev-tex/pgf"
+RDEPEND="${DEPEND}
+	dev-python/pygments[${PYTHON_USEDEP}]"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+}
+
+src_install() {
+	dodoc *rst
+	use doc && dodoc ${PN}_quickstart/*pdf ${PN}/*pdf
+
+	cd ${PN} || die
+
+	installation() {
+		python_domodule {de,}${PN}3.py
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall sty
+}
-- 
cgit v1.3.1