From 74ae40ee903f7bc8b1704ad4b03902aea7fbd3aa Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 22 Apr 2023 00:54:54 +0000
Subject: Adding metadata

---
 dev-python/clang-python/Manifest                   |   1 +
 .../clang-python-17.0.0_pre20230421.ebuild         |  54 +++++++++
 dev-python/doit-py/Manifest                        |   1 -
 dev-python/doit-py/doit-py-0.5.0.ebuild            |  27 -----
 dev-python/doit/doit-0.36.0.ebuild                 |  63 ----------
 dev-python/ensurepip-setuptools/Manifest           |   1 +
 .../ensurepip-setuptools-67.7.1.ebuild             |  24 ++++
 dev-python/lit/Manifest                            |   1 +
 dev-python/lit/lit-17.0.0_pre20230421.ebuild       |  42 +++++++
 dev-python/sentry-sdk/Manifest                     |   1 +
 dev-python/sentry-sdk/sentry-sdk-1.20.0.ebuild     | 109 ++++++++++++++++++
 dev-python/setuptools/Manifest                     |   1 +
 dev-python/setuptools/setuptools-67.7.1.ebuild     | 128 +++++++++++++++++++++
 dev-python/virtualenv/Manifest                     |   1 +
 dev-python/virtualenv/virtualenv-20.22.0.ebuild    | 101 ++++++++++++++++
 dev-python/xarray/Manifest                         |   1 +
 dev-python/xarray/xarray-2023.4.2.ebuild           |  56 +++++++++
 17 files changed, 521 insertions(+), 91 deletions(-)
 create mode 100644 dev-python/clang-python/clang-python-17.0.0_pre20230421.ebuild
 delete mode 100644 dev-python/doit-py/doit-py-0.5.0.ebuild
 delete mode 100644 dev-python/doit/doit-0.36.0.ebuild
 create mode 100644 dev-python/ensurepip-setuptools/ensurepip-setuptools-67.7.1.ebuild
 create mode 100644 dev-python/lit/lit-17.0.0_pre20230421.ebuild
 create mode 100644 dev-python/sentry-sdk/sentry-sdk-1.20.0.ebuild
 create mode 100644 dev-python/setuptools/setuptools-67.7.1.ebuild
 create mode 100644 dev-python/virtualenv/virtualenv-20.22.0.ebuild
 create mode 100644 dev-python/xarray/xarray-2023.4.2.ebuild

(limited to 'dev-python')

diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index e79e1260419a..ea6be99832d1 100644
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -8,3 +8,4 @@ DIST llvm-project-16.0.1.src.tar.xz.sig 566 BLAKE2B 06c03d789e63ab30bba4c56ba9ec
 DIST llvm-project-16.0.2.src.tar.xz 117995768 BLAKE2B b329b2b123428f3a966a96f074a75520f07d12fc13ec755403cff2346b23195e6a0c05ca9e789b4cf5b4b3557a922bd41d8dffb6056ee33fbbf2b81001511fae SHA512 4ca76aaaca8812a06a94071e7444a3213d85dca51ea86f6125f854776f69a3e088a92d0621e3911e526f280b35bfb778fb3742c6010d3ed1eba605c08720377c
 DIST llvm-project-16.0.2.src.tar.xz.sig 566 BLAKE2B 8243748ac27e4eec3cc011371e179e19f1005336f07d956fd358f649d1429c8d0ea22ecc376b1dec9fe3db971467ad1dd63e97bb089885d0e1994eeab26b6fd7 SHA512 dbe9367a259954a38f2369b2f226726162090227f1a5ae8c8809eaae47cad7b3b26c754633e6e5c54cacd6360a504d7ba4c659d9232c1648388d657a2aaad10c
 DIST llvm-project-5c60a08c696c0420ddc5fdad5b8e50a7528cb3bf.tar.gz 182291041 BLAKE2B f5997611e0293df515d4494d14895cc8fbe22b536f5c419e4ad7d098acbf2b1046ceb332d865eacdae0b7fa1a77b78090551976835dd1b95b5270c9f6e12e410 SHA512 6cda8e55b4fc70e94838c772c56213c811affda96fb98a03d432348f995a313447d0e0e84533350e1fda3162d82633b260ccd8e3b1d59d3216187b44dc5556fb
