From e83e26c4679923fac83dcd649f7d088e866bb477 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Thu, 12 Nov 2020 05:42:32 +0000
Subject: Updating liguros repo

---
 dev-python/bottle/Manifest                         |  1 +
 dev-python/bottle/bottle-0.12.19.ebuild            | 48 +++++++++++++++
 dev-python/cliff/Manifest                          |  1 +
 dev-python/cliff/cliff-3.5.0.ebuild                | 41 +++++++++++++
 dev-python/genson/genson-1.1.0.ebuild              |  2 +
 dev-python/numpy/numpy-1.19.2.ebuild               |  2 +-
 dev-python/pipenv/Manifest                         |  1 +
 dev-python/pipenv/pipenv-2020.11.4.ebuild          | 52 ++++++++++++++++
 .../pytest-asyncio/pytest-asyncio-0.14.0.ebuild    |  2 +-
 dev-python/requests/Manifest                       |  1 +
 dev-python/requests/requests-2.25.0.ebuild         | 56 ++++++++++++++++++
 .../uncertainties/uncertainties-3.1.4-r1.ebuild    | 37 ++++++++++++
 .../uncertainties/uncertainties-3.1.4.ebuild       | 40 -------------
 dev-python/urllib3/Manifest                        |  1 +
 dev-python/urllib3/urllib3-1.26.1.ebuild           | 69 ++++++++++++++++++++++
 15 files changed, 312 insertions(+), 42 deletions(-)
 create mode 100644 dev-python/bottle/bottle-0.12.19.ebuild
 create mode 100644 dev-python/cliff/cliff-3.5.0.ebuild
 create mode 100644 dev-python/pipenv/pipenv-2020.11.4.ebuild
 create mode 100644 dev-python/requests/requests-2.25.0.ebuild
 create mode 100644 dev-python/uncertainties/uncertainties-3.1.4-r1.ebuild
 delete mode 100644 dev-python/uncertainties/uncertainties-3.1.4.ebuild
 create mode 100644 dev-python/urllib3/urllib3-1.26.1.ebuild

(limited to 'dev-python')

diff --git a/dev-python/bottle/Manifest b/dev-python/bottle/Manifest
index f8636ed54391..b40f921fa196 100644
--- a/dev-python/bottle/Manifest
+++ b/dev-python/bottle/Manifest
@@ -1 +1,2 @@
 DIST bottle-0.12.18.tar.gz 71557 BLAKE2B a34cc1ab9a2a8505b7fda8bbddbae30b4e6c4829cae53f0f886237a21fdfa7f2b2463b216d7a16464539f41bdce4c1dabb5cc66027b8fdd19b10e9a78a3cdbb5 SHA512 db8a341cd80d755205518bb9eac5b79dca9e541ab3ad9d9d57f891d895f7df75a8facd16b068cbdf7c4f884f35e384449f4cbd565a43e9c5d000d3a9f5b7dcb0
