From a3ceca1b4c0d9bdb550dc23f06ffbb5a8e033bc7 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 16:24:49 -0500
Subject: Adding metadata

---
 dev-python/rdflib/Manifest            |  1 -
 dev-python/rdflib/metadata.xml        | 13 ------
 dev-python/rdflib/rdflib-7.6.0.ebuild | 76 -----------------------------------
 3 files changed, 90 deletions(-)
 delete mode 100644 dev-python/rdflib/Manifest
 delete mode 100644 dev-python/rdflib/metadata.xml
 delete mode 100644 dev-python/rdflib/rdflib-7.6.0.ebuild

(limited to 'dev-python/rdflib')

diff --git a/dev-python/rdflib/Manifest b/dev-python/rdflib/Manifest
deleted file mode 100644
index 969410525dcd..000000000000
--- a/dev-python/rdflib/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST rdflib-7.6.0.gh.tar.gz 5175542 BLAKE2B d5e9f9ce4bea6c5d52b62b9271cd182368cd81ab90a72c0a356238c1744a0d03c077bed5801add5e7090db5ea3a947e0d6cfa1a4f785a01336d5dc6951951241 SHA512 464fe52d968bd8618cef5ab99c28cb465b9b07287a28049d7e2916c1dac4971187be5794b4007509f875fb28cb0c198fd2e1d9338893ecdd00ed5d0d6865ee98
diff --git a/dev-python/rdflib/metadata.xml b/dev-python/rdflib/metadata.xml
deleted file mode 100644
index b14504590ad4..000000000000
--- a/dev-python/rdflib/metadata.xml
+++ /dev/null
@@ -1,13 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-  <maintainer type="project">
-    <email>python@gentoo.org</email>
-    <name>Python</name>
-  </maintainer>
-  <stabilize-allarches/>
-  <upstream>
-    <remote-id type="pypi">rdflib</remote-id>
-    <remote-id type="github">RDFLib/rdflib</remote-id>
-  </upstream>
-</pkgmetadata>
diff --git a/dev-python/rdflib/rdflib-7.6.0.ebuild b/dev-python/rdflib/rdflib-7.6.0.ebuild
deleted file mode 100644
index b3e2af12b247..000000000000
--- a/dev-python/rdflib/rdflib-7.6.0.ebuild
+++ /dev/null
@@ -1,76 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=poetry
-PYTHON_COMPAT=( python3_{13..14} )
-PYTHON_REQ_USE="sqlite?,threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="RDF library containing a triple store and parser/serializer"
-HOMEPAGE="
-	https://github.com/RDFLib/rdflib/
-	https://pypi.org/project/rdflib/
-"
-# tests removed in 7.1.2
-SRC_URI="
-	https://github.com/RDFLib/rdflib/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
-IUSE="examples sqlite"
-
-RDEPEND="
-	dev-python/html5lib[${PYTHON_USEDEP}]
-	<dev-python/pyparsing-4[${PYTHON_USEDEP}]
-	>=dev-python/pyparsing-3.2.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/requests[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=()
-# (xdist fails to collect)
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	# doctests require internet
-	sed -i -e '/doctest-modules/d' pyproject.toml || die
-
-	# we disable pytest-cov
-	sed -i -e 's@, no_cover: None@@' test/test_misc/test_plugins.py || die
-
-	# allow regular html5lib, html5rdf is a fork with minimal changes:
-	# removing six dep (which is kinda good) and bundling webencodings
-	# (which is horrible)
-	find -name '*.py' -exec sed -i -e 's:html5rdf:html5lib:g' {} + || die
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# tests try to install stuff via pip
-		test/test_misc/test_plugins.py
-		# triggers a GC error (and stack overflow was expected anyway)
-		'test/test_sparql/test_translate_algebra.py::test_roundtrip[test_other__service1]'
-	)
-
-	epytest -m "not webtest and not testcontainer"
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}
-- 
cgit v1.3