+DIST llvm-project-5ea158077ec9ca50857ede5cbb0b27c61663fd55.tar.gz 182543024 BLAKE2B 32f5a9ddaa6c7e283d97256d7bd68634f2f8ed6d7167e743ba8076809ea1a3a7159f9ccc56a6e5a8838481cade07389669d8a35b17b5922da0cbef04c80131f8 SHA512 3d180c04ef39adbc9c6ee485e21cdf63fde362f0a22026b00a6d3eba6243e4c8e96fc088335f31051e54f4546d62569131a671d2e655ea735d597361f5732827
diff --git a/dev-python/clang-python/clang-python-17.0.0_pre20230421.ebuild b/dev-python/clang-python/clang-python-17.0.0_pre20230421.ebuild
new file mode 100644
index 000000000000..f37802f5c2d7
--- /dev/null
+++ b/dev-python/clang-python/clang-python-17.0.0_pre20230421.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		sys-devel/clang:${LLVM_MAJOR}
+	)
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	# tests rely on results from a specific clang version, so override
+	# the search path
+	local -x CLANG_LIBRARY_PATH=${BROOT}/usr/lib/llvm/${LLVM_MAJOR}/$(get_libdir)
+	local -x CLANG_NO_DEFAULT_CONFIG=1
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/doit-py/Manifest b/dev-python/doit-py/Manifest
index a0966693812b..7b7691a48937 100644
--- a/dev-python/doit-py/Manifest
+++ b/dev-python/doit-py/Manifest
@@ -1,2 +1 @@
 DIST doit-py-0.5.0.gh.tar.gz 15174 BLAKE2B 092f21549d3c088baf8a96b8dd7575304d08c7ae7b0472e7a890159247422060af06c1cc14064cd608bd59e71788067c5374953b16f4511971bb3018c0245cd4 SHA512 f9e70be30f47b7251bdb479762dabe655be898f9fe37fc5ac6608110a82863a08002271620569745f9ec2f47c03529c044a6ea74244b8bb6438b3fbe7e4c28f7
