From d42db3ed2648023a152ebde11df983ae337f4b51 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 1 Nov 2025 19:06:26 +0000
Subject: Adding metadata

---
 .../python-gnupg/python-gnupg-0.5.5-r1.ebuild      | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/python-gnupg/python-gnupg-0.5.5-r1.ebuild

(limited to 'dev-python/python-gnupg/python-gnupg-0.5.5-r1.ebuild')

diff --git a/dev-python/python-gnupg/python-gnupg-0.5.5-r1.ebuild b/dev-python/python-gnupg/python-gnupg-0.5.5-r1.ebuild
new file mode 100644
index 000000000000..023942b27f6a
--- /dev/null
+++ b/dev-python/python-gnupg/python-gnupg-0.5.5-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="A Python wrapper for GnuPG"
+HOMEPAGE="
+	https://docs.red-dove.com/python-gnupg/
+	https://github.com/vsajip/python-gnupg/
+	https://pypi.org/project/python-gnupg/
+"
+SRC_URI="
+	https://github.com/vsajip/python-gnupg/releases/download/${PV}/${P}.tar.gz
+	verify-sig? (
+		https://github.com/vsajip/python-gnupg/releases/download/${PV}/${P}.tar.gz.asc
+	)
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~sparc x86"
+
+# Need gnupg[nls] for avoiding decode errors and possible hangs
+# w/ e.g. sec-keys/openpgp-keys-gentoo-developers but other pkgs too.
+DEPEND="
+	|| (
+		app-alternatives/gpg[reference]
+		app-alternatives/gpg[freepg(-)]
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	verify-sig? ( sec-keys/openpgp-keys-vinaysajip )
+"
+
+distutils_enable_tests unittest
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/vinaysajip.asc
+
+python_test() {
+	# NO_EXTERNAL_TESTS must be enabled,
+	# to disable tests needing Internet access.
+	NO_EXTERNAL_TESTS=1 eunittest
+}
-- 
cgit v1.3.1