From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/vector/vector-1.8.0.ebuild | 50 +++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/vector/vector-1.8.0.ebuild

(limited to 'dev-python/vector/vector-1.8.0.ebuild')

diff --git a/dev-python/vector/vector-1.8.0.ebuild b/dev-python/vector/vector-1.8.0.ebuild
new file mode 100644
index 000000000000..ba7e2779a1b7
--- /dev/null
+++ b/dev-python/vector/vector-1.8.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+PYPI_VERIFY_REPO=https://github.com/scikit-hep/vector
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="Vector classes and utilities"
+HOMEPAGE="
+	https://github.com/scikit-hep/vector/
+	https://pypi.org/project/vector/
+	https://vector.readthedocs.io/
+	https://doi.org/10.5281/zenodo.7054478
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/numpy-1.19.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/awkward[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# no module named papermill
+	tests/test_notebooks.py
+	# testing for exact (not mathematical) equality against sympy
+	# which changes without being wrong...
+	tests/compute/sympy/lorentz/
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature "awkward array support" dev-python/awkward
+	optfeature "sympy support" dev-python/sympy
+}
-- 
cgit v1.3.1