+DIST bottle-0.12.19.tar.gz 73142 BLAKE2B e59d7a507d3401869ba4953a48274062fc56226afa2f7aad596b4ef4352e4a79cea2d224dfe32d7ce014e4f4a3ba088d0e7a0886f64a84bb6b78571e953fa3c3 SHA512 e5d2f6a32d1b89ae3cc9607456c0614db2b58882c6d36273d695c51d3d77b1858cac4d914dbf19bca3b74be68c197aa6473f162e40d9b7ae2af3a084a28c2637
diff --git a/dev-python/bottle/bottle-0.12.19.ebuild b/dev-python/bottle/bottle-0.12.19.ebuild
new file mode 100644
index 000000000000..4f9d79ca9b22
--- /dev/null
+++ b/dev-python/bottle/bottle-0.12.19.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A fast and simple micro-framework for small web-applications"
+HOMEPAGE="https://pypi.org/project/bottle/ https://bottlepy.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/mako[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.12.8-py3.5-backport.patch
+)
+
+python_prepare_all() {
+	sed -i -e '/scripts/d' setup.py || die
+
+	# Remove test file requring connection to network
+	rm test/test_server.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# A few odd fails in the suite under pypy
+	# https://github.com/bottlepy/bottle/issues/714
+	"${EPYTHON}" test/testall.py || die "tests failed under ${EPYTHON}"
+}
+
+pkg_postinst() {
+	optfeature "Templating support" dev-python/mako
+	elog "Due to problems with bottle.py being in /usr/bin (see bug #474874)"
+	elog "we do as most other distros and do not install the script anymore."
+	elog "If you do want/have to call it directly rather than through your app,"
+	elog "please use the following instead:"
+	elog '  `python -m bottle`'
+}
diff --git a/dev-python/cliff/Manifest b/dev-python/cliff/Manifest
index 2d357f1db111..6a03bc74cc1f 100644
--- a/dev-python/cliff/Manifest
+++ b/dev-python/cliff/Manifest
@@ -1 +1,2 @@
 DIST cliff-3.4.0.tar.gz 78990 BLAKE2B d7d8209e2fe24614cde6d3e113eb0dbbba981addef045fe318143e71f9a240188c0fb74e831d868b31b6dafb4289f7beabfbb5fe1dade1df196f670c53a55549 SHA512 d625588f4eed0aeee549b4a21e604f1cb886b8c10a12df7c546a5292223ec5bf9067352b4d326d5710673dab56eec47e2fb46c9c5d5df6e9fbf026d030bcde1c
+DIST cliff-3.5.0.tar.gz 82997 BLAKE2B f169770a0a956e6091e56eccda8d10906bee09bdb03b474f3b17837b3eda858f3afd21beae1d6945bcdabfa89fc1555d13d70ddd0454a10fe05bfb63c8de75e7 SHA512 215f22e5dd2c4c17bd0f19866189b6b247377a7d5bddeb4a07b7536af7545bd0440b5fb0a98474fc018e3b12f6695f60028c012f3e7eeb6498b20f2923939d08
diff --git a/dev-python/cliff/cliff-3.5.0.ebuild b/dev-python/cliff/cliff-3.5.0.ebuild
new file mode 100644
index 000000000000..5ffb0ffdc9a1
--- /dev/null
+++ b/dev-python/cliff/cliff-3.5.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+# TODO: revert to rdepend once this is merged
+# https://github.com/openstack/cliff/pull/3
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Command Line Interface Formulation Framework"
+HOMEPAGE="https://github.com/openstack/cliff"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~mips ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/cmd2-0.8.0[${PYTHON_USEDEP}]
+	<dev-python/prettytable-0.8[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/genson/genson-1.1.0.ebuild b/dev-python/genson/genson-1.1.0.ebuild
index ae95f6c737a2..528882179571 100644
--- a/dev-python/genson/genson-1.1.0.ebuild
+++ b/dev-python/genson/genson-1.1.0.ebuild
@@ -5,6 +5,8 @@ EAPI=7
 
 PYTHON_COMPAT=( python3_{5,6,7,8,9} )
 
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
 inherit distutils-r1
 
 DESCRIPTION="GenSON is a powerful, user-friendly JSON Schema generator built in Python"
diff --git a/dev-python/numpy/numpy-1.19.2.ebuild b/dev-python/numpy/numpy-1.19.2.ebuild
index ffdebcafcae5..93e962d37397 100644
--- a/dev-python/numpy/numpy-1.19.2.ebuild
+++ b/dev-python/numpy/numpy-1.19.2.ebuild
@@ -24,7 +24,7 @@ SRC_URI="
 	)"
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 arm arm64 hppa ~ia64 ~mips ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha ~amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
 IUSE="doc lapack"
 
 RDEPEND="
