From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/vdirsyncer/Manifest                 |  1 +
 dev-python/vdirsyncer/metadata.xml             | 13 +++++
 dev-python/vdirsyncer/vdirsyncer-0.20.0.ebuild | 69 ++++++++++++++++++++++++++
 3 files changed, 83 insertions(+)
 create mode 100644 dev-python/vdirsyncer/Manifest
 create mode 100644 dev-python/vdirsyncer/metadata.xml
 create mode 100644 dev-python/vdirsyncer/vdirsyncer-0.20.0.ebuild

(limited to 'dev-python/vdirsyncer')

diff --git a/dev-python/vdirsyncer/Manifest b/dev-python/vdirsyncer/Manifest
new file mode 100644
index 000000000000..f154cfb80fbc
--- /dev/null
+++ b/dev-python/vdirsyncer/Manifest
@@ -0,0 +1 @@
+DIST vdirsyncer-0.20.0.tar.gz 126633 BLAKE2B 4d9c984d18eddcee4dea2fe29b76060ce1ca51cff23a6f188fed12d848a7e544102333808d584fcf342faf08fa792f54e0ce997d0a3ca846c6cf9741a21a2c9a SHA512 8499440ce8ba036d40f5bbff9d7cadb485be8bb2419d1fbad947f244259dabba9f2527ffff24298f697dd10e6ccd39155ea9547a480c584f64da0eadb993dad7
diff --git a/dev-python/vdirsyncer/metadata.xml b/dev-python/vdirsyncer/metadata.xml
new file mode 100644
index 000000000000..579a93c0d5bb
--- /dev/null
+++ b/dev-python/vdirsyncer/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>amynka@gentoo.org</email>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/vdirsyncer/vdirsyncer-0.20.0.ebuild b/dev-python/vdirsyncer/vdirsyncer-0.20.0.ebuild
new file mode 100644
index 000000000000..037e247c667b
--- /dev/null
+++ b/dev-python/vdirsyncer/vdirsyncer-0.20.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 pypi systemd
+
+DESCRIPTION="Synchronize calendars and contacts"
+HOMEPAGE="
+	https://github.com/pimutils/vdirsyncer/
+	https://pypi.org/project/vdirsyncer/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	>=dev-python/click-log-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/aiostream-0.4.3[${PYTHON_USEDEP}]
+	dev-python/aiohttp-oauthlib[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aioresponses[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( AUTHORS.rst CHANGELOG.rst CONTRIBUTING.rst README.rst config.example )
+
+EPYTEST_PLUGINS=( hypothesis pytest-{asyncio,httpserver} )
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# skip tests needing servers running
+	local -x DAV_SERVER=skip
+	local -x REMOTESTORAGE_SERVER=skip
+	# pytest dies hard if the envvars do not have any value...
+	local -x CI=false
+	local -x DETERMINISTIC_TESTS=false
+
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/system/utils/test_main.py::test_request_ssl
+	)
+
+	epytest -o addopts=
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	systemd_douserunit contrib/vdirsyncer.{service,timer}
+}
-- 
cgit v1.3