From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/textx/Manifest           |  1 +
 dev-python/textx/metadata.xml       | 13 ++++++++
 dev-python/textx/textx-4.3.0.ebuild | 60 +++++++++++++++++++++++++++++++++++++
 3 files changed, 74 insertions(+)
 create mode 100644 dev-python/textx/Manifest
 create mode 100644 dev-python/textx/metadata.xml
 create mode 100644 dev-python/textx/textx-4.3.0.ebuild

(limited to 'dev-python/textx')

diff --git a/dev-python/textx/Manifest b/dev-python/textx/Manifest
new file mode 100644
index 000000000000..373758100fab
--- /dev/null
+++ b/dev-python/textx/Manifest
@@ -0,0 +1 @@
+DIST textX-4.3.0.gh.tar.gz 2228585 BLAKE2B 5693a3304d16c45d5048999fffb3a4954ca7102b79e23f4c8186bcca5a7629931db61ca666be6cb022da05e8299a756656f7aa58e0ef0ac72a5c00a605bbf2dc SHA512 602ffed8be2b333eb9cb53d4af4e03dfdac615d5491d3c146a90d7fcada1109f0384af5f98f99656f6d8c6ca1022e1f8d7d735cfaa30690509b88f7075317031
diff --git a/dev-python/textx/metadata.xml b/dev-python/textx/metadata.xml
new file mode 100644
index 000000000000..31b17c9369c5
--- /dev/null
+++ b/dev-python/textx/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>zmedico@gentoo.org</email>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/textx/textx-4.3.0.ebuild b/dev-python/textx/textx-4.3.0.ebuild
new file mode 100644
index 000000000000..b74f27684b63
--- /dev/null
+++ b/dev-python/textx/textx-4.3.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P=textX-${PV}
+DESCRIPTION="Meta-language for DSL implementation inspired by Xtext"
+HOMEPAGE="
+	https://pypi.org/project/textX/
+	https://github.com/textX/textX/
+"
+SRC_URI="
+	https://github.com/textX/textX/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/arpeggio-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Update the shebang
+	sed -e "s:install/usr/bin/${EPYTHON}:test/usr/bin/${EPYTHON}:" \
+		-i "${BUILD_DIR}"/test/usr/bin/textx || die
+
+	# Install necessary plugins
+	local plugins=(
+		tests/functional/subcommands/example_project
+		tests/functional/registration/projects/*
+	)
+	local p
+	for p in "${plugins[@]}"; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest tests/functional
+}
-- 
cgit v1.3