diff --git a/dev-python/pipenv/Manifest b/dev-python/pipenv/Manifest
index 0d32f4ddc0de..a5728565415c 100644
--- a/dev-python/pipenv/Manifest
+++ b/dev-python/pipenv/Manifest
@@ -1 +1,2 @@
+DIST pipenv-2020.11.4.tar.gz 11574683 BLAKE2B cb2ac4ba6b07377a3a5540b23756afac38a02691e495ba93031815417d001701b919221fd83d0f9e6b94d4f28c1fa754c2c31e289830305a8c8ac75d847209c4 SHA512 c9015eb9a449fa517f31619d1fec5d99882da915a50e189ba6ab9c7c147862f9734f0df200330d666380afe5d2cf52d18015c539635ca6459042ab50d3ccd059
 DIST pipenv-2020.8.13.tar.gz 11573493 BLAKE2B ac6c6f0336f0c675f73fbecfdefe158eb2a53b5aa4559850b3c9a050404d9d18b0ff2ca3cb62031da027937244a6bbb0d4c1ec433073e429518ec0ea908cb12e SHA512 90ccaf386bc68d856ee9c645084cb65c4213902a8c87e2059cc2274b88d922c3b02c58c15d05945e1f61e8b816ef92a11672cadaf125143bd5019ab25ff0b19e
diff --git a/dev-python/pipenv/pipenv-2020.11.4.ebuild b/dev-python/pipenv/pipenv-2020.11.4.ebuild
new file mode 100644
index 000000000000..23aa8e7e8a76
--- /dev/null
+++ b/dev-python/pipenv/pipenv-2020.11.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+MY_PV=${PV/_beta/b}
+DESCRIPTION="Python Development Workflow for Humans"
+HOMEPAGE="https://github.com/pypa/pipenv https://pypi.org/project/pipenv/"
+SRC_URI="https://github.com/pypa/pipenv/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${MY_PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.0.35[${PYTHON_USEDEP}]
+	dev-python/virtualenv-clone[${PYTHON_USEDEP}]
+	"
+
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		<dev-python/pytest-5[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)"
+
+src_prepare() {
+	# remove vendored version of PyYAML that is backported to Python2
+	# this should be removed when upstream removes support for Python2
+	rm -vR "${S}/${PN}/patched/yaml2/" || die
+	# disable running of unittests in parallel with xdist
+	sed -i 's/addopts = -ra -n auto/;&/g' setup.cfg || die
+	sed -i 's/plugins = xdist/;&/g' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vvv -x -m "not cli and not needs_internet" tests/unit/ || die
+}
diff --git a/dev-python/pytest-asyncio/pytest-asyncio-0.14.0.ebuild b/dev-python/pytest-asyncio/pytest-asyncio-0.14.0.ebuild
index 2e7aeab78e68..9467dac8fac6 100644
--- a/dev-python/pytest-asyncio/pytest-asyncio-0.14.0.ebuild
+++ b/dev-python/pytest-asyncio/pytest-asyncio-0.14.0.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://github.com/pytest-dev/pytest-asyncio/archive/v${PV}.tar.gz -> $
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 x86"
+KEYWORDS="amd64 arm arm64 ~ia64 ~ppc ~ppc64 x86"
 
 RDEPEND="
 	>=dev-python/pytest-5.4.0"
diff --git a/dev-python/requests/Manifest b/dev-python/requests/Manifest
index e8ddf9c68fe5..1466b6610d0b 100644
--- a/dev-python/requests/Manifest
+++ b/dev-python/requests/Manifest
@@ -1 +1,2 @@
 DIST requests-2.24.0.tar.gz 115071 BLAKE2B ae98be1d023b2a7b883e15a7a5d214ecbf482234e9de6bfc9cd06d1f04d1b57d101d41a2c6fdd07b7a6b468875463514841d2e023391ac8ae0797a2cb58b3424 SHA512 46ca8ab70eb39be8398c242404b9b3ffb6baddd5c78eaad125b55c719154eb8c7b6a737a8dc587b0cb51b3b9a074abaa8b2ff347a64d38f4f90cdba4db16a119
