From a53c4bb2ba0b2fc298e5a726a1e05c16c3063ffb Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 19 Oct 2022 13:04:40 +0000
Subject: Adding metadata

---
 dev-python/astroid/Manifest                        |   1 +
 dev-python/astroid/astroid-2.12.12.ebuild          |  60 ++++++
 dev-python/berkeleydb/berkeleydb-18.1.5.ebuild     |   2 +-
 dev-python/hatchling/Manifest                      |   1 +
 dev-python/hatchling/hatchling-1.11.1.ebuild       |  77 ++++++++
 dev-python/pandas/Manifest                         |   1 +
 dev-python/pandas/pandas-1.5.1.ebuild              | 210 +++++++++++++++++++++
 dev-python/pyglet/Manifest                         |   1 +
 dev-python/pyglet/pyglet-1.5.27.ebuild             |  74 ++++++++
 dev-python/rdflib/rdflib-6.2.0.ebuild              |   2 +-
 dev-python/simpy/simpy-4.0.1-r1.ebuild             |  28 +++
 dev-python/traitlets/traitlets-5.5.0.ebuild        |   3 +-
 .../uncertainties/uncertainties-3.1.7.ebuild       |   2 +-
 dev-python/xxhash/Manifest                         |   1 +
 dev-python/xxhash/xxhash-3.1.0.ebuild              |  38 ++++
 15 files changed, 497 insertions(+), 4 deletions(-)
 create mode 100644 dev-python/astroid/astroid-2.12.12.ebuild
 create mode 100644 dev-python/hatchling/hatchling-1.11.1.ebuild
 create mode 100644 dev-python/pandas/pandas-1.5.1.ebuild
 create mode 100644 dev-python/pyglet/pyglet-1.5.27.ebuild
 create mode 100644 dev-python/simpy/simpy-4.0.1-r1.ebuild
 create mode 100644 dev-python/xxhash/xxhash-3.1.0.ebuild

(limited to 'dev-python')

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index d0eb7209297b..c84c8d593648 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1,3 +1,4 @@
 DIST astroid-2.12.10.gh.tar.gz 435902 BLAKE2B eccabfbbda11edc958b0e5d5870f5df88cb267249d4d440e470515b75cda992ce9e7fd3dd50b9165ca40c6643053b0df0aeb754ec3b0461ea8a1ce45b0065ceb SHA512 55c3013a1672c4ce82f44ea85e4ac16881f0ea0a2f25b6457044e3c824699e13d46f5007f7410ca8d9a7d69c6690c8c41a187c9650fd4d4b7e9a7aa31e21add3
 DIST astroid-2.12.11.gh.tar.gz 436132 BLAKE2B ba3aa5766e669d1b509856cd8eb8cb90f6483b8459e6a2511945c4c54f28d86179b3420d6bfa26f54cf459926114d34dd2fe7d775f356eda17f995be860672a3 SHA512 1e8e364bcebce90d06f90494e2a029bfeae89a0dd3120400fa6ff5098ca05ec7c7f520336cc3b174ac007c81e272d774385c35f94762789b767d38e603c7d41d
+DIST astroid-2.12.12.gh.tar.gz 437277 BLAKE2B a1f549db526b1012e76e1da480e779a35971e8985f452eaf5ce1bc6735c5210db5c2282685dbaa2f1720a1e1fa6cf6f2152fbb8c782243cd11e09acc427774da SHA512 61047c1aa31b5b0a80c604194a91341c474062e2f1094316ff9b03641ecfe3ddf25b4a3b26356561f9c16d8b5599694ecef275ce5846792a18bcc0a7ad3e720f
 DIST astroid-2.12.8.gh.tar.gz 434545 BLAKE2B 3ad3ff1a7e1a0c9433387b4167041adcc405e9b6d0fc0a850073960db9e7458d0b6989e3a0f78679ba4730f1da2fe9d35de3f984d2c79532d9f96c2a726b1f0e SHA512 76052caaef27f983751e3abfb44c38ad497a4d2d659521ee55c99080c9cacea90cf3603d6468b01cc9b127cd8318157faae56bb151c6449145c70545719c6c51