-DIST doit-py-0.5.0.tar.gz 15174 BLAKE2B 092f21549d3c088baf8a96b8dd7575304d08c7ae7b0472e7a890159247422060af06c1cc14064cd608bd59e71788067c5374953b16f4511971bb3018c0245cd4 SHA512 f9e70be30f47b7251bdb479762dabe655be898f9fe37fc5ac6608110a82863a08002271620569745f9ec2f47c03529c044a6ea74244b8bb6438b3fbe7e4c28f7
diff --git a/dev-python/doit-py/doit-py-0.5.0.ebuild b/dev-python/doit-py/doit-py-0.5.0.ebuild
deleted file mode 100644
index e905c7790edf..000000000000
--- a/dev-python/doit-py/doit-py-0.5.0.ebuild
+++ /dev/null
@@ -1,27 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8,9,10,11} )
-
-inherit distutils-r1
-
-DESCRIPTION="doit tasks for python stuff"
-HOMEPAGE="https://pythonhosted.org/doit-py/ https://github.com/pydoit/doit-py"
-SRC_URI="https://github.com/pydoit/doit-py/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 ~riscv x86"
-
-DEPEND="
-	test? (
-		app-text/hunspell[l10n_en]
-		dev-python/pyflakes[${PYTHON_USEDEP}]
-	)"
-RDEPEND="
-	dev-python/configclass[${PYTHON_USEDEP}]"
-
-distutils_enable_sphinx doc
-distutils_enable_tests pytest
diff --git a/dev-python/doit/doit-0.36.0.ebuild b/dev-python/doit/doit-0.36.0.ebuild
deleted file mode 100644
index dc8259183ac3..000000000000
--- a/dev-python/doit/doit-0.36.0.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10,11} )
-inherit bash-completion-r1 distutils-r1
-
-DESCRIPTION="Automation tool"
-HOMEPAGE="https://pydoit.org/
-	https://pypi.org/project/doit/
-	https://github.com/pydoit/doit"
-SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 ~riscv x86"
-
-RDEPEND="
-	dev-python/cloudpickle[${PYTHON_USEDEP}]
-	dev-python/pyinotify[${PYTHON_USEDEP}]
-	|| (
-		dev-python/tomli[${PYTHON_USEDEP}]
-		dev-python/tomlkit[${PYTHON_USEDEP}]
-	)
-"
-BDEPEND="
-	test? (
-		$(python_gen_impl_dep sqlite)
-		dev-python/pyflakes[${PYTHON_USEDEP}]
-	)
-"
-PDEPEND=">=dev-python/doit-py-0.4.0[${PYTHON_USEDEP}]"
-
-distutils_enable_tests pytest
-distutils_enable_sphinx doc \
-	dev-python/sphinx-rtd-theme
-
-EPYTEST_DESELECT=(
-	# test failing due to impact on PATH run in a sandbox
-	tests/test_cmd_strace.py::TestCmdStrace::test_dep # #836164
-	tests/test_cmd_strace.py::TestCmdStrace::test_target
-)
-
-src_prepare() {
-	# Replace custom theme with builtin for documentation
-	sed -e '/html_theme/s/press/sphinx_rtd_theme/' -i doc/conf.py || die
-	# Remove non-exist modules for doc generation (#832754)
-	sed \
-		-e '/sphinx_sitemap/d' \
-		-e '/sphinx_reredirects/d' \
-		-i doc/conf.py || die
-
-	distutils-r1_src_prepare
-}
-
-src_install() {
-	distutils-r1_src_install
-	newbashcomp bash_completion_doit ${PN}
-	insinto /usr/share/zsh/site-functions
-	newins zsh_completion_doit _${PN}
-}
diff --git a/dev-python/ensurepip-setuptools/Manifest b/dev-python/ensurepip-setuptools/Manifest
index fc8edc04a472..203d072051af 100644
--- a/dev-python/ensurepip-setuptools/Manifest
+++ b/dev-python/ensurepip-setuptools/Manifest
@@ -1,2 +1,3 @@
 DIST setuptools-67.6.1-py3-none-any.whl 1089263 BLAKE2B fe1ca817d2743e5edefac47230aa2cb5f4e75945bcdb821ca2d61011a419653d8b0880d846e11e4450cb19fd22fcd45d570b6c33fce640a8515df6e65f7a1662 SHA512 ad7a81c60b2b3f190561178531123a0e2d278c4cd9615930d5b0276fc79bea390f1cc92ab37061378ebee09fc36c21440a4db00f20029093570b7006cd14b25b
 DIST setuptools-67.7.0-py3-none-any.whl 1093434 BLAKE2B 76e91b7353f75f4c2c3eaa0222b1e846c82fb24a7c7220408cc3f547d8243bc0e306b19661f26e5bd5b2a82b3f8e58c60b3906869011477fbc2db82152baeb94 SHA512 22428cf43932d4a16f704adace5e6fa9ddff15c2715c9ba2c0f47c2e96d5fa95e5fbd21e2e55cef9c43a41d29f6cd2d09500b1cb81daedb64820e388ead70346
