From a3ceca1b4c0d9bdb550dc23f06ffbb5a8e033bc7 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 16:24:49 -0500
Subject: Adding metadata

---
 .../python-pkcs11/python-pkcs11-0.9.4.ebuild       | 61 ----------------------
 1 file changed, 61 deletions(-)
 delete mode 100644 dev-python/python-pkcs11/python-pkcs11-0.9.4.ebuild

(limited to 'dev-python/python-pkcs11/python-pkcs11-0.9.4.ebuild')

diff --git a/dev-python/python-pkcs11/python-pkcs11-0.9.4.ebuild b/dev-python/python-pkcs11/python-pkcs11-0.9.4.ebuild
deleted file mode 100644
index 8dc002629cc9..000000000000
--- a/dev-python/python-pkcs11/python-pkcs11-0.9.4.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-DISTUTILS_EXT=1
-PYPI_VERIFY_REPO=https://github.com/pyauth/python-pkcs11
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1 edo pypi
-
-DESCRIPTION="PKCS#11/Cryptoki support for Python"
-HOMEPAGE="
-	https://github.com/pyauth/python-pkcs11/
-	https://pypi.org/project/python-pkcs11/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64"
-
-RDEPEND="
-	dev-python/asn1crypto[${PYTHON_USEDEP}]
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	dev-python/cython[${PYTHON_USEDEP}]
-	dev-python/setuptools-scm[${PYTHON_USEDEP}]
-	test? (
-		dev-libs/openssl
-		dev-libs/softhsm
-		dev-python/cryptography[${PYTHON_USEDEP}]
-		dev-python/parameterized[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=()
-distutils_enable_tests pytest
-distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
-
-src_test() {
-	local -x PKCS11_MODULE="${BROOT}/usr/$(get_libdir)/softhsm/libsofthsm2.so"
-	local -x PKCS11_TOKEN_LABEL="TEST"
-	local -x PKCS11_TOKEN_PIN="1234"
-	local -x PKCS11_TOKEN_SO_PIN="5678"
-
-	mkdir -p "${HOME}/.config/softhsm2" || die
-	cat > "${HOME}/.config/softhsm2/softhsm2.conf" <<- EOF || die "Failed to create config"
-		directories.tokendir = ${T}
-		objectstore.backend = file
-	EOF
-
-	edo softhsm2-util --init-token --free \
-		--label ${PKCS11_TOKEN_LABEL} \
-		--pin ${PKCS11_TOKEN_PIN} \
-		--so-pin ${PKCS11_TOKEN_SO_PIN}
-
-	rm -r pkcs11 || die
-	distutils-r1_src_test
-}
-- 
cgit v1.3.1