From ecdac123787b96ce6649f0f91da12ea6458cc2b1 Mon Sep 17 00:00:00 2001
From: Palica <palica+gitlab@liguros.net>
Date: Tue, 23 Jun 2020 22:35:08 +0200
Subject: Updating liguros repo

---
 dev-python/wtforms/wtforms-2.2.1.ebuild | 59 +++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/wtforms/wtforms-2.2.1.ebuild

(limited to 'dev-python/wtforms/wtforms-2.2.1.ebuild')

diff --git a/dev-python/wtforms/wtforms-2.2.1.ebuild b/dev-python/wtforms/wtforms-2.2.1.ebuild
new file mode 100644
index 000000000000..aeb0c540d6e9
--- /dev/null
+++ b/dev-python/wtforms/wtforms-2.2.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python2_7 python3_{6,7,8} )
+inherit distutils-r1
+
+MY_PN="WTForms"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flexible forms validation and rendering library for python web development"
+HOMEPAGE="https://wtforms.readthedocs.io/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_P}"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( >=dev-python/sphinx-0.6[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/Babel[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/webob[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Extension-tests are written for an older version of Django
+	# Disable pep8 even when it is installed
+	sed \
+		-e "s|'ext_django.tests', ||" \
+		-e "/import pep8/d" \
+		-e "s|has_pep8 = True|has_pep8 = False|" \
+		-i tests/runtests.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" tests/runtests.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+}
-- 
cgit v1.3.1