From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/tables/Manifest             |  1 +
 dev-python/tables/metadata.xml         | 24 ++++++++++
 dev-python/tables/tables-3.11.1.ebuild | 80 ++++++++++++++++++++++++++++++++++
 3 files changed, 105 insertions(+)
 create mode 100644 dev-python/tables/Manifest
 create mode 100644 dev-python/tables/metadata.xml
 create mode 100644 dev-python/tables/tables-3.11.1.ebuild

(limited to 'dev-python/tables')

diff --git a/dev-python/tables/Manifest b/dev-python/tables/Manifest
new file mode 100644
index 000000000000..42e62d7d4137
--- /dev/null
+++ b/dev-python/tables/Manifest
@@ -0,0 +1 @@
+DIST tables-3.11.1.tar.gz 4790533 BLAKE2B a88a0e117ba9c1dc93e5231a99ebe14cb4c8586c508d37c30105a99097e17c3c87a511430321b75c3f051e2880f5ebdb4fbd9d95e2e68be0b560b54e263a8653 SHA512 4e398a2b481e199a9d9dc0e46787f87fa1b8e01ad0e742c748b7bec814cad610a3cabb9a8ef6ab115596d7240e03f28775bdba724fe03b235531ab3b2f6578d9
diff --git a/dev-python/tables/metadata.xml b/dev-python/tables/metadata.xml
new file mode 100644
index 000000000000..0b3897e0f9a5
--- /dev/null
+++ b/dev-python/tables/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription lang="en">
+  PyTables is a hierarchical database package designed to efficently
+  manage very large amounts of data. PyTables is built on top of the
+  HDF5 library and the NumPy package. It features an object-oriented
+  interface that, combined with natural naming and C-code generated
+  from Pyrex sources, makes it a fast, yet extremely easy to use tool
+  for interactively save and retrieve large amounts of data.
+  </longdescription>
+  <use>
+    <flag name="cpudetection">Enables runtime CPU detection (useful for bindist, compatibility on other CPUs)</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/tables/tables-3.11.1.ebuild b/dev-python/tables/tables-3.11.1.ebuild
new file mode 100644
index 000000000000..f594fea3d4cd
--- /dev/null
+++ b/dev-python/tables/tables-3.11.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 prefix pypi
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="
+	https://www.pytables.org/
+	https://github.com/PyTables/PyTables/
+	https://pypi.org/project/tables/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv ~sparc x86"
+IUSE="+cpudetection examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/bzip2:0=
+	app-arch/lz4:0=
+	>=app-arch/zstd-1.0.0:=
+	>=dev-libs/c-blosc-1.11.1:0=
+	<dev-libs/c-blosc2-3
+	>=dev-libs/c-blosc2-2.11.0:=
+	dev-libs/lzo:2=
+	>=dev-python/numpy-1.19.0:=[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.8.4:=
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numexpr-2.6.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	>=dev-python/cython-3.1[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	rm -r c-blosc/{blosc,internal-complibs} || die
+
+	sed -i -e '/blosc2/d' pyproject.toml || die
+	hprefixify -w '/prefixes =/' setup.py
+
+	# TODO
+	sed -i -e 's:test_write_chunk_filtermask:_&:' \
+		tables/tests/test_direct_chunk.py || die
+
+	export PYTABLES_NO_EMBEDDED_LIBS=1
+	export USE_PKGCONFIG=TRUE
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" tables/tests/test_all.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r contrib examples
+		docompress -x /usr/share/doc/${PF}/{contrib,examples}
+	fi
+}
-- 
cgit v1.3