From 5e07081cf4f5afaef79409b430a018b1daec073e Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Fri, 15 May 2026 06:07:52 +0000
Subject: Adding metadata

---
 .../python-distutils-extra-3.3.ebuild              | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 dev-python/python-distutils-extra/python-distutils-extra-3.3.ebuild

(limited to 'dev-python/python-distutils-extra/python-distutils-extra-3.3.ebuild')

diff --git a/dev-python/python-distutils-extra/python-distutils-extra-3.3.ebuild b/dev-python/python-distutils-extra/python-distutils-extra-3.3.ebuild
new file mode 100644
index 000000000000..608ee62c2551
--- /dev/null
+++ b/dev-python/python-distutils-extra/python-distutils-extra-3.3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+MY_P="${PN}-debian-${PV}"
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Gettext support, themed icons and scrollkeeper-based documentation in distutils"
+HOMEPAGE="
+	https://salsa.debian.org/python-team/packages/python-distutils-extra/
+	https://launchpad.net/python-distutils-extra/
+"
+SRC_URI="
+	https://salsa.debian.org/python-team/packages/python-distutils-extra/-/archive/debian/${PV}/${MY_P}.tar.bz2
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DOCS=( doc/{README,FAQ} )
+
+BDEPEND="
+	test? (
+		>=dev-libs/gobject-introspection-1.82.0-r2
+		dev-python/httplib2[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-util/intltool
+	)
+"
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+	"${EPYTHON}" test/auto.py -v || die "Tests fail with ${EPYTHON}"
+}
-- 
cgit v1.3.1