From 26cb790d5c3144747fa0bf0ee13fc2c41728f304 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 14 Jun 2023 01:25:52 +0000
Subject: Adding metadata

---
 .../python-rtmidi/python-rtmidi-1.5.1.ebuild       | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/python-rtmidi/python-rtmidi-1.5.1.ebuild

(limited to 'dev-python/python-rtmidi/python-rtmidi-1.5.1.ebuild')

diff --git a/dev-python/python-rtmidi/python-rtmidi-1.5.1.ebuild b/dev-python/python-rtmidi/python-rtmidi-1.5.1.ebuild
new file mode 100644
index 000000000000..1b60d97844f1
--- /dev/null
+++ b/dev-python/python-rtmidi/python-rtmidi-1.5.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=meson-python
+PYPI_NO_NORMALIZE=1
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings for media-libs/rtmidi implemented using Cython"
+HOMEPAGE="
+	https://pypi.org/project/python-rtmidi/
+	https://spotlightkid.github.io/python-rtmidi/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+alsa jack"
+
+# Most of these tests do not play nicely with the sandbox, some only
+# work with exactly the same version of rtmidi as the bundled one, and
+# several fail even with disabled sandbox unless there are actual MIDI
+# I/O devices present.
+RESTRICT="test"
+
+DEPEND="media-libs/rtmidi[alsa?,jack?]"
+RDEPEND="${DEPEND}"
+BDEPEND="<dev-python/cython-2.99[${PYTHON_USEDEP}]
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.1-build_backend.patch
+	"${FILESDIR}"/${PN}-1.5.1-unbundle_rtmidi.patch
+)
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Just in case
+	rm -r src/rtmidi || die
+	rm src/_rtmidi.cpp || die
+}
+
+python_test() {
+	cd "${T}" || die
+	eunittest "${S}"/tests
+}
-- 
cgit v1.3.1