diff --git a/dev-python/astroid/astroid-2.12.12.ebuild b/dev-python/astroid/astroid-2.12.12.ebuild
new file mode 100644
index 000000000000..de4ea1f950c3
--- /dev/null
+++ b/dev-python/astroid/astroid-2.12.12.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/PyCQA/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/PyCQA/astroid/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.10[${PYTHON_USEDEP}]
+	<dev-python/wrapt-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why it's broken
+		tests/unittest_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/unittest_brain_dataclasses.py::test_pydantic_field
+		tests/unittest_brain.py::SixBrainTest::test_from_imports
+		tests/unittest_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# some problem with warnings (our options?)
+		tests/unittest_decorators.py::TestDeprecationDecorators::test_deprecated_default_argument_values_one_arg
+		tests/unittest_decorators.py::TestDeprecationDecorators::test_deprecated_default_argument_values_two_args
+		tests/unittest_scoped_nodes.py::test_deprecation_of_doc_attribute
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker
+}
diff --git a/dev-python/berkeleydb/berkeleydb-18.1.5.ebuild b/dev-python/berkeleydb/berkeleydb-18.1.5.ebuild
index 5040832558c7..c646294754ba 100644
--- a/dev-python/berkeleydb/berkeleydb-18.1.5.ebuild
+++ b/dev-python/berkeleydb/berkeleydb-18.1.5.ebuild
@@ -17,7 +17,7 @@ SRC_URI="https://dev.gentoo.org/~arthurzam/distfiles/dev-python/${PN}/${P}.tar.x
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86"
 
 RDEPEND="
 	|| (
diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index e66f12317683..ecf1c64bd356 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,4 +1,5 @@
 DIST hatch-hatchling-v1.10.0.gh.tar.gz 256897 BLAKE2B 87a15624018d9919f29304f44520649465514bc594d266c152d28c08b99635b6f2d9b2f0ef68604e4d497860162cf9224d68ac78c22291fb80585a341a5d9704 SHA512 afb7f634f819cb3b914ede5c818a587f4a75f3a2c8e753f265f973e9b7d9c53e030dfdfdc862fb5b44cbdfd2564b1b863e3f12d7b7a31b4b62f7e316267de9c7
 DIST hatch-hatchling-v1.11.0.gh.tar.gz 364776 BLAKE2B 75cb39a336317b6c3a9168b5c994ad26fb303b75c7dcba8b2c92e7e6ffddfad6068b1336b203ce7944573df7a19ab920c6da5bbf12ac158e9c57bf196304bc7b SHA512 9e8b05058c61dd58a2ed3537ba9f007661804cce855648218ab717e184ea66ed307be53af8af449181ef0f9aa4e04afe2bc6ff6169934a84f33d804ddb70091b
+DIST hatch-hatchling-v1.11.1.gh.tar.gz 367624 BLAKE2B 006f9f9ab266eba7b7e489d4359a9ddb17a6e079c31e189662da8c4d090884eeae4bf108301d5c315d823e92cb813841e41211cc55618f4ee9109bccdde61e1e SHA512 7bdf5a2930950503dbe534f6ead724ed84420193ba55137600a5b98a085e94588e333bb5a14ad944746dc400522ebbea4849718686420fd6ed7de3d6e8852d8e
 DIST hatch-hatchling-v1.8.1.gh.tar.gz 1525669 BLAKE2B d1c33648eb202d57448f4f01d724361bce0db2ca25b1445f2c5bdec5f517f0ddfa961d07ff6d76ba7f326d1feae524a1f6600b563ad6f8bd504c7d00e1b1316d SHA512 d1878085adfd00e4efe7bbd5d70bf76e2d34bd42f0ef4dfc813088025dcc9d180605013a0acd9e24b3da86087dcf9bbb37be76528001034282f7a30a6ccbc20b
 DIST hatch-hatchling-v1.9.0.gh.tar.gz 252859 BLAKE2B 7fe0e06b26808ab47c8deead09744c32b2806327944ca799fe1b919ffe34227b7f51c0c5c7a7cad5b3a08b61acc10a0f9528048f3a4a45cf53efece64005fe9d SHA512 b99de517e6a049910e119fea9de667dc87782ff6400a8b730bb402c6337176f39a8e956d69e71561e413b80710b651421eb320d2b1b747b1818c97607c456c78
diff --git a/dev-python/hatchling/hatchling-1.11.1.ebuild b/dev-python/hatchling/hatchling-1.11.1.ebuild
new file mode 100644
index 000000000000..c91f404557b0
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.11.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{7,8,9,10} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	epytest tests/backend
+}
diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 72cf1b31d9c8..4a39f815dd01 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1,2 +1,3 @@
 DIST pandas-1.4.4.tar.gz 4949620 BLAKE2B 7ce236ae28ed6c6857a3acf6936aad2b1dc53a048986809d8dedbb9595dd2234bacbe114b74d8a171a6b31254372ea262566b134e7b5b24d5d4666938c7e6154 SHA512 a12e92dd751ed2342d9291724833732cdadbc9791e59533b9efded570b9893bacbe2f10e6bc70d673adb9356dcb0ae3d64d8a1dfe6ae8a3c70e474556ded4d91
 DIST pandas-1.5.0.tar.gz 5191537 BLAKE2B c7dec1d0197e6ac860667177f0f255bb327dbd48fe4501280d578b93f4496e61c0847dc478effeb8c5729d7a9d3e8a643c01db095a9843d6d211a9420f94d42c SHA512 8d340da1e0dff9b64c8993359b35ddcfc796fa15fee1bf1a27ea5a12e33f8b20d45bfac0ff9275b16ff0d4f7855a73962629e06c62bc08ca5e21b4ef1ea29ec2
