From 55cf1d4ec4f7fb4b0a03561e8923d7c9972d62a8 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 18 Dec 2024 18:50:29 +0000
Subject: Adding metadata

---
 .../python-engineio/python-engineio-4.11.1.ebuild  | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 dev-python/python-engineio/python-engineio-4.11.1.ebuild

(limited to 'dev-python/python-engineio/python-engineio-4.11.1.ebuild')

diff --git a/dev-python/python-engineio/python-engineio-4.11.1.ebuild b/dev-python/python-engineio/python-engineio-4.11.1.ebuild
new file mode 100644
index 000000000000..5345bcc039c4
--- /dev/null
+++ b/dev-python/python-engineio/python-engineio-4.11.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python implementation of the Engine.IO realtime server"
+HOMEPAGE="
+	https://python-engineio.readthedocs.io/
+	https://github.com/miguelgrinberg/python-engineio/
+	https://pypi.org/project/python-engineio/"
+SRC_URI="
+	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/simple-websocket-0.10.0[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+# Can use eventlet, werkzeug, or gevent, but no tests for werkzeug
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/tornado[${PYTHON_USEDEP}]
+		dev-python/websockets[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# eventlet is masked for removal
+		tests/common/test_async_eventlet.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# also eventlet
+		tests/common/test_server.py::TestServer::test_async_mode_eventlet
+		tests/common/test_server.py::TestServer::test_connect
+		tests/common/test_server.py::TestServer::test_service_task_started
+		tests/common/test_server.py::TestServer::test_upgrades
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio
+}
-- 
cgit v1.3.1