From ac4e1bda5b8077042e58f7c6aa8b017f4d1bf465 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sun, 18 Jun 2023 01:06:52 +0000
Subject: Adding metadata

---
 .../python-rtmidi/python-rtmidi-1.5.2.ebuild       | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 dev-python/python-rtmidi/python-rtmidi-1.5.2.ebuild

(limited to 'dev-python/python-rtmidi/python-rtmidi-1.5.2.ebuild')

diff --git a/dev-python/python-rtmidi/python-rtmidi-1.5.2.ebuild b/dev-python/python-rtmidi/python-rtmidi-1.5.2.ebuild
new file mode 100644
index 000000000000..cf7945a5c48e
--- /dev/null
+++ b/dev-python/python-rtmidi/python-rtmidi-1.5.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DOCS_BUILDER="sphinx"
+DOCS_DEPEND="dev-python/myst-parser"
+DOCS_DIR="docs"
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYPI_NO_NORMALIZE=1
+
+inherit distutils-r1 docs pypi
+
+DESCRIPTION="Python bindings for media-libs/rtmidi implemented using Cython"
+HOMEPAGE="
+	https://pypi.org/project/python-rtmidi/
+	https://spotlightkid.github.io/python-rtmidi/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+alsa jack"
+
+# Most of these tests do not play nicely with the sandbox, some only
+# work with exactly the same version of rtmidi as the bundled one, and
+# several fail even with disabled sandbox unless there are actual MIDI
+# I/O devices present.
+RESTRICT="test"
+
+DEPEND="media-libs/rtmidi[alsa?,jack?]"
+RDEPEND="${DEPEND}"
+BDEPEND="<dev-python/cython-2.99[${PYTHON_USEDEP}]
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.1-meson_pure.patch
+	"${FILESDIR}"/${PN}-1.5.1-unbundle_rtmidi.patch
+	"${FILESDIR}"/${PN}-1.5.2-build_backend.patch
+)
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Just in case
+	rm -r src/rtmidi || die
+	rm src/_rtmidi.cpp || die
+
+	# Needed by USE=doc because documentation generation happens in ${S}
+	# but the version.py generated by Meson end up in respective ${BUILD_DIR}s.
+	# The version put in ${S} should be ignored by everything except Sphinx but
+	# just in case, be consistent and generate it unconditionally.
+	sed -e "s|@VERSION@|${PV}|" < rtmidi/version.py.in > rtmidi/version.py || die
+}
+
+python_test() {
+	cd "${T}" || die
+	eunittest "${S}"/tests
+}
-- 
cgit v1.3.1