From f8567a6b293674606904abe05bf9fbbb2ecd3b97 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 28 May 2025 06:54:29 +0000
Subject: Adding metadata

---
 dev-python/yara-python/yara-python-4.5.4.ebuild | 40 +++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 dev-python/yara-python/yara-python-4.5.4.ebuild

(limited to 'dev-python/yara-python/yara-python-4.5.4.ebuild')

diff --git a/dev-python/yara-python/yara-python-4.5.4.ebuild b/dev-python/yara-python/yara-python-4.5.4.ebuild
new file mode 100644
index 000000000000..604f35884253
--- /dev/null
+++ b/dev-python/yara-python/yara-python-4.5.4.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{11..14} )
+inherit distutils-r1
+
+DESCRIPTION="Python interface for a malware identification and classification tool"
+HOMEPAGE="https://github.com/VirusTotal/yara-python"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/VirusTotal/yara-python.git"
+else
+	SRC_URI="https://github.com/virustotal/yara-python/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+RDEPEND="
+	=app-forensics/yara-$(ver_cut 1-2)*
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests unittest
+
+python_configure_all() {
+	cat >> setup.cfg <<-EOF
+	dynamic_linking = True
+	EOF
+}
+
+python_test() {
+	"${EPYTHON}" tests.py -v || die "Tests fail with ${EPYTHON}"
+}
-- 
cgit v1.3.1