From a3ceca1b4c0d9bdb550dc23f06ffbb5a8e033bc7 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 16:24:49 -0500
Subject: Adding metadata

---
 dev-python/spyder-kernels/Manifest                 |  1 -
 dev-python/spyder-kernels/metadata.xml             | 17 -----
 .../spyder-kernels/spyder-kernels-3.1.4.ebuild     | 86 ----------------------
 3 files changed, 104 deletions(-)
 delete mode 100644 dev-python/spyder-kernels/Manifest
 delete mode 100644 dev-python/spyder-kernels/metadata.xml
 delete mode 100644 dev-python/spyder-kernels/spyder-kernels-3.1.4.ebuild

(limited to 'dev-python/spyder-kernels')

diff --git a/dev-python/spyder-kernels/Manifest b/dev-python/spyder-kernels/Manifest
deleted file mode 100644
index 98096ee13ddb..000000000000
--- a/dev-python/spyder-kernels/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST spyder-kernels-3.1.4.gh.tar.gz 247046 BLAKE2B 9d31c18d2967326a2d93cb910a7382bedafa79d6d9a67f43495f63385708a4a9ee7eb480e1f5bc6c9d54d5cc03cca687bfddc1e01adc567a28ecae895b7b7af8 SHA512 318e122f45b60dfb64ec85351b77c4e0bce71b76a557161da4b69fc648ba2a985870d239fc85c0d675511e079b9c30ca36fbf1780fc9121b2e7417c10e4e3a24
diff --git a/dev-python/spyder-kernels/metadata.xml b/dev-python/spyder-kernels/metadata.xml
deleted file mode 100644
index f8a3e51131c7..000000000000
--- a/dev-python/spyder-kernels/metadata.xml
+++ /dev/null
@@ -1,17 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-  <upstream>
-    <remote-id type="pypi">spyder-kernels</remote-id>
-    <remote-id type="github">spyder-ide/spyder-kernels</remote-id>
-  </upstream>
-  <stabilize-allarches/>
-  <maintainer type="person">
-    <email>nowa@gentoo.org</email>
-    <name>Nowa Ammerlaan</name>
-  </maintainer>
-  <maintainer type="project">
-    <email>python@gentoo.org</email>
-    <name>Python</name>
-  </maintainer>
-</pkgmetadata>
diff --git a/dev-python/spyder-kernels/spyder-kernels-3.1.4.ebuild b/dev-python/spyder-kernels/spyder-kernels-3.1.4.ebuild
deleted file mode 100644
index 9a4173cea5d9..000000000000
--- a/dev-python/spyder-kernels/spyder-kernels-3.1.4.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1
-
-MY_P=${P/_beta/b}
-DESCRIPTION="Kernels used by spyder on its ipython console"
-HOMEPAGE="
-	https://github.com/spyder-ide/spyder-kernels/
-	https://pypi.org/project/spyder-kernels/
-"
-SRC_URI="https://github.com/spyder-ide/${PN}/archive/refs/tags/v${PV/_beta/b}.tar.gz -> ${MY_P}.gh.tar.gz"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-
-RDEPEND="
-	dev-python/cloudpickle[${PYTHON_USEDEP}]
-	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
-	>=dev-python/ipykernel-6.29.3[${PYTHON_USEDEP}]
-	<dev-python/ipython-10[${PYTHON_USEDEP}]
-	>=dev-python/ipython-9.5.0[${PYTHON_USEDEP}]
-	<dev-python/jupyter-client-9[${PYTHON_USEDEP}]
-	>=dev-python/jupyter-client-7.4.9[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
-	>=dev-python/traitlets-5.14.3[${PYTHON_USEDEP}]
-	>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	test? (
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/django[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/mock[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/h5py[${PYTHON_USEDEP}]
-			dev-python/pandas[${PYTHON_USEDEP}]
-			dev-python/xarray[${PYTHON_USEDEP}]
-		' 'python*')
-	)
-"
-
-EPYTEST_PLUGINS=( anyio pytest-rerunfailures )
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# pydicom only packaged in ::sci at the moment
-		spyder_kernels/utils/tests/test_iofuncs.py::test_load_dicom_files
-
-		# require polars
-		spyder_kernels/console/tests/test_console_kernel.py::test_get_value_with_polars
-		spyder_kernels/utils/tests/test_nsview.py::test_polars_dataframe
-	)
-	local EPYTEST_IGNORE=()
-
-	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
-		EPYTEST_IGNORE+=(
-			# require pandas
-			spyder_kernels/utils/tests/test_nsview.py
-		)
-	fi
-
-	if ! has_version "dev-python/h5py[${PYTHON_USEDEP}]"; then
-		EPYTEST_DESELECT+=(
-			# require hdf5
-			spyder_kernels/utils/tests/test_iofuncs.py::test_save_load_hdf5_files
-			spyder_kernels/utils/tests/test_dochelpers.py
-		)
-	fi
-
-	epytest
-}
-- 
cgit v1.3