From a3ceca1b4c0d9bdb550dc23f06ffbb5a8e033bc7 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 16:24:49 -0500
Subject: Adding metadata

---
 dev-python/zstandard/Manifest                |  1 -
 dev-python/zstandard/metadata.xml            | 12 -----
 dev-python/zstandard/zstandard-0.25.0.ebuild | 74 ----------------------------
 3 files changed, 87 deletions(-)
 delete mode 100644 dev-python/zstandard/Manifest
 delete mode 100644 dev-python/zstandard/metadata.xml
 delete mode 100644 dev-python/zstandard/zstandard-0.25.0.ebuild

(limited to 'dev-python/zstandard')

diff --git a/dev-python/zstandard/Manifest b/dev-python/zstandard/Manifest
deleted file mode 100644
index 98df9a19e08f..000000000000
--- a/dev-python/zstandard/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST python-zstandard-0.25.0.gh.tar.gz 795455 BLAKE2B 6f5410b66b90cd737530259328d4abd04129a249f9b508db2e5ccd2cb028b22f13f0659b16604afe0f9c5026b282a0c5eb4a1faaa6df4946f9b99319d06ef825 SHA512 1ca492bcb39c22ec9eb1877799172de4a04033df364f4271b658243c0a9816ac584df0df85ebe967a2e2b98a10db90b66e7b050ecb8bfa9f9c7ad50f2f87921a
diff --git a/dev-python/zstandard/metadata.xml b/dev-python/zstandard/metadata.xml
deleted file mode 100644
index 9bca3117a180..000000000000
--- a/dev-python/zstandard/metadata.xml
+++ /dev/null
@@ -1,12 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="project">
-		<email>python@gentoo.org</email>
-		<name>Python</name>
-	</maintainer>
-	<upstream>
-		<remote-id type="pypi">zstandard</remote-id>
-		<remote-id type="github">indygreg/python-zstandard</remote-id>
-	</upstream>
-</pkgmetadata>
diff --git a/dev-python/zstandard/zstandard-0.25.0.ebuild b/dev-python/zstandard/zstandard-0.25.0.ebuild
deleted file mode 100644
index d684fd03eac0..000000000000
--- a/dev-python/zstandard/zstandard-0.25.0.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1
-
-MY_P=python-zstandard-${PV}
-DESCRIPTION="Zstandard Bindings for Python"
-HOMEPAGE="
-	https://github.com/indygreg/python-zstandard/
-	https://pypi.org/project/zstandard/
-"
-SRC_URI="
-	https://github.com/indygreg/python-zstandard/archive/${PV}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
-
-DEPEND="
-	>=app-arch/zstd-1.5.7:=
-"
-RDEPEND="
-	${DEPEND}
-	$(python_gen_cond_dep '
-		>=dev-python/cffi-1.14.0-r2:=[${PYTHON_USEDEP}]
-	' 'python*')
-"
-
-EPYTEST_PLUGINS=( hypothesis )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	# the C backend is repeatedly broken, so force CFFI instead
-	sed -e '/PYTHON_ZSTANDARD_IMPORT_POLICY/s:default:cffi:' \
-		-i zstandard/__init__.py || die
-	# unbundle zstd
-	rm zstd/* || die
-	> zstd/zstd.c || die
-	# it does random preprocessing on that, so we can't use #include
-	local f
-	for f in zdict.h zstd.h zstd_errors.h; do
-		cp "${ESYSROOT}/usr/include/${f}" "zstd/${f}" || die
-	done
-	sed -i -e '/include_dirs/a    libraries=["zstd"],' make_cffi.py || die
-
-	distutils-r1_src_prepare
-
-	DISTUTILS_ARGS=(
-		--no-c-backend
-	)
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# unreliable, fails on x86
-		tests/test_data_structures.py::TestCompressionParameters::test_estimated_compression_context_size
-		# check for bundled zstd version, fails on other system zstd
-		tests/test_module_attributes.py::TestModuleAttributes::test_version
-	)
-	local -x ZSTD_SLOW_TESTS=1
-
-	rm -rf zstandard || die
-	epytest
-}
-- 
cgit v1.3