+DIST setuptools-67.7.1-py3-none-any.whl 1093433 BLAKE2B a28d3fa5fe0229e681c9cdf846f387b57e77a31a3d20f18a7164af6d6e5832ce65c71c8dc9326bebae2e2c5d80498609acaa315999133b320972ca4f6dc988c8 SHA512 b9ef9fbd268f48f5c585deb4bd5ee9d47fc4633832fb52dff61663ce045b05d67d9aee1eab0482a34dd7b55aa42a1eb0948ac6bb94fbb050435c73f3b63439f9
diff --git a/dev-python/ensurepip-setuptools/ensurepip-setuptools-67.7.1.ebuild b/dev-python/ensurepip-setuptools/ensurepip-setuptools-67.7.1.ebuild
new file mode 100644
index 000000000000..c13c3370cbbe
--- /dev/null
+++ b/dev-python/ensurepip-setuptools/ensurepip-setuptools-67.7.1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pypi
+
+DESCRIPTION="Shared setuptools wheel for ensurepip Python module"
+HOMEPAGE="https://pypi.org/project/setuptools/"
+SRC_URI="$(pypi_wheel_url "${PN#ensurepip-}")"
+S=${DISTDIR}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	!<dev-python/ensurepip-wheels-100
+"
+
+src_install() {
+	insinto /usr/lib/python/ensurepip
+	doins "${A}"
+}
diff --git a/dev-python/lit/Manifest b/dev-python/lit/Manifest
index e79e1260419a..ea6be99832d1 100644
--- a/dev-python/lit/Manifest
+++ b/dev-python/lit/Manifest
@@ -8,3 +8,4 @@ DIST llvm-project-16.0.1.src.tar.xz.sig 566 BLAKE2B 06c03d789e63ab30bba4c56ba9ec
 DIST llvm-project-16.0.2.src.tar.xz 117995768 BLAKE2B b329b2b123428f3a966a96f074a75520f07d12fc13ec755403cff2346b23195e6a0c05ca9e789b4cf5b4b3557a922bd41d8dffb6056ee33fbbf2b81001511fae SHA512 4ca76aaaca8812a06a94071e7444a3213d85dca51ea86f6125f854776f69a3e088a92d0621e3911e526f280b35bfb778fb3742c6010d3ed1eba605c08720377c
 DIST llvm-project-16.0.2.src.tar.xz.sig 566 BLAKE2B 8243748ac27e4eec3cc011371e179e19f1005336f07d956fd358f649d1429c8d0ea22ecc376b1dec9fe3db971467ad1dd63e97bb089885d0e1994eeab26b6fd7 SHA512 dbe9367a259954a38f2369b2f226726162090227f1a5ae8c8809eaae47cad7b3b26c754633e6e5c54cacd6360a504d7ba4c659d9232c1648388d657a2aaad10c
 DIST llvm-project-5c60a08c696c0420ddc5fdad5b8e50a7528cb3bf.tar.gz 182291041 BLAKE2B f5997611e0293df515d4494d14895cc8fbe22b536f5c419e4ad7d098acbf2b1046ceb332d865eacdae0b7fa1a77b78090551976835dd1b95b5270c9f6e12e410 SHA512 6cda8e55b4fc70e94838c772c56213c811affda96fb98a03d432348f995a313447d0e0e84533350e1fda3162d82633b260ccd8e3b1d59d3216187b44dc5556fb
+DIST llvm-project-5ea158077ec9ca50857ede5cbb0b27c61663fd55.tar.gz 182543024 BLAKE2B 32f5a9ddaa6c7e283d97256d7bd68634f2f8ed6d7167e743ba8076809ea1a3a7159f9ccc56a6e5a8838481cade07389669d8a35b17b5922da0cbef04c80131f8 SHA512 3d180c04ef39adbc9c6ee485e21cdf63fde362f0a22026b00a6d3eba6243e4c8e96fc088335f31051e54f4546d62569131a671d2e655ea735d597361f5732827
diff --git a/dev-python/lit/lit-17.0.0_pre20230421.ebuild b/dev-python/lit/lit-17.0.0_pre20230421.ebuild
new file mode 100644
index 000000000000..0e39fac626c6
--- /dev/null
+++ b/dev-python/lit/lit-17.0.0_pre20230421.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm
+	)
+"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index a296fd241d29..f7b6941074af 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -3,3 +3,4 @@ DIST sentry-python-1.17.0.gh.tar.gz 332229 BLAKE2B 5c94f80d8cbe9582fe03e948c74e3
 DIST sentry-python-1.18.0.gh.tar.gz 338306 BLAKE2B 5af147598af6fd9d03f9931bf6d1519d3c307e16bab188a14ed3e9956060d7c6c65b386d330f5674be1cc7f2147c1e78c7901ce2ef46198887d86ebff0614f7e SHA512 250ea5f4374218672e240893c14ecb7ca22654c673f0a44cc00ca4099ea1d27b749be59c3004de68be3f79cdfbef7e614d1ec5506f3c1eb1699a440eb6387907
 DIST sentry-python-1.19.0.gh.tar.gz 345791 BLAKE2B f0cc7b4bad7f3ede98c254dac40ab49392edd92b36adbef0aac277a4ff14e4f8b27cf8ef602a6ac768ab8e6fb04fa05b3220a0b87a24ed280462fe5c0dc349bf SHA512 ced2fe549e40c189ab31a8af6bae857357aaa5ea1b0f4cccf1d5a0e6d332375cc72257fbc45e81335ac3ff37f705e9e73cfc551ad4320d7150614cedac948338
 DIST sentry-python-1.19.1.gh.tar.gz 345933 BLAKE2B 0b6912553b41fe14b14a4199756f54e9870819c9bf15a91253889c43b3b93d63d09d9cbe96ec35b83a2d966990549e2043543506abeefa0320ff6098e8ea8304 SHA512 ca2f701904fc9d38ce89a2e085d30b4d4f532878a383a20016d0b5763b4d1e34fd1f6bd87c8aecb46f40e5b5bdc6b8021fb6154df28d1cd50f634326c1b3f499
