From 883618fc7f52a9a37d002ebfe939cced8069fd2b Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Mon, 5 Jan 2026 07:17:23 +0000
Subject: Adding metadata

---
 .../python-pkcs11/python-pkcs11-0.9.3.ebuild       | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/python-pkcs11/python-pkcs11-0.9.3.ebuild

(limited to 'dev-python/python-pkcs11/python-pkcs11-0.9.3.ebuild')

diff --git a/dev-python/python-pkcs11/python-pkcs11-0.9.3.ebuild b/dev-python/python-pkcs11/python-pkcs11-0.9.3.ebuild
new file mode 100644
index 000000000000..4650c1e6e832
--- /dev/null
+++ b/dev-python/python-pkcs11/python-pkcs11-0.9.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 edo pypi
+
+DESCRIPTION="PKCS#11/Cryptoki support for Python"
+HOMEPAGE="
+		https://github.com/pyauth/python-pkcs11
+		https://pypi.org/project/python-pkcs11
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="dev-python/asn1crypto[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+		test? (
+				dev-libs/openssl
+				dev-libs/softhsm
+				dev-python/cryptography[${PYTHON_USEDEP}]
+				dev-python/parameterized[${PYTHON_USEDEP}]
+		)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+
+PATCHES=( "${FILESDIR}/${PN}-0.9.3-refactor-under-src.patch" )
+
+src_test() {
+	local -x PKCS11_MODULE="${BROOT}/usr/$(get_libdir)/softhsm/libsofthsm2.so"
+	local -x PKCS11_TOKEN_LABEL="TEST"
+	local -x PKCS11_TOKEN_PIN="1234"
+	local -x PKCS11_TOKEN_SO_PIN="5678"
+
+	mkdir -p "${HOME}/.config/softhsm2" || die
+	cat > "${HOME}/.config/softhsm2/softhsm2.conf" <<- EOF || die "Failed to create config"
+		directories.tokendir = ${T}
+		objectstore.backend = file
+	EOF
+
+	edo softhsm2-util --init-token --free \
+		--label ${PKCS11_TOKEN_LABEL} \
+		--pin ${PKCS11_TOKEN_PIN} \
+		--so-pin ${PKCS11_TOKEN_SO_PIN}
+
+	distutils-r1_src_test
+}
-- 
cgit v1.3.1