From 0caf09d16d18de997a4fd29f35cf3433aaff3951 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Fri, 23 Aug 2024 17:49:44 +0000
Subject: Adding metadata

---
 .../python-glanceclient-4.7.0.ebuild               | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-python/python-glanceclient/python-glanceclient-4.7.0.ebuild

(limited to 'dev-python/python-glanceclient/python-glanceclient-4.7.0.ebuild')

diff --git a/dev-python/python-glanceclient/python-glanceclient-4.7.0.ebuild b/dev-python/python-glanceclient/python-glanceclient-4.7.0.ebuild
new file mode 100644
index 000000000000..18abc051781d
--- /dev/null
+++ b/dev-python/python-glanceclient/python-glanceclient-4.7.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A client for the OpenStack Glance API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-glanceclient/
+	https://github.com/openstack/python-glanceclient/
+	https://pypi.org/project/python-glanceclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/keystoneauth1-3.6.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-17.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/warlock-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+PATCHES=(
+	# combined patch for urllib3-2 and py3.12 test failures
+	# https://bugs.launchpad.net/python-glanceclient/+bug/2069684
+	# https://bugs.launchpad.net/python-glanceclient/+bug/2069682
+	"${FILESDIR}/${PN}-4.6.0-test.patch"
+
+	# py3.13 added close() to mock_open calls
+	# https://review.opendev.org/c/openstack/python-glanceclient/+/923628
+	"${FILESDIR}/${PN}-4.6.0-test-py3.13.patch"
+)
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b glanceclient/tests/unit
+}
-- 
cgit v1.3.1