+DIST sentry-python-1.20.0.gh.tar.gz 345505 BLAKE2B e95225188a74f4d9e67f6044bcf3bbeccacc31c455a652d8233350d138c20ee9f356e56aab98a1c2f764917d79426e10a810cb6c18cfabcc5f606ec21c42f7e8 SHA512 6c162d44cc3b38a9aa192a7153d52e93424950e1020cd2d6ea8e61d23b3d41ca169e3dde7c0355e5da2ed45ce39c41322d6e0f239d6e00e30a55540db796f968
diff --git a/dev-python/sentry-sdk/sentry-sdk-1.20.0.ebuild b/dev-python/sentry-sdk/sentry-sdk-1.20.0.ebuild
new file mode 100644
index 000000000000..adaa1c27ade8
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-1.20.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=sentry-python-${PV}
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="
+	https://sentry.io/
+	https://github.com/getsentry/sentry-python/
+	https://pypi.org/project/sentry-sdk/
+"
+SRC_URI="
+	https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# tests require Internet access
+	tests/integrations/httpx/test_httpx.py
+	tests/integrations/requests/test_requests.py
+	tests/integrations/stdlib/test_httplib.py
+	tests/integrations/flask/test_flask.py
+	tests/integrations/django/test_basic.py
+	tests/integrations/socket/test_socket.py
+	# wtf is it supposed to do?!
+	tests/integrations/gcp/test_gcp.py
+	# broken by rq-1.10.1 (optional dep)
+	tests/integrations/rq/test_rq.py
+	# fastapi is not packaged
+	tests/integrations/asgi/test_fastapi.py
+	# TODO
+	tests/integrations/bottle
+	# TODO: causes breakage in other tests
+	tests/integrations/starlette
+	# TODO
+	tests/integrations/tornado
+	# requires mockupdb
+	tests/integrations/pymongo
+)
+
+EPYTEST_DESELECT=(
+	# hangs
+	'tests/test_transport.py::test_transport_works'
+	# TODO
+	'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+	tests/test_client.py::test_databag_depth_stripping
+	tests/test_client.py::test_databag_string_stripping
+	tests/test_client.py::test_databag_breadth_stripping
+	tests/integrations/asgi/test_asgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/asgi/test_asgi.py::test_websocket
+	tests/integrations/aiohttp/test_aiohttp.py::test_transaction_style
+	tests/integrations/aiohttp/test_aiohttp.py::test_traces_sampler_gets_request_object_in_sampling_context
+	# incompatible version?
+	tests/integrations/falcon/test_falcon.py
+	tests/integrations/sqlalchemy/test_sqlalchemy.py::test_large_event_not_truncated
+	# test_circular_references: apparently fragile
+	'tests/integrations/threading/test_threading.py::test_circular_references'
+	# test for new feature, fails with IndexError
+	tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+	# TODO
+	tests/integrations/wsgi/test_wsgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/wsgi/test_wsgi.py::test_profile_sent_when_profiling_enabled
+	tests/test_profiler.py::test_sample_buffer
+	tests/test_profiler.py::test_thread_scheduler_takes_first_samples
+	tests/test_profiler.py::test_thread_scheduler_takes_more_samples
+	tests/test_profiler.py::test_thread_scheduler_single_background_thread
+	# broken with py3.11, *shrug*
+	tests/test_profiler.py::test_extract_stack_with_max_depth
+	# TODO
+	tests/integrations/sqlalchemy/test_sqlalchemy.py::test_long_sql_query_preserved
+	tests/test_scrubber.py::test_breadcrumb_extra_scrubbing
+	tests/test_scrubber.py::test_span_data_scrubbing
+)
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 67d29fb2a9ec..3c8d70f364c3 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -1,2 +1,3 @@
 DIST setuptools-67.6.1.tar.gz 2486256 BLAKE2B 7827eec689b6a4463888137660489a29cd6aa67a14f0cf42ece78463788d74b97bd951b75c48c185c5c33d5bea29c44c8660649bf79035012bc75b915e9d0a42 SHA512 197910ad4c4058af0107e240d2e27bc2c1ff373cb3fba33af09eb3cc42614c45e4bb73a65802f253466eafd94517e08b51e98f50213817ad03d88ee0ccf9adbc
 DIST setuptools-67.7.0.tar.gz 2491327 BLAKE2B 3d1e89cf5b2753883397ff3a668dbfcef41c57775bd1871ada69c11a7deffe53fd4c4036b5c98146ec0496b1be86df1522c64cc981acb5ec192bd93bd800c2de SHA512 39502337b5d7f710c55219ab970a5cab23e8987598af722ad231d2dea2e1dfaaddb09dc698a5746a719b36e5e3065c48ecee2ac428e4d41470bec6ad3c99daf6
