From c2e5e4c19cba7486ac4ea1a9d39241aa825c501a Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Thu, 13 Apr 2023 17:15:39 +0000
Subject: Adding metadata

---
 dev-python/kombu/Manifest                          |  1 +
 dev-python/kombu/kombu-5.3.0_beta3.ebuild          | 93 ++++++++++++++++++++++
 dev-python/libvirt-python/Manifest                 |  2 +
 .../libvirt-python/libvirt-python-9.2.0.ebuild     | 56 +++++++++++++
 .../sphinx_celery/sphinx_celery-2.0.0-r2.ebuild    | 23 ++++++
 5 files changed, 175 insertions(+)
 create mode 100644 dev-python/kombu/kombu-5.3.0_beta3.ebuild
 create mode 100644 dev-python/libvirt-python/libvirt-python-9.2.0.ebuild
 create mode 100644 dev-python/sphinx_celery/sphinx_celery-2.0.0-r2.ebuild

(limited to 'dev-python')

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index ac09c93dc8b9..7f6c66b735ee 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.3.0b2.tar.gz 434341 BLAKE2B 6d5188f7682ccf2daa6ca4ed0fec7988cd4781954be0fdc847c18e47d5c425a657c3df0f5bda7999c764de293626e119a4645e92ff7bf23328f4fcb9d6f4cd4a SHA512 3000577cc3b2acfb378396640245f2bdf4c9e5e1d45252a27e4e168e22ff4070f480ad1fd70059b24cd710c452924bff1716f69bedcf020446f428f0967de832
+DIST kombu-5.3.0b3.tar.gz 436058 BLAKE2B d8470eea43a1d5f862d93e3b3608a3240b25cad6ccb342318a7bebda17e6ce818dce2889cb7af22fd77d2f6e69d1fdfa6926c77ba715c76dd40e973f3d9920dc SHA512 c330e1dd334810ed5fdeea234c49606aa8e43f84006703ff26d900f40ec7ce4920418bef3fd43abc8c792fb750499031191394475c45bfac50f7d29a6e30f5f8
diff --git a/dev-python/kombu/kombu-5.3.0_beta3.ebuild b/dev-python/kombu/kombu-5.3.0_beta3.ebuild
new file mode 100644
index 000000000000..e6b664fac46d
--- /dev/null
+++ b/dev-python/kombu/kombu-5.3.0_beta3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_celery
+
+EPYTEST_IGNORE=(
+	# Unpackaged azure-servicebus
+	t/unit/transport/test_azureservicebus.py
+	# Unpackaged librabbitmq
+	t/unit/transport/test_librabbitmq.py
+	# Unpackaged python-consul
+	t/unit/transport/test_consul.py
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	t/unit/transport/test_etcd.py
+)
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+	)
+	local EPYTEST_IGNORE=(
+		# obsolete Pyro4
+		t/unit/transport/test_pyro.py
+		# unpackaged azure
+		t/unit/transport/test_azurestoragequeues.py
+	)
+
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}
diff --git a/dev-python/libvirt-python/Manifest b/dev-python/libvirt-python/Manifest
index 455064094d44..68406eba26a6 100644
--- a/dev-python/libvirt-python/Manifest
+++ b/dev-python/libvirt-python/Manifest
@@ -4,3 +4,5 @@ DIST libvirt-python-8.8.0.tar.gz 236523 BLAKE2B 56504045d4c44c2419fb8f97b1c147f1
 DIST libvirt-python-8.8.0.tar.gz.asc 833 BLAKE2B 2769a404916227ce9d77ec0e76d2985b67f7e59e3f280486b59f9a9edb4fe5405ae22dd03c2d4c9f1c620a977eef90ec8fdc93d3891d8824021a226a0581cb9a SHA512 edeace09e2de739d318f63ac7b33f814ac3d2e4ad7a32164fb0691723b4872d64bc60d0f96baf1809158e76fd7dbbff75c6ee4e9112b1ba6c264287c36d691b4
 DIST libvirt-python-8.9.0.tar.gz 240769 BLAKE2B 992f02fe584f33ea5bd91a28338e281d49515bae392d5209e07a916b9449965c753b9a12b2f4d8433069efc1e3c5907a378e3e2d8ee1d55ab682a3e983b2eca3 SHA512 f13767528518189bb4a6094dc029f3dee16179a269b25f1224ba448569e3a2f8b036124711060d4dda8de0f7719474a700b616e1e8e8d29028d585c2a631aa32
 DIST libvirt-python-8.9.0.tar.gz.asc 833 BLAKE2B 690613f7f558155db56a5194042bdf49e004143b2066bcaccb48fc9082364a88b5f8d4112623095838a116817a55e34e8ca29e01221299efc396fb1501a060ae SHA512 a490284745c948d87f0239b70257b5cd66ae2515a4f3f33c05a2b3e1ccc28e2769c8c61d45e4f855b595a6d82b6d73e50bcd00a8bbfc7cb7fbe1a4969e48e17b
+DIST libvirt-python-9.2.0.tar.gz 243411 BLAKE2B 4478060de12fe78dc60505cbfdc9a38d398ea3860e9a1a146379695f6ed7ec21d8840b54e6a716b1177e422a934ec5dfd86365208147515f70bc02c605c32b8c SHA512 24abeb7ec27135c30cdf751476b091b89b3aa2e448f6fe57d29064e1465a49944b2c0bb19cb01ce4d728036c9387bb244594816a9853a00b1d43d89dd7f94cd5
+DIST libvirt-python-9.2.0.tar.gz.asc 833 BLAKE2B 8f09ba2399fa083d41c979354dd72ca0c44047f46c6117b08cf823d8fc7ba5a2bfa031e51855238865dc08eb77846362d200d362e8675049f32b635e40bb25cc SHA512 4cb0bffaaa95e93cff1dd2f35f0219bc97567e21e04778b6f5bd0b33aa3523cea43f5fd7d95da73ba82f695b2cab8c771a5adbd9511e8a6deeb13e7e80fe7aa2
diff --git a/dev-python/libvirt-python/libvirt-python-9.2.0.ebuild b/dev-python/libvirt-python/libvirt-python-9.2.0.ebuild
new file mode 100644
index 000000000000..8fe650b92dd5
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-9.2.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+MY_P="${P/_rc/-rc}"
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/libvirt.org.asc
+inherit distutils-r1 verify-sig
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt-python.git"
+	RDEPEND="app-emulation/libvirt:="
+else
+	SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz
+		verify-sig? ( https://libvirt.org/sources/python/${MY_P}.tar.gz.asc )"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	verify-sig? ( sec-keys/openpgp-keys-libvirt )
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/sphinx_celery/sphinx_celery-2.0.0-r2.ebuild b/dev-python/sphinx_celery/sphinx_celery-2.0.0-r2.ebuild
new file mode 100644
index 000000000000..ffb44a08d915
--- /dev/null
+++ b/dev-python/sphinx_celery/sphinx_celery-2.0.0-r2.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Celery Sphinx Theme and Utilities"
+HOMEPAGE="
+	https://github.com/celery/sphinx_celery/
+	https://pypi.org/project/sphinx-celery/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/sphinx-2.0.0[${PYTHON_USEDEP}]
+"
-- 
cgit v1.3.1