From d998aafe76f70eb2c8a06b5dd6cd9f356f014839 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Mon, 25 Sep 2023 06:30:51 +0000
Subject: Adding metadata

---
 dev-python/elasticsearch/Manifest                  |  1 +
 .../elasticsearch/elasticsearch-8.10.0.ebuild      | 66 ++++++++++++++++
 dev-python/hypothesis/Manifest                     |  1 +
 dev-python/hypothesis/hypothesis-6.87.0.ebuild     | 91 ++++++++++++++++++++++
 dev-python/pkgcraft/Manifest                       |  1 -
 dev-python/pkgcraft/pkgcraft-0.0.5.ebuild          | 78 -------------------
 dev-python/pygit2/Manifest                         |  1 +
 dev-python/pygit2/pygit2-1.13.1.ebuild             | 45 +++++++++++
 dev-python/pypdf/Manifest                          |  1 +
 dev-python/pypdf/pypdf-3.16.2.ebuild               | 56 +++++++++++++
 dev-python/python-utils/Manifest                   |  1 +
 dev-python/python-utils/python-utils-3.8.0.ebuild  | 42 ++++++++++
 dev-python/rapidfuzz/Manifest                      |  1 +
 dev-python/rapidfuzz/rapidfuzz-3.3.1.ebuild        | 50 ++++++++++++
 dev-python/xlsxwriter/Manifest                     |  1 +
 dev-python/xlsxwriter/xlsxwriter-3.1.5.ebuild      | 28 +++++++
 16 files changed, 385 insertions(+), 79 deletions(-)
 create mode 100644 dev-python/elasticsearch/elasticsearch-8.10.0.ebuild
 create mode 100644 dev-python/hypothesis/hypothesis-6.87.0.ebuild
 delete mode 100644 dev-python/pkgcraft/pkgcraft-0.0.5.ebuild
 create mode 100644 dev-python/pygit2/pygit2-1.13.1.ebuild
 create mode 100644 dev-python/pypdf/pypdf-3.16.2.ebuild
 create mode 100644 dev-python/python-utils/python-utils-3.8.0.ebuild
 create mode 100644 dev-python/rapidfuzz/rapidfuzz-3.3.1.ebuild
 create mode 100644 dev-python/xlsxwriter/xlsxwriter-3.1.5.ebuild

(limited to 'dev-python')

diff --git a/dev-python/elasticsearch/Manifest b/dev-python/elasticsearch/Manifest
index fde8b1059be9..b6740542793f 100644
--- a/dev-python/elasticsearch/Manifest
+++ b/dev-python/elasticsearch/Manifest
@@ -1,2 +1,3 @@
+DIST elasticsearch-py-8.10.0.gh.tar.gz 896444 BLAKE2B 7cadd9d23e31b42ba309345f228193a856ceac0c6b64786ae84668ff361f750d0413609b753b6faa113835eddb6b212b79bee0ee6e25025f2829b92b9109701d SHA512 2e72b726447f4fe139a7b1bb1a95e0eca613f53bb0c6d758b646203676835b56fedff418feca386d1300f8eb6ac2f14a5a99d7d7716bad286641ab43c9abcbc4
 DIST elasticsearch-py-8.8.2.gh.tar.gz 527409 BLAKE2B e7768150e22995b4ae4a5b0898a252c46e90b224e8c4132a7035d726db9367facfe2cd006c0d319454c61c075d180776f567e45791d731bf1fc1d40a78d284a2 SHA512 5e5610425fe3727b817fbeafb411fa3e455a1f08c4992774c95c93c5b0d01880198d39febb18baee7a1da85bd126d9679fb6a2aac4602df8ec49cfff0b5bd3be
 DIST elasticsearch-py-8.9.0.gh.tar.gz 881506 BLAKE2B 7e6813ff5d5f5f90e67f479258506736a07fac45529f3e957a10cec8251a923afaf3ce4a88f34be8c1dccc4d2df95f87e2b97e05c296bf530f169bd6756b0779 SHA512 b8054edd2bb7577601b2dfe423ff5b191d59abcc1e8aaba86af18be3215548b2d540bb398b5ad83955da99c35995c4ba2755c9da3823fab1fffb0e7a01633f32