+DIST setuptools-67.7.1.tar.gz 2491346 BLAKE2B 2eb89badcbfec51fb3deca5f4267036305569bf42677b87c9eeb7cecd902c121ffc6725506bfa0ba3ac50e06c036a520dd14b6193ff048e21ed80dfeb1c93602 SHA512 c90a6ad0c215540dfd93d5c88126dab15499deb80ed601f4a90c92dfdff5fed6ff168fb8e6b9dc5ba8b1f067114d383400df390b2eebd934e2e728c3b56886af
diff --git a/dev-python/setuptools/setuptools-67.7.1.ebuild b/dev-python/setuptools/setuptools-67.7.1.ebuild
new file mode 100644
index 000000000000..617e61b823a9
--- /dev/null
+++ b/dev-python/setuptools/setuptools-67.7.1.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-4.11.1[${PYTHON_USEDEP}]
+	' 3.9)
+"
+BDEPEND="
+	${RDEPEND}
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	distutils-r1_src_prepare
+
+	# remove bundled dependencies, setuptools will switch to system deps
+	# automatically
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+	)
+
+	if has_version "<dev-python/packaging-22"; then
+		EPYTEST_DESELECT+=(
+			# old packaging is more lenient
+			setuptools/tests/config/test_setupcfg.py::TestOptions::test_raises_accidental_env_marker_misconfig
+		)
+	fi
+
+	epytest -n "$(makeopts_jobs)" setuptools
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index d25091220f98..e56487ca2baa 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,2 +1,3 @@
 DIST virtualenv-20.20.0.tar.gz 12069625 BLAKE2B 3db53d2859c542953be233af0d195d992eecef345700ad7c229b88519f7042189907263d312d3613b45c5c069bec2440a8639bcc58b2c6894ed79301735e65b2 SHA512 6710efcbead1358479961c84ec3f6b9c3a1fc59c2f6b33fa13e2609554f7072aee7ef8cc07b4aa2fbc27ac950a78e447529fb8ceb2e4ee0881a4356a67d26641
 DIST virtualenv-20.21.0.tar.gz 12070063 BLAKE2B f69d5934191ccd8e9420c37e51b53df7876961d6f13d0f75845530893fd91df29a512e64eaa27135535816250a3149087029e6fe1b15317b8079af9cee2832ea SHA512 77aae5ebc5007093953c30da1eed996e851a65c7dd1f7a3a85961a1bb251b3d7970936eea1efe8babb216d2024072bdbf1c1a97ba8760a04a0abf6e7c3a27d09
