From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/python3-xapp/Manifest                  |  1 +
 dev-python/python3-xapp/metadata.xml              | 14 ++++++
 dev-python/python3-xapp/python3-xapp-3.0.2.ebuild | 53 +++++++++++++++++++++++
 3 files changed, 68 insertions(+)
 create mode 100644 dev-python/python3-xapp/Manifest
 create mode 100644 dev-python/python3-xapp/metadata.xml
 create mode 100644 dev-python/python3-xapp/python3-xapp-3.0.2.ebuild

(limited to 'dev-python/python3-xapp')

diff --git a/dev-python/python3-xapp/Manifest b/dev-python/python3-xapp/Manifest
new file mode 100644
index 000000000000..d238a4569cda
--- /dev/null
+++ b/dev-python/python3-xapp/Manifest
@@ -0,0 +1 @@
+DIST python3-xapp-3.0.2.tar.gz 39265 BLAKE2B 33850fdc4e288470af57fa6b5abb27c3984b938ebc80fec4965f0271856a2c239a2ef4f720f31ea013938bdc9022754e114171a98ce80d86e54a5baeafdfab59 SHA512 83e9a3ac6526ffe55543a45f687656cf86e6dc77497610f52012115a8b830e0f8706a82896a0b11b66d5fb26274f06d7fe4d80cd5f9ab6304f513fd2ab2ee2a8
diff --git a/dev-python/python3-xapp/metadata.xml b/dev-python/python3-xapp/metadata.xml
new file mode 100644
index 000000000000..d47e66179ed4
--- /dev/null
+++ b/dev-python/python3-xapp/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>sparky@bluefang-logic.com</email>
+    <name>Matthew Turnbull</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/python3-xapp/python3-xapp-3.0.2.ebuild b/dev-python/python3-xapp/python3-xapp-3.0.2.ebuild
new file mode 100644
index 000000000000..a8f716797a21
--- /dev/null
+++ b/dev-python/python3-xapp/python3-xapp-3.0.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit meson python-r1
+
+DESCRIPTION="Python bindings for x11-libs/xapp"
+HOMEPAGE="https://github.com/linuxmint/python3-xapp"
+SRC_URI="https://github.com/linuxmint/python3-xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~loong ~ppc64 ~riscv x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# There are no tests, and src_test() needs to be overridden
+# using python_foreach_impl otherwise theres an error.
+RESTRICT="test"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		>=x11-libs/xapp-3.2.2[introspection,${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	dev-python/psutil[${PYTHON_USEDEP}]
+	x11-themes/xapp-symbolic-icon-theme
+"
+
+src_configure() {
+	configuring() {
+		meson_src_configure \
+			-Dpython_target="${EPYTHON}"
+	}
+	python_foreach_impl configuring
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_install() {
+	installing() {
+		meson_src_install
+		python_optimize
+	}
+	python_foreach_impl installing
+}
-- 
cgit v1.3.1