From e1e67a5d95d606250a2ca98dec076ecd6e0062d8 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 4 Jan 2025 18:54:09 +0000
Subject: Adding metadata

---
 dev-python/python-ly/python-ly-0.9.9.ebuild | 48 +++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-python/python-ly/python-ly-0.9.9.ebuild

(limited to 'dev-python/python-ly/python-ly-0.9.9.ebuild')

diff --git a/dev-python/python-ly/python-ly-0.9.9.ebuild b/dev-python/python-ly/python-ly-0.9.9.ebuild
new file mode 100644
index 000000000000..6fad01e609ca
--- /dev/null
+++ b/dev-python/python-ly/python-ly-0.9.9.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Tool and library for manipulating LilyPond files"
+HOMEPAGE="
+	https://github.com/frescobaldi/python-ly/
+	https://pypi.org/project/python-ly/
+"
+SRC_URI="
+	https://github.com/frescobaldi/python-ly/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+# https://github.com/frescobaldi/python-ly/issues/176
+SRC_URI+="
+	test? (
+		https://www.w3.org/2001/03/xml.xsd
+		https://www.w3.org/XML/2008/06/xlink.xsd
+	)
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# https://github.com/frescobaldi/python-ly/issues/176
+	sed -e 's:\(schemaLocation="\).*/\([a-z]*\.xsd"\):\1\2:' \
+		-i tests/musicxml.xsd || die
+	cp "${DISTDIR}"/{xml,xlink}.xsd tests/ || die
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	distutils-r1_src_test
+}
-- 
cgit v1.3.1