+DIST virtualenv-20.22.0.tar.gz 6612036 BLAKE2B aeebf0a80dd96eb78dc4a2ca258e1089a9ce1a4e0bb66b1e8b5093353e298e22dbcc57acea7f5094dee29e4e855c51ce235901fd39d29fbfbc3dd96dcef8b15f SHA512 83d15b03abebd856b1636d0f00443f77882de9fdeb9dff67b72dc839d55f4e7e0668914ef3ac79cdf1d8cf147e29ba97feb720a5ebfcf24dc6cd27ec2e04384d
diff --git a/dev-python/virtualenv/virtualenv-20.22.0.ebuild b/dev-python/virtualenv/virtualenv-20.22.0.ebuild
new file mode 100644
index 000000000000..74de7d119503
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.22.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	<dev-python/distlib-1[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+	<dev-python/filelock-4[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.11[${PYTHON_USEDEP}]
+	<dev-python/platformdirs-4[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.2[${PYTHON_USEDEP}]
+"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/pip-22.2.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-freezegun-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
+		>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	)
+"
+# https://github.com/pypa/virtualenv/issues/2554
+BDEPEND+="
+	test? (
+		$(python_gen_cond_dep '
+			!!<dev-python/virtualenv-20.22[${PYTHON_USEDEP}]
+		' 3.9)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+		# tests failing without python2 installed
+		"tests/unit/create/test_creator.py::test_py_pyc_missing[True-False]"
+		"tests/unit/create/test_creator.py::test_py_pyc_missing[False-False]"
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+	[[ ${EPYTHON} == python3.11 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		tests/unit/discovery/py_info/test_py_info.py::test_py_info_setuptools
+		tests/unit/discovery/py_info/test_py_info.py::test_custom_venv_install_scheme_is_prefered
+		tests/unit/discovery/py_info/test_py_info.py::test_fallback_existent_system_executable
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p flaky -p freezegun -p pytest_mock
+}
diff --git a/dev-python/xarray/Manifest b/dev-python/xarray/Manifest
index 3f24823b5b47..a2071eed4401 100644
--- a/dev-python/xarray/Manifest
+++ b/dev-python/xarray/Manifest
@@ -2,3 +2,4 @@ DIST xarray-2023.2.0.tar.gz 3070514 BLAKE2B 00b08bb75878eed1aa82ac18ae5bc468d878
 DIST xarray-2023.3.0.tar.gz 3686167 BLAKE2B b9c2e04d0278e383aef17280e74863244d458324c01ac59a453e72196d65cad8fbca9f8f99a33b6db66637f742e04e5615fa8fc6eed307f0511954a856f8f3d2 SHA512 c08269e6fc8cdd3123dd7c39e0b85959bafdc53a5da75187fc615281fb71212bf2e45059f8d18fa05339567a4827e7bb68de3e605416929a6a1defdb4ed393e3
 DIST xarray-2023.4.0.tar.gz 3689883 BLAKE2B 50c5a18eaf28fc3bc38bc322dc393ec3e6a66c2651341019b389ba950c01f3950ee13e0922568f29ac1e3650ca9fdb55aec5574abe8f733959f15151208ac09b SHA512 1bb5052cb48e4ecb2d4e9d88cb0a0d3b25469b762d34059b5f65a88c2cbd125711d9af8a46a16b3eff3783f7d7653118b44503f19512ebc89845449a92efe1d9
 DIST xarray-2023.4.1.tar.gz 3690082 BLAKE2B 33b8c8b6694911e0fb670dc60b784e9473a632bbdc793ac85685c9891933e373e40378c7362d7d3f7d6cf584716f8759ad73701d469534b70323d8e20d27ef3b SHA512 5bffb6b09d1188da27f19b6ec652ffb5a16ebdf036cf53f2d7c5b1805e7beababea6505127a23170d8ae8ad9453f429598b17f468c84b72ad07383ea3951d935
+DIST xarray-2023.4.2.tar.gz 3692437 BLAKE2B d4fb5b184386bb7e9574ea3bdf484c3df82b9dca1fcd2380ac65b6a58da9f89da057d70efa9bd045b5cf6900c38f6aa4176fd2990cfe1369f987c452711307d6 SHA512 581b06a677b80c0f7e494a80ae52d75bd62bf613b13b7b7215458ceef727fb55a898c8da8cc6f8a6875ef6898007897eea8be55fb138f1dacad42965bbf1d956
diff --git a/dev-python/xarray/xarray-2023.4.2.ebuild b/dev-python/xarray/xarray-2023.4.2.ebuild
new file mode 100644
index 000000000000..f64c9aa706f2
--- /dev/null
+++ b/dev-python/xarray/xarray-2023.4.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="N-D labeled arrays and datasets in Python"
+HOMEPAGE="
+	https://xarray.pydata.org/
+	https://github.com/pydata/xarray/
+	https://pypi.org/project/xarray/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/numpy-1.22[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+"
+# note: most of the test dependencies are optional
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bottleneck[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/toolz[${PYTHON_USEDEP}]
+		!hppa? ( >=dev-python/scipy-1.4[${PYTHON_USEDEP}] )
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# warning-targeted tests are fragile and not important to end users
+	xarray/tests/test_backends.py::test_no_warning_from_dask_effective_get
+	# TODO: segv in netcdf4-python
+	'xarray/tests/test_backends.py::test_open_mfdataset_manyfiles[netcdf4-20-True-5-5]'
+	'xarray/tests/test_backends.py::test_open_mfdataset_manyfiles[netcdf4-20-True-5-None]'
+	'xarray/tests/test_backends.py::test_open_mfdataset_manyfiles[netcdf4-20-True-None-5]'
+	'xarray/tests/test_backends.py::test_open_mfdataset_manyfiles[netcdf4-20-True-None-None]'
+	xarray/tests/test_backends.py::TestDask::test_save_mfdataset_compute_false_roundtrip
+)
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p xdist.plugin -n "$(makeopts_jobs)"
+}
-- 
cgit v1.3