From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/testtools/testtools-2.9.1.ebuild | 44 +++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-python/testtools/testtools-2.9.1.ebuild

(limited to 'dev-python/testtools/testtools-2.9.1.ebuild')

diff --git a/dev-python/testtools/testtools-2.9.1.ebuild b/dev-python/testtools/testtools-2.9.1.ebuild
new file mode 100644
index 000000000000..78f7159d6547
--- /dev/null
+++ b/dev-python/testtools/testtools-2.9.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/testing-cabal/testtools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Extensions to the Python standard library unit testing framework"
+HOMEPAGE="
+	https://github.com/testing-cabal/testtools/
+	https://pypi.org/project/testtools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-2.0.0[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testresources[${PYTHON_USEDEP}]
+		dev-python/twisted[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc
+
+python_test() {
+	if ! has_version "dev-python/twisted[${PYTHON_USEDEP}]"; then
+		sed -i -e '/twistedsupport/d' tests/test_suite.py || die
+	fi
+
+	"${EPYTHON}" -m testtools.run tests.test_suite ||
+		die "tests failed under ${EPYTHON}"
+}
-- 
cgit v1.3