From ff03324f0b5c30484659977ecb3a56e73f5856a5 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Wed, 5 Aug 2026 03:04:47 -0500
Subject: Adding metadata

---
 dev-python/python-gammu/python-gammu-3.4.0.ebuild | 59 +++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-python/python-gammu/python-gammu-3.4.0.ebuild

(limited to 'dev-python/python-gammu/python-gammu-3.4.0.ebuild')

diff --git a/dev-python/python-gammu/python-gammu-3.4.0.ebuild b/dev-python/python-gammu/python-gammu-3.4.0.ebuild
new file mode 100644
index 000000000000..221495de491c
--- /dev/null
+++ b/dev-python/python-gammu/python-gammu-3.4.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for Gammu"
+HOMEPAGE="
+	https://wammu.eu/python-gammu/
+	https://github.com/gammu/python-gammu/
+	https://pypi.org/project/python-gammu/
+"
+SRC_URI="
+	https://github.com/gammu/python-gammu/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=app-mobilephone/gammu-1.44.0
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		$(python_gen_impl_dep sqlite)
+		app-mobilephone/gammu[dbi]
+	)
+"
+
+DOCS=( AUTHORS NEWS.rst README.rst )
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	rm -rf gammu || die
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docompress -x /usr/share/doc/${P}/examples
+		dodoc -r examples
+	fi
+}
-- 
cgit v1.3