From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/websockets/Manifest               |  1 +
 dev-python/websockets/metadata.xml           | 19 +++++++++
 dev-python/websockets/websockets-16.0.ebuild | 60 ++++++++++++++++++++++++++++
 3 files changed, 80 insertions(+)
 create mode 100644 dev-python/websockets/Manifest
 create mode 100644 dev-python/websockets/metadata.xml
 create mode 100644 dev-python/websockets/websockets-16.0.ebuild

(limited to 'dev-python/websockets')

diff --git a/dev-python/websockets/Manifest b/dev-python/websockets/Manifest
new file mode 100644
index 000000000000..1309f9fbaca0
--- /dev/null
+++ b/dev-python/websockets/Manifest
@@ -0,0 +1 @@
+DIST websockets-16.0.gh.tar.gz 458014 BLAKE2B 409323f84f919064f758ad06bccf526d1aafac7aee791b9fd35908081ad13cbd252ca49cefbfdc870e5526da82e641750ee46f0103e53c10f0e9b35f9483982f SHA512 ed0bfe6e6402c1504680e9afcb7478e06a5f1af6c0761e35a9a6192569b59c5cce5d0a9f0aaea35922e499a3968dba409cb8d398829e9dff6466db5cb5b98b98
diff --git a/dev-python/websockets/metadata.xml b/dev-python/websockets/metadata.xml
new file mode 100644
index 000000000000..2eb3ff3ed987
--- /dev/null
+++ b/dev-python/websockets/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>games@gentoo.org</email>
+    <name>Gentoo Games Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="cpe">cpe:/a:websockets_project:websockets</remote-id>
+  </upstream>
+  <use>
+    <flag name="native-extensions">Compiles native C extensions</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/websockets/websockets-16.0.ebuild b/dev-python/websockets/websockets-16.0.ebuild
new file mode 100644
index 000000000000..a2cb723326ce
--- /dev/null
+++ b/dev-python/websockets/websockets-16.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library for building WebSocket servers and clients in Python"
+HOMEPAGE="
+	https://websockets.readthedocs.io/
+	https://github.com/python-websockets/websockets/
+	https://pypi.org/project/websockets/
+"
+# tests are missing pypi sdist, as of 16.0
+SRC_URI="
+	https://github.com/python-websockets/websockets/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	if use native-extensions && [[ ${EPYTHON} != pypy3 ]] ; then
+		local -x BUILD_EXTENSION=yes
+	else
+		local -x BUILD_EXTENSION=no
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires DNS access
+		# https://bugs.gentoo.org/909567
+		tests/legacy/test_client_server.py::ClientServerTests::test_explicit_host_port
+		tests/legacy/test_client_server.py::SecureClientServerTests::test_explicit_host_port
+		# TODO
+		tests/asyncio/test_server.py::ServerTests::test_close_server_keeps_handlers_running
+	)
+
+	local EPYTEST_PLUGINS=( pytest-rerunfailures )
+	epytest tests -p rerunfailures --reruns=10 --reruns-delay=2
+}
-- 
cgit v1.3