+DIST pandas-1.5.1.tar.gz 5199286 BLAKE2B 17d98870f3397d7a9289a18708021a614b1d456e2ea99dae8927727aabb8aab73bd31f25c3035947f8f4c38404e7d971bf999500b300307b19a2cf6029763d0e SHA512 e5f25f21f17f36c6488f14fbfa391beb9f1989652de01cb8346d2826dead9331fea27295ee1e6f42d0875f2f1a91fcd23d606edd339432589bca5ba8d89e5ecd
diff --git a/dev-python/pandas/pandas-1.5.1.ebuild b/dev-python/pandas/pandas-1.5.1.ebuild
new file mode 100644
index 000000000000..edb1cd1bbc34
--- /dev/null
+++ b/dev-python/pandas/pandas-1.5.1.ebuild
@@ -0,0 +1,210 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="
+	https://pandas.pydata.org/
+	https://github.com/pandas-dev/pandas/
+	https://pypi.org/project/pandas/
+"
+SRC_URI="
+	https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.7.0[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+# TODO: Re-add dev-python/statsmodel[python3_11] dep once it supports python3_11
+# https://github.com/statsmodels/statsmodels/issues/8287
+OPTIONAL_DEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	|| (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	|| (
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	)
+	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.12.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+	!hppa? (
+		$(python_gen_cond_dep '
+			dev-python/statsmodels[${PYTHON_USEDEP}]
+		' python3_{8..10} )
+		>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+	)
+	X? (
+		|| (
+			dev-python/PyQt5[${PYTHON_USEDEP}]
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.1-r3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${COMMON_DEPEND}
+	>=dev-python/cython-0.29.32[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/xlrd[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5.5.3[${PYTHON_USEDEP}]
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-1.31[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="
+	${COMMON_DEPEND}
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	# requires package installed
+	sed -e '/extra_compile_args =/s:"-Werror"::' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# test for rounding errors, fails if we have better precision
+		# e.g. on amd64 with FMA or on arm64
+		# https://github.com/pandas-dev/pandas/issues/38921
+		pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+		# TODO
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated_direct
+		pandas/tests/io/test_clipboard.py::TestClipboard::test_raw_roundtrip
+
+		# TODO: xdist?
+		pandas/tests/test_expressions.py::TestExpressions::test_run_binary
+
+		# TODO: these require a running db server
+		pandas/tests/io/test_sql.py::TestMySQLAlchemy
+		pandas/tests/io/test_sql.py::TestMySQLAlchemyConn
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemy
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemyConn
+
+		# OOMs
+		pandas/tests/io/parser/test_c_parser_only.py::test_bytes_exceed_2gb
+	)
+
+	local -x LC_ALL=C.UTF-8
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	epytest pandas --skip-slow --skip-network -m "not single" \
+		-n "$(makeopts_jobs)" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.0" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-1.3.0"
+	optfeature "miscellaneous statistical functions" dev-python/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}
diff --git a/dev-python/pyglet/Manifest b/dev-python/pyglet/Manifest
index 239afa870a19..883c40eb0f44 100644
--- a/dev-python/pyglet/Manifest
+++ b/dev-python/pyglet/Manifest
@@ -1 +1,2 @@
 DIST pyglet-1.5.26.tar.gz 6534434 BLAKE2B a4366390f4ed92ed9e6c2d362fd8a009adf0e8a21ca00e1b9fead3cba99d192bb007413eca36892433f3bc4e2bf3258c550b2827262fc70e87b20566d46acb15 SHA512 819b2bbf71c9c632c1cefbb31e2a7186905c1475a1e978cd75dd6c019e5a53e6af79bceb57c68b61a3bb5692e04091c89c67b9168bb76ee19009c1ab719b8530
+DIST pyglet-1.5.27.gh.tar.gz 6532179 BLAKE2B f1dc668530a69e275860befe11f4c86003c5de2dadede706df7abac9eb6fb1729ea030c7053f0149926f3ffdd12985d9abea4afac65de3b6b7541fe871eda369 SHA512 98896dab06873cbf3cdd0d4015cb0b9e062cffb1110908bd422ecdc4f0e16943adc8a4986e7dbfdae4392e82ac115bad6f937896e166989ad2c4d73a0f45c8be
diff --git a/dev-python/pyglet/pyglet-1.5.27.ebuild b/dev-python/pyglet/pyglet-1.5.27.ebuild
new file mode 100644
index 000000000000..d7b44bdb3281
--- /dev/null
+++ b/dev-python/pyglet/pyglet-1.5.27.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+# python3.11: https://github.com/pyglet/pyglet/issues/606
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Cross-platform windowing and multimedia library for Python"
+HOMEPAGE="
+	https://pyglet.org/
+	https://github.com/pyglet/pyglet/
+	https://pypi.org/project/pyglet/
+"
+SRC_URI="https://github.com/pyglet/pyglet/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples image +sound"
+
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		media-libs/fontconfig
+	)
+"
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	image? ( || (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		x11-libs/gtk+:2
+	) )
+	sound? ( || (
+		media-libs/openal
+		media-sound/pulseaudio
+	) )
+"
+#	ffmpeg? ( media-libs/avbin-bin )
+
+DOCS=( DESIGN NOTICE README.md RELEASE_NOTES )
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	xdg_environment_reset
+
+	local EPYTEST_DESELECT=(
+		# lacking device/server permissions
+		tests/unit/media/test_listener.py::test_openal_listener
+		tests/unit/media/test_listener.py::test_pulse_listener
+	)
+
+	# Specify path to avoid running interactive tests
+	# We could add in integration tests, but they're slow
+	nonfatal epytest tests/unit || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/rdflib/rdflib-6.2.0.ebuild b/dev-python/rdflib/rdflib-6.2.0.ebuild
index 5e58a1109f85..9dd7d15b6afa 100644
--- a/dev-python/rdflib/rdflib-6.2.0.ebuild
+++ b/dev-python/rdflib/rdflib-6.2.0.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86"
 IUSE="examples sqlite"
 
 RDEPEND="
diff --git a/dev-python/simpy/simpy-4.0.1-r1.ebuild b/dev-python/simpy/simpy-4.0.1-r1.ebuild
new file mode 100644
index 000000000000..cca585d6b8d7
--- /dev/null
+++ b/dev-python/simpy/simpy-4.0.1-r1.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="tk"
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+MY_P="${P/simpy/SimPy}"
+
+DESCRIPTION="Object-oriented, process-based discrete-event simulation language"
+HOMEPAGE="https://simpy.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+# Could not import extension sphinx.builders.epub3 (exception: cannot import
+# name 'StandaloneHTMLBuilder' from partially initialized module
+# 'sphinx.builders.html' (most likely due to a circular import)
+# (/usr/lib/python3.10/site-packages/sphinx/builders/html/__init__.py))
+#distutils_enable_sphinx docs dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
diff --git a/dev-python/traitlets/traitlets-5.5.0.ebuild b/dev-python/traitlets/traitlets-5.5.0.ebuild
index 142069fda3ec..898aab3c4771 100644
--- a/dev-python/traitlets/traitlets-5.5.0.ebuild
+++ b/dev-python/traitlets/traitlets-5.5.0.ebuild
@@ -20,7 +20,8 @@ SLOT="0"
 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 distutils_enable_sphinx docs/source \
-	dev-python/sphinx_rtd_theme
+	dev-python/myst_parser \
+	dev-python/pydata-sphinx-theme
 distutils_enable_tests pytest
 
 python_test() {
diff --git a/dev-python/uncertainties/uncertainties-3.1.7.ebuild b/dev-python/uncertainties/uncertainties-3.1.7.ebuild
index 6007dafd5c39..625ccb21169d 100644
--- a/dev-python/uncertainties/uncertainties-3.1.7.ebuild
+++ b/dev-python/uncertainties/uncertainties-3.1.7.ebuild
@@ -20,7 +20,7 @@ BDEPEND="${RDEPEND}
 	test? (	dev-python/numpy[${PYTHON_USEDEP}] )
 "
 
-distutils_enable_tests nose
+distutils_enable_tests pytest
 distutils_enable_sphinx doc --no-autodoc
 
 pkg_postinst() {
diff --git a/dev-python/xxhash/Manifest b/dev-python/xxhash/Manifest
index 2d4d065a874f..ceac0fcc9cac 100644
--- a/dev-python/xxhash/Manifest
+++ b/dev-python/xxhash/Manifest
@@ -1 +1,2 @@
 DIST xxhash-3.0.0.tar.gz 74279 BLAKE2B 4c3d68103a7145aa1fd99da955b206c734c7882f1f6f3020d8bce9e5f2eb9714b9168b28918595bbb60445a024ec50d606e387358e6db8f4e575014763dece65 SHA512 170bfbacf0c4f8136550a257328d71dca096d996a52993a54442a7c5a54d48c51bb7997b3a718d73ae6c8e25a672ed4de664e7a651e02c43eb5f3fd135a59a80
+DIST xxhash-3.1.0.tar.gz 74389 BLAKE2B c2c7467aca51a397366c9de47104831f2d3d732b6b287e3fce4a0481d21bf059330dd63e1372b8da3aa9354efbc3de6ba106501d86c907b5783f7192e5e7c9a1 SHA512 a1d78dbbcc8fc8e41b6bc1d9e571df6951d4545fe61b198427db6f8c99058a095cf20e09951acc7bf9b432963f8b234741ae1f15ebb19972e69be0c59c9eb165
diff --git a/dev-python/xxhash/xxhash-3.1.0.ebuild b/dev-python/xxhash/xxhash-3.1.0.ebuild
new file mode 100644
index 000000000000..dee873128d4e
--- /dev/null
+++ b/dev-python/xxhash/xxhash-3.1.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python binding for the xxHash library"
+HOMEPAGE="
+	https://github.com/ifduyue/python-xxhash/
+	https://pypi.org/project/xxhash/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	>=dev-libs/xxhash-0.8.0
+"
+RDEPEND="
+	${DEPEND}
+"
+
+distutils_enable_tests unittest
+
+python_configure_all() {
+	export XXHASH_LINK_SO=1
+}
+
+python_test() {
+	cd tests || die
+	eunittest
+}
-- 
cgit v1.3