From d0b48a4e60d056bda9466abe69007fe01fc644a7 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 30 Oct 2024 07:38:24 +0000
Subject: Adding metadata

---
 dev-ruby/ruby-prof/ruby-prof-1.7.1.ebuild | 44 +++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-ruby/ruby-prof/ruby-prof-1.7.1.ebuild

(limited to 'dev-ruby/ruby-prof/ruby-prof-1.7.1.ebuild')

diff --git a/dev-ruby/ruby-prof/ruby-prof-1.7.1.ebuild b/dev-ruby/ruby-prof/ruby-prof-1.7.1.ebuild
new file mode 100644
index 000000000000..b98c8311d4e5
--- /dev/null
+++ b/dev-ruby/ruby-prof/ruby-prof-1.7.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_EXTRADOC="README.md CHANGES"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_GEMSPEC="ruby-prof.gemspec"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/ruby_prof/extconf.rb)
+RUBY_FAKEGEM_EXTENSION_LIBDIR="lib"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A module for profiling Ruby code"
+HOMEPAGE="https://github.com/ruby-prof/ruby-prof"
+SRC_URI="https://github.com/ruby-prof/${PN}/archive/${PV}.tar.gz -> ${P}.tgz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="test"
+
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 dev-ruby/minitest )"
+
+all_ruby_prepare() {
+	# Avoid bundler
+	sed -i -e '/bundler/I s:^:#:' -e '/:build/ s:^:#:' Rakefile || die
+
+	sed -i -e '2igem "test-unit"' -e '/bundler/ s:^:#:' test/test_helper.rb || die
+
+	# We install the shared object in lib, not ext.
+	sed -i -e 's#../ext/ruby_prof#../lib/ruby_prof#' lib/ruby-prof.rb || die
+
+	# Avoid unneeded dependency on rake-compiler
+	sed -i -e '/extensiontask/ s:^:#:' \
+		-e '/ExtensionTask/,/end/ s:^:#:' Rakefile || die
+
+	# Don't strip library by default
+	sed -i -e '/LDFLAGS/ s/-s//' ext/ruby_prof/extconf.rb || die
+}
-- 
cgit v1.3.1