From bfd9c39e4712ebdb442d4ca0673061faed1e70e1 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 05:48:38 -0500
Subject: Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.
---
 dev-python/python-debian/Manifest                  |  1 +
 dev-python/python-debian/metadata.xml              | 16 +++++++
 .../python-debian/python-debian-1.1.0.ebuild       | 54 ++++++++++++++++++++++
 3 files changed, 71 insertions(+)
 create mode 100644 dev-python/python-debian/Manifest
 create mode 100644 dev-python/python-debian/metadata.xml
 create mode 100644 dev-python/python-debian/python-debian-1.1.0.ebuild

(limited to 'dev-python/python-debian')

diff --git a/dev-python/python-debian/Manifest b/dev-python/python-debian/Manifest
new file mode 100644
index 000000000000..e11f66fd46f7
--- /dev/null
+++ b/dev-python/python-debian/Manifest
@@ -0,0 +1 @@
+DIST python-debian_1.1.0.tar.xz 200940 BLAKE2B 24d31e04fc08c43f9b9e4c9ad71eedaa3529f47266eed2610fc9cfd8a2c3ab932bf9570fcc5c49a219189d6a522af92ee8378aa520932d83ec8153463657484b SHA512 e93e8e6b0127a2f78b70c827ae9afec6302daf790315d1d3445d51f0da487768ec134a5173ea2ec75482fdd1da6af0e8fdb9037234a3c35f9b982a49dfbddfcf
diff --git a/dev-python/python-debian/metadata.xml b/dev-python/python-debian/metadata.xml
new file mode 100644
index 000000000000..16fe9c1ceca9
--- /dev/null
+++ b/dev-python/python-debian/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>floppym@gentoo.org</email>
+		<name>Mike Gilbert</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">python-debian</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/python-debian/python-debian-1.1.0.ebuild b/dev-python/python-debian/python-debian-1.1.0.ebuild
new file mode 100644
index 000000000000..2ac3456cfc42
--- /dev/null
+++ b/dev-python/python-debian/python-debian-1.1.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2011-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python modules to work with Debian-related data formats"
+HOMEPAGE="
+	https://salsa.debian.org/python-debian-team/python-debian/
+	https://pypi.org/project/python-debian/
+"
+SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.xz"
+# seriously?
+S=${WORKDIR}/work
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 x86"
+
+RDEPEND="
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		app-arch/dpkg
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# silence false positives
+	rm -rf debian || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_compile_all() {
+	# See debian/rules.
+	"${EPYTHON}" src/debian/doc-debtags > README.debtags || die
+}
+
+python_test() {
+	epytest --doctest-modules
+}
-- 
cgit v1.3.1