diff --git a/dev-python/elasticsearch/elasticsearch-8.10.0.ebuild b/dev-python/elasticsearch/elasticsearch-8.10.0.ebuild
new file mode 100644
index 000000000000..d9b9528748a1
--- /dev/null
+++ b/dev-python/elasticsearch/elasticsearch-8.10.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+inherit distutils-r1
+
+MY_P="elasticsearch-py-${PV}"
+
+DESCRIPTION="Official Elasticsearch client library for Python"
+HOMEPAGE="
+	https://ela.st/es-python
+	https://github.com/elastic/elasticsearch-py
+	https://pypi.org/project/elasticsearch/
+"
+SRC_URI="https://github.com/elastic/elasticsearch-py/archive/refs/tags/v${PV}.tar.gz -> ${MY_P}.gh.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/aiohttp-3[${PYTHON_USEDEP}] <dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	>=dev-python/elastic-transport-8[${PYTHON_USEDEP}] <dev-python/elastic-transport-9[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.4[${PYTHON_USEDEP}] <dev-python/requests-3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mapbox-vector-tile[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+		dev-python/unasync[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# REST api tests are a black hole for effort. It downloads the tests so its an ever moving target
+	# It also requires effort to blacklist tests for apis which are license restricted.
+	"test_elasticsearch/test_server/test_rest_api_spec.py"
+	# Counting deprecation warnings from python is bound to fail even if all are fixed in this package
+	# Not worth it
+	"test_elasticsearch/test_client/test_deprecated_options.py"
+	# Running daemon for tests is finicky and upstream CI fails at it as well
+	"test_elasticsearch/test_server/"
+	"test_elasticsearch/test_async/test_server/"
+)
+
+distutils_enable_sphinx docs/sphinx dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_prepare() {
+	# Replace added pytest options with setting asyncio_mode to auto.
+	# Test suite hasnt set asyncio parameters so its needed here.
+	sed -i '/[tool:pytest]/,/^$/ { s/addopts.*/asyncio_mode = auto/ }' setup.cfg || die
+
+	default
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index c25b9dc0a0ea..12f7970ae17a 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -3,3 +3,4 @@ DIST hypothesis-6.84.3.gh.tar.gz 9386113 BLAKE2B 9d990b1634e7cd12f933f3a53b4231f
 DIST hypothesis-6.85.1.gh.tar.gz 9387516 BLAKE2B 362dc9adff39e0229307ed4d8c63a2c78a2653d5b880a7748218bccb3a4f6e36c6a0e38d51aa72a5acfb8e66f9d1418dbf8d039b855a6596515257d815566cc8 SHA512 4916575f60b9472d58a02a776fdf7794ea83e9e59b414a05f5ed06aff31ed91719485ceddec8233125425393444f0487ab2a6adae7c9cd6d3448460c20d3c556
 DIST hypothesis-6.86.1.gh.tar.gz 9388105 BLAKE2B 92a645c1e2f0d40bb96271b9539f415d5bdf8a57c50d658a8d041802cc3adc49708c420127bf0ae0daca1480c975766b5c4b1d4a07b18c020a608ea577e1894f SHA512 133adced2ef15f64aca404384ac372d36dec4a28b8b768631b09de6698fb718bd27c062546f0fe8b428510c51014ff124d4469e1b904aedc2fdd84183cee48bf
 DIST hypothesis-6.86.2.gh.tar.gz 9388171 BLAKE2B 7f6ba341c96e9ad2c6a05c777cd94d5437b24a66f571e690701501ce13bce7a448afdad0964f6ba0c34d3a4e1f52cbbc0f23709e4a15750c0f13b81d25ae2810 SHA512 6d858e9722014ae136a13bf93f1f4bd55b7eef7ae9f25dbb90abe1e5dab4422aa2987ed01f852d74ba8332af2cfc99b7f938f9a934604fea74e51f5dd4d52f9c
+DIST hypothesis-6.87.0.gh.tar.gz 9388325 BLAKE2B 5774e125a212a3ec4b64e9575db727c6338f931a2b065dce4f8c2bf9e7fa7026c4ed1dc11b4030af7f012064fbeae7240086eda2b0862b41d2ee37ae8540c03a SHA512 2f11d3bfff9c6f6322e368b40987d5379d0aeb619c5017a746ac935e43f50381d4ad8e180765cfddf5196a4f0f69f89df48cc9069e9d3f79446e5d396c673a3b
diff --git a/dev-python/hypothesis/hypothesis-6.87.0.ebuild b/dev-python/hypothesis/hypothesis-6.87.0.ebuild
new file mode 100644
index 000000000000..4c56e9453286
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.87.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" --dist=worksteal \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/pkgcraft/Manifest b/dev-python/pkgcraft/Manifest
index a9eb28b65b2d..895bd3cece3e 100644
--- a/dev-python/pkgcraft/Manifest
+++ b/dev-python/pkgcraft/Manifest
@@ -1,2 +1 @@
-DIST pkgcraft-0.0.5.tar.gz 400237 BLAKE2B de78c1570ce8080742d3afbff2c9078b56fb14e7b097bd09b47c5b21a5de1062989835c9c12e4efd9d4be4aef7e9dec1350606700d80c5482cf81d1d2c4febc0 SHA512 2366180189314cafa4be8a180eed62a8c994bfd862ebc5292e01d9cd2585b9eca082535e405924ad758d6f89309c5e64727242a52f95f6e71aa6aff3495edd57
 DIST pkgcraft-0.0.6.tar.gz 406538 BLAKE2B 5c90b57cb11e9f754cd695989994b3a9be52007482981c997f2e361fbbb72aeb0810d7f41dea1cdcd74c47840bb1c3b2cf225c967ba76b01769da93f909d9911 SHA512 ddd7bf77a3509156e8c16e5aeeb94a5f4530d9d1a3e6617d3974adfae7b46f0b0d31f4828dbd70261b42c883e776bf7572ca2fe8e23c9216637d886b9d8811cc
diff --git a/dev-python/pkgcraft/pkgcraft-0.0.5.ebuild b/dev-python/pkgcraft/pkgcraft-0.0.5.ebuild
deleted file mode 100644
index 6d2f905ebaac..000000000000
--- a/dev-python/pkgcraft/pkgcraft-0.0.5.ebuild
+++ /dev/null
@@ -1,78 +0,0 @@
-# Copyright 2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11} )
-
-inherit distutils-r1
-
-DESCRIPTION="Python bindings for pkgcraft"
-HOMEPAGE="
-	https://pypi.org/project/pkgcraft/
-	https://github.com/pkgcraft/pkgcraft-python
-"
-
-if [[ ${PV} == 9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/pkgcraft/pkgcraft-python"
-	inherit git-r3
-
-	PKGCRAFT_VERSION_MAX="9999"
-	PKGCRAFT_VERSION_MIN="9999"
-else
-	SRC_URI="https://github.com/pkgcraft/pkgcraft-python/releases/download/v${PV}/${P/-python}.tar.gz"
-	S="${WORKDIR}"/${P/-python}
-
-	KEYWORDS="~amd64 ~arm64"
-
-	PKGCRAFT_VERSION_MAX="9999"
-	PKGCRAFT_VERSION_MIN="0.0.6"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="+examples"
-
-RDEPEND="
-	<sys-libs/pkgcraft-${PKGCRAFT_VERSION_MAX}
-	>=sys-libs/pkgcraft-${PKGCRAFT_VERSION_MIN}:=
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	dev-python/cython
-	dev-python/setuptools-scm
-	virtual/pkgconfig
-"
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	if [[ ${PV} != 9999 ]] ; then
-		local actual_pkgcraft_min=$(sed -En '/^MIN_VERSION =/{s/[^0-9.]//gp}' setup.py || die)
-		if [[ ${actual_pkgcraft_min} != ${PKGCRAFT_VERSION_MIN} ]] ; then
-			eerror "Expected minimum pkgcraft-c version: ${PKGCRAFT_VERSION_MIN}"
-			eerror "Actual minimum pkgcraft-c version: ${actual_pkgcraft_min}"
-			die "Mismatch between setup.py's MIN_VERSION and ebuild!"
-		fi
-	fi
-
-	distutils-r1_python_prepare_all
-}
-
-python_test() {
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest
-}
-
-python_install() {
-	# Conditional because these aren't installed officially right now
-	# and the naming is just for convenience.
-	if use examples ; then
-		while IFS= read -r -d '' file ; do
-			python_newexe "${S}"/examples/${file##*/} pkgcraft-${file##*/}
-		done < <(find "${S}"/examples -type f -executable -print0 || die)
-	fi
-
-	distutils-r1_python_install
-}
diff --git a/dev-python/pygit2/Manifest b/dev-python/pygit2/Manifest
index 78a29ff29419..aabf87015649 100644
--- a/dev-python/pygit2/Manifest
+++ b/dev-python/pygit2/Manifest
@@ -1 +1,2 @@
 DIST pygit2-1.12.2.tar.gz 738453 BLAKE2B 805472147021296b28f0d47f97e5b42355e2f8eb418cc48134a8c2a0c606e04bdf6ee9ddd5586949652b36d921631aaa16fb739d8491db01196c7ecb26f2ea13 SHA512 adf82f385b0cb8e239113171e7e4d75d4902828b18a04f2624c6931f7d11648ae0503d615ef5d89ddc477b94c5ac48354be223e2bde7d4c111a957e114b6a28d
+DIST pygit2-1.13.1.tar.gz 739041 BLAKE2B 37997247edcc8b4268ea8e0347be4673ccd1e12e0cf1c1be37849560f91335c39998d7c42b0fc9ca40c9b5cbf315154ee13a5e9453d266ebce1a6f6ebb80fed6 SHA512 632d60c1d0602b264504b0e99458c93f0f3699b5ebff34b70ea9381a4472fd938db426c04b6ec0b8b3e5c85aaede440ed28dda232b55954813fce099df6d94e8
diff --git a/dev-python/pygit2/pygit2-1.13.1.ebuild b/dev-python/pygit2/pygit2-1.13.1.ebuild
new file mode 100644
index 000000000000..449e40347d24
--- /dev/null
+++ b/dev-python/pygit2/pygit2-1.13.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings for libgit2"
+HOMEPAGE="
+	https://github.com/libgit2/pygit2/
+	https://pypi.org/project/pygit2/
+"
+
+LICENSE="GPL-2-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+DEPEND="
+	=dev-libs/libgit2-1.7*:=
+"
+BDEPEND="
+	>=dev-python/cffi-1.9.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	${BDEPEND}
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unconditionally prevent it from using network
+	sed -i -e '/has_network/s:True:False:' test/utils.py || die
+}
+
+src_test() {
+	rm -r pygit2 || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/pypdf/Manifest b/dev-python/pypdf/Manifest
index 64f7a46450e4..cbdcec91b17c 100644
--- a/dev-python/pypdf/Manifest
+++ b/dev-python/pypdf/Manifest
@@ -5,5 +5,6 @@ DIST pypdf-3.15.4.gh.tar.gz 7929672 BLAKE2B da8bbbe6f1df51be63d116789eb4626ab59e
 DIST pypdf-3.15.5.gh.tar.gz 7930893 BLAKE2B acdd6254c45e11631faccc4fd6029525d7cec52f7cf222d48f95a9bb736a83bdb9dfc6bf2830f55d0f881eb23ca0641c06fa97165c64789f7b152998febfe017 SHA512 173cfbfbbd5f2f08ebd03aa36750904d5a7ac328c27da1b38bda7b34586bf86eab391b3c1e9a6dd5f2e754d1871303afe151a80a3bb5d4ab867b6a019ecef054
 DIST pypdf-3.16.0.gh.tar.gz 7936276 BLAKE2B 9b20c57f3bd5ccce0bd5bf71c7e084117a37450ddd7e126b03d58920bfb5896151a3a42253a96cd2e316696a19fab4c1c1743988ba85585867dff45ae98c254a SHA512 23dbb67b1a4455326133f1621e763752994baba55cd85191bcb61691bfd43f2e29f7ee11eb5d65415897e7f7af3367d1dc830a0d0e2f6ff0e3103ccb3b60d0c7
 DIST pypdf-3.16.1.gh.tar.gz 7948024 BLAKE2B f35399af13418c4136d7f20763e875f5572759db0da25cada1bb076645db651a77c1e6cf244087cc2d3d6c9b786dfdbf887aa46ed8b48f9d0103618e60b0e8ad SHA512 d81b15c097c2eaa41ec421bc9fda47bd05f3cd3726834baff7024201c0a0f70d8cc5df5aae8471fe361be765b7874b4a93779eb3fdb1c266f8bdb4f1f3835ebd
+DIST pypdf-3.16.2.gh.tar.gz 7968803 BLAKE2B 7bca0cf5baefb79d9c3a76445fd5cf77478a2f076f5c3e6c891d9f107cbb2ee08535388ae1ba84b0aeaf63ebebfe54966603cbeb7a5a2c0b0327e7506893d893 SHA512 01dfdcf5038820dd0d922e57cfa3eae472a406eca4d24a46596028aa23d0bb88a805204faa3576e3ed4e49ba552619002b2be305498b31e9b96afa19a2575f7d
 DIST pypdf-sample-files-935652968f76a41b4fa51afd05498e7dd7314c5e.gh.tar.gz 11187445 BLAKE2B e9332009a49249fdaa8b6c29258b11dfcf3627a5550ea7402cf0288bb4b0537136b039e6f4aefb03574076d1fc0af6100effc0d36510f035d9e63836ad52c4d7 SHA512 8d525aa323e5b45f71130459faa9686ec4ae04bc594895a64f1a5b6d027f866c48aca78602ad526000a11b547cc77068d1ac5e733d3e3a99df0e257c02fbb9e7
 DIST pypdf-sample-files-b60ca63512466d1bafc587a2b223961b23a8e48a.gh.tar.gz 11199764 BLAKE2B e68bfb587c26a7a0ba9bb687e2b44d607cf890454dc2e5380db4037cb9a0be571e72b178d5ac86a0556f09fc344fc6ea76ee87bf9c6dee63799853acaba714b0 SHA512 20ff1d623a67fd0b08e1dfefc47d29ed28b5c62f1e0ef5a32699876e265541d97c10067ec954a387ba4952319d6903fb3d4db97e686200f9142329db06a11a7b
diff --git a/dev-python/pypdf/pypdf-3.16.2.ebuild b/dev-python/pypdf/pypdf-3.16.2.ebuild
new file mode 100644
index 000000000000..6c2aa83bb7b4
--- /dev/null
+++ b/dev-python/pypdf/pypdf-3.16.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=b60ca63512466d1bafc587a2b223961b23a8e48a
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/pypdf/
+	https://github.com/py-pdf/pypdf/
+"
+SRC_URI="
+	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# rely on -Werror
+	tests/test_utils.py::test_deprecate_no_replacement
+	tests/test_workflows.py::test_orientations
+	# TODO: requires fpdf
+	tests/test_page.py::test_compression
+)
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
+	fi
+}
+
+python_test() {
+	epytest -o addopts= -m "not enable_socket"
+}
diff --git a/dev-python/python-utils/Manifest b/dev-python/python-utils/Manifest
index e75b49b7473e..bda97de1e4c6 100644
--- a/dev-python/python-utils/Manifest
+++ b/dev-python/python-utils/Manifest
@@ -1 +1,2 @@
 DIST python-utils-3.7.0.tar.gz 29654 BLAKE2B ff306a2ee3e84585081f504ad50f117294698c75dd4d5015db6cf9326796d69aaf63365ac5bbedb3af4d41e4f18b7a05437860bf41cdb870e43f1ba75e92628c SHA512 df3b33dbf213c7099a5a17166ac1e01e9044bf6bb364de96a4b182831ff3216fe37edb7f94cb66f8d2fcab42cea404a9c4f27142890ae0e7510363815f47ad41
+DIST python-utils-3.8.0.tar.gz 30397 BLAKE2B 05fb02505b233bfc6e8128a59e076b6fd81ee90bf5eda5ccf6f5476cf2f1796381fe392e8bce6d2a074aae1408c7ab267f5aff746349215765542497c9ca3d4b SHA512 0fcb1358eb1659d500a10fd6a9e6339b2d006f50d1656e4fd20a65c993e194d30fe204434d94f53872364cd67c6dbf68c0ed30cb1063571a6b143f1145e71bff
diff --git a/dev-python/python-utils/python-utils-3.8.0.ebuild b/dev-python/python-utils/python-utils-3.8.0.ebuild
new file mode 100644
index 000000000000..2850b5219145
--- /dev/null
+++ b/dev-python/python-utils/python-utils-3.8.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of small Python functions & classes"
+HOMEPAGE="
+	https://github.com/WoLpH/python-utils/
+	https://pypi.org/project/python-utils/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	docs
+	_python_utils_tests/test_logger.py
+	python_utils/loguru.py
+)
+
+python_prepare_all() {
+	sed -i -e '/--cov/d' -e '/--mypy/d' pytest.ini || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/rapidfuzz/Manifest b/dev-python/rapidfuzz/Manifest
index a806e6c26ae8..9c7814d797b3 100644
--- a/dev-python/rapidfuzz/Manifest
+++ b/dev-python/rapidfuzz/Manifest
@@ -2,3 +2,4 @@ DIST rapidfuzz-3.1.1.tar.gz 1279245 BLAKE2B bd3fa008a29fa9d7c2af8708d498e1b6f449
 DIST rapidfuzz-3.1.2.tar.gz 1280133 BLAKE2B 5f1d3175bc5ded1900f31c73d0e9fdfd6035533abf3cc9a12be3ba41edd424cb816505d4f82ff2bb4f0a825c53259c3cf1af33cd6b6234680ab93fb5232c91a4 SHA512 462b7b029027a2677ff927285cf614a6b2a6690af622f093633eec1390f0399b70f4240461db493aa9b30a2043f91b44fbbfa8e4bfb65af953516168c2b31409
 DIST rapidfuzz-3.2.0.tar.gz 1472554 BLAKE2B 7946f6139aec1ca9ccc623750bd09601e04171f3030bb7cfeac5cedf9ec1a639c444e9fd3394efde199e447a6834dce46be20dfb8be33232a324e4dea23b9cf1 SHA512 0ea0ecc62e2493519a302edd090521ed7efeae35e73812aeadaca2e2369362b57b1a095a09296edfa8db07b6bf58de4451dc71e96e6c215ebbe96dc1f8e7e995
 DIST rapidfuzz-3.3.0.tar.gz 1507179 BLAKE2B 59f45a3a2551d4ccc1e3c077abbd2ce2e569be51dd72b0378a2744557d65588d9a98c53048471fe8f1b4600f3b997e26477d65bac983954ae9d8331aea4dc5c3 SHA512 ee3a362f7c9bf4c54cff93a8c3d830541f07ed67628469b1406261fca086bd15eb4a418ece56fa3e4f25e0c6b859080d19582f5eea90547541a39d35ec70ea19
+DIST rapidfuzz-3.3.1.tar.gz 1507246 BLAKE2B 66964d155d682704266a32ce6632d91db4c0fdcf82722c6d58e7c305b0c4a341890b3c57d9936cc0f019b4aa5658279fc6d2f8885c17096ed8cb1721e2c633d3 SHA512 13f32818bdf1e71a30610c252afa1685ad64b858bff5b4309b5dfeca5f281096fc9fcd0683ed543bca0cee00db96df1c4fb6e0b76408c3694b508a9735d6cffc
diff --git a/dev-python/rapidfuzz/rapidfuzz-3.3.1.ebuild b/dev-python/rapidfuzz/rapidfuzz-3.3.1.ebuild
new file mode 100644
index 000000000000..b784f0b3629e
--- /dev/null
+++ b/dev-python/rapidfuzz/rapidfuzz-3.3.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
+HOMEPAGE="
+	https://github.com/maxbachmann/RapidFuzz/
+	https://pypi.org/project/rapidfuzz/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# all these are header-only libraries
+DEPEND="
+	>=dev-cpp/taskflow-3.0.0
+	>=dev-cpp/rapidfuzz-cpp-2.0.0
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/rapidfuzz-capi[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+	# remove bundled libraries
+	rm -r extern || die
+
+	distutils-r1_src_prepare
+
+	# TODO: re-cythonnize when we can reliably dep on Cython >= 3
+	export RAPIDFUZZ_BUILD_EXTENSION=1
+}
diff --git a/dev-python/xlsxwriter/Manifest b/dev-python/xlsxwriter/Manifest
index daf18a26ed0e..75b7216b9338 100644
--- a/dev-python/xlsxwriter/Manifest
+++ b/dev-python/xlsxwriter/Manifest
@@ -1,3 +1,4 @@
 DIST XlsxWriter-RELEASE_3.1.2.gh.tar.gz 36697835 BLAKE2B 055d0ac2e70ce5f86167f630044136f984bf19b494cb2ea5d7b98ce2098942e4c89eb0c3c3a8eeb48b1a4dcff30b71d45c2f2528634ed2f652d27f358d4778f7 SHA512 05f70721e6c55d54acdc143681ec581d3bf16c5d07725790bc648c169507e3cd9bd600ac4fcb4ff03fa449a6efc469d0745b92fcdb89afbf27ee1e2998c09613
 DIST XlsxWriter-RELEASE_3.1.3.gh.tar.gz 37317330 BLAKE2B 08dd76cfb7bcb336d0fa64276d11d0cee90809169cf0597739a262b970cc82741ac56beb681e78e7f3d88bec65f4a5c4b7a368ea800aab8bcfc4814e5b679638 SHA512 673b51d7d25fae462fb0b40fbb131ffd32237ee0078d235cbe1bb2fb4cee67bf72955aa555e3f5950bee9be7d256dad9ddadba2df4f50dc774cf1fda7503f43c
 DIST XlsxWriter-RELEASE_3.1.4.gh.tar.gz 37324495 BLAKE2B ebedb84e46eb73e750b9442969c397bb9c77af807c1bd78fe956bf304ae942cb8575f8f410631c7ae542f9e16c1d5c76385ba232fec109bc5ccf59fd1843b2c3 SHA512 2faa7a9fc03a620c3a1f9230685b2bd09c5b282fb783d36a28de225b1d5e64663db32cd5da1a16ffe3cb4bc886f77b79eb7f13ce460c18f6e88667b9979e504e
+DIST XlsxWriter-RELEASE_3.1.5.gh.tar.gz 37348174 BLAKE2B ae86c45f63dabe7678a476fcc7aae60de36a0b4b1a422b83ecfb6143ab0b1563ee274ea715aca7147e1fa184a3311c9f7c92c3b7d3c01bf934d5772c635862e3 SHA512 c2da3a2dc52e7f9b887e71828452484edabd99e882a3cbeed9969e04fef538cac2b48042900e9ac4bf8e41ed21178aa498b3ebecd018d2bdd31cad29b81c040b
diff --git a/dev-python/xlsxwriter/xlsxwriter-3.1.5.ebuild b/dev-python/xlsxwriter/xlsxwriter-3.1.5.ebuild
new file mode 100644
index 000000000000..ebaeb3e4f89f
--- /dev/null
+++ b/dev-python/xlsxwriter/xlsxwriter-3.1.5.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+TAG=RELEASE_${PV}
+MY_P=XlsxWriter-${TAG}
+DESCRIPTION="Python module for creating Excel XLSX files"
+HOMEPAGE="
+	https://github.com/jmcnamara/XlsxWriter/
+	https://pypi.org/project/XlsxWriter/
+"
+SRC_URI="
+	https://github.com/jmcnamara/XlsxWriter/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+distutils_enable_tests pytest
-- 
cgit v1.3