+DIST requests-2.25.0.tar.gz 101897 BLAKE2B 5de8f4f5059915f929ebb71d8209bfefbe95bb381544ed0b6875cc01cb958e6fe8861cd8321143463da5dd872ad4ff8c828008bcd6409b41857c4d2037db3f67 SHA512 dd13ccb6bcd95bdd31a414dba67e5a0914ff172ae6f5d255849837e8e2a7e404e3c02fc3d07e5ff6dc81c12d0fe56c3b83bc62bc377dd3f504b00b97b144db74
diff --git a/dev-python/requests/requests-2.25.0.ebuild b/dev-python/requests/requests-2.25.0.ebuild
new file mode 100644
index 000000000000..1439bf38165c
--- /dev/null
+++ b/dev-python/requests/requests-2.25.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library for human beings"
+HOMEPAGE="https://requests.readthedocs.io/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="socks5 +ssl"
+
+RDEPEND="
+	>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
+	>=dev-python/chardet-3.0.2[${PYTHON_USEDEP}]
+	<dev-python/chardet-4[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	<dev-python/idna-3[${PYTHON_USEDEP}]
+	<dev-python/urllib3-1.27[${PYTHON_USEDEP}]
+	socks5? ( >=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}] )
+	ssl? (
+		>=dev-python/cryptography-1.3.4[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip tests that require some kind of network
+	sed -e 's:test_connect_timeout:_&:' \
+		-e 's:test_total_timeout_connect:_&:' \
+		-i tests/test_requests.py || die
+	# probably pyopenssl version dependent
+	sed -e 's:test_https_warnings:_&:' \
+		-i tests/test_requests.py || die
+	# doctests rely on networking
+	sed -e 's:--doctest-modules::' \
+		-i pytest.ini || die
+}
diff --git a/dev-python/uncertainties/uncertainties-3.1.4-r1.ebuild b/dev-python/uncertainties/uncertainties-3.1.4-r1.ebuild
new file mode 100644
index 000000000000..1114d2265114
--- /dev/null
+++ b/dev-python/uncertainties/uncertainties-3.1.4-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python module for calculations with uncertainties"
+HOMEPAGE="https://pythonhosted.org/uncertainties/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests nose
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( build/sphinx/html/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/uncertainties/uncertainties-3.1.4.ebuild b/dev-python/uncertainties/uncertainties-3.1.4.ebuild
deleted file mode 100644
index 0d9e6d8b7fee..000000000000
--- a/dev-python/uncertainties/uncertainties-3.1.4.ebuild
+++ /dev/null
@@ -1,40 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python3_{5,6,7,8,9} )
-
-inherit distutils-r1
-
-DESCRIPTION="Python module for calculations with uncertainties"
-HOMEPAGE="https://pythonhosted.org/uncertainties/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc"
-
-RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
-"
-
-distutils_enable_tests nose
-
-ppython_compile_all() {
-	if use doc; then
-		PYTHONPATH="${BUILD_DIR}"/lib esetup.py build_sphinx
-	fi
-}
-
-python_compile_all() {
-	use doc && "${PYTHON}" setup.py build_sphinx
-}
-
-python_install_all() {
-	use doc && local HTML_DOCS=( build/sphinx/html/. )
-	distutils-r1_python_install_all
-}
diff --git a/dev-python/urllib3/Manifest b/dev-python/urllib3/Manifest
index 585f9b56c642..5f08aba1e331 100644
--- a/dev-python/urllib3/Manifest
+++ b/dev-python/urllib3/Manifest
@@ -2,3 +2,4 @@ DIST urllib3-1.24.2.tar.gz 230699 BLAKE2B 9c2f2be8fa743f542493d75072c02423d1bd40
 DIST urllib3-1.25.10.tar.gz 256875 BLAKE2B 3f2ad2cb3ac9a09f73c1ec03e89aa7313055afa443c53ec82fd9227348859566e20ca33b803972134be24eeed070c63b98e6ae75efde4006e2a4bb7b4cf3f054 SHA512 5718dab472a476bfd555753758ceef46c81dc358131205b6db05d186a66f397dc07252eda1622d12586390ccf14e8e17acdb9486c17cb7d34e323287a67373af
 DIST urllib3-1.25.11.tar.gz 260300 BLAKE2B 06bd2107bad479e36c6474f95567c3ecb119d18b193b358df9e345e4d09392366255b21597b26fbf2374220b921cc2117a1972f88021c3a6ebac3844a319acbe SHA512 58f77edb9ced62cbac7b0baf2651c07f9f413267f103730ee25f08c5d4d0bf52a2ace02f58841bcd55652db677c7a1dc9a756681e7e32d590bc69d8b93e8f173
 DIST urllib3-1.26.0.tar.gz 291709 BLAKE2B e750bcd28c6205cb8e7f12c2a1c6123d48979877b206914fc122f67ff6cdf3e16e5d7ee0ffae1f4af40f028075f9592cdebf8856ca7e29b541283a8023afbf0d SHA512 5e5a78486cded9a378532a094818cfcaf6ec621d3aefbffac4c78f130798ee06f08e47d14f3d154274a502c8c1e3963a12d65030ba6109108ed786202637bd42
+DIST urllib3-1.26.1.tar.gz 286708 BLAKE2B 19f210a56850e9754faa7a7a309292ba69450ba3ca232bc42f10e1f163eb72e7430eb233d8a0ee1cf97acbdfa132b2e515561e67fade3806347e04e6c7869db2 SHA512 5fbb28e190ecf58aae0932994bc1adb1542041bf96f176a9ece22bd6ee8d4ae8dc8f40dea77359601b704025e65c65ca27137f65d3d47fac3fc796b7bbd112f3
diff --git a/dev-python/urllib3/urllib3-1.26.1.ebuild b/dev-python/urllib3/urllib3-1.26.1.ebuild
new file mode 100644
index 000000000000..2e845200e543
--- /dev/null
+++ b/dev-python/urllib3/urllib3-1.26.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
+HOMEPAGE="https://github.com/urllib3/urllib3"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="brotli test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/PySocks-1.5.8[${PYTHON_USEDEP}]
+	<dev-python/PySocks-2.0[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.0.0[${PYTHON_USEDEP}]
+	brotli? ( dev-python/brotlipy[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep "
+			${RDEPEND}
+			dev-python/brotlipy[\${PYTHON_USEDEP}]
+			dev-python/mock[\${PYTHON_USEDEP}]
+			dev-python/pytest[\${PYTHON_USEDEP}]
+			dev-python/pytest-freezegun[\${PYTHON_USEDEP}]
+			>=dev-python/trustme-0.5.3[\${PYTHON_USEDEP}]
+			>=www-servers/tornado-4.2.1[\${PYTHON_USEDEP}]
+		" python3_{6,7,8,9})
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/alabaster \
+	dev-python/mock
+
+python_prepare_all() {
+	# https://github.com/urllib3/urllib3/issues/1756
+	sed -e 's:10.255.255.1:240.0.0.0:' \
+		-i test/__init__.py || die
+	# tests failing if 'localhost.' cannot be resolved
+	sed -e 's:test_dotted_fqdn:_&:' \
+		-i test/with_dummyserver/test_https.py || die
+	sed -e 's:test_request_host_header_ignores_fqdn_dot:_&:' \
+		-i test/with_dummyserver/test_socketlevel.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x CI=1
+	# FIXME: get tornado ported
+	case ${EPYTHON} in
+		python3*)
+			pytest -vv || die "Tests fail with ${EPYTHON}"
+			;;
+	esac
+}
-- 
cgit v1.3.1