From 345fe9eab74ece187aa4fb81823473439093946a Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Fri, 25 Oct 2024 07:55:25 +0000
Subject: Adding metadata

---
 .../python-daemon/python-daemon-3.1.0.ebuild       | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/python-daemon/python-daemon-3.1.0.ebuild

(limited to 'dev-python/python-daemon/python-daemon-3.1.0.ebuild')

diff --git a/dev-python/python-daemon/python-daemon-3.1.0.ebuild b/dev-python/python-daemon/python-daemon-3.1.0.ebuild
new file mode 100644
index 000000000000..62dc8f4ba2f4
--- /dev/null
+++ b/dev-python/python-daemon/python-daemon-3.1.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Library to implement a well-behaved Unix daemon process"
+HOMEPAGE="
+	https://pagure.io/python-daemon/
+	https://pypi.org/project/python-daemon/
+"
+
+# build system and tests use GPL-3.0+ but none of these files are installed
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/lockfile-0.10[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	test? (
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# overengineered logic with NIH deps
+	rm setup.py || die
+	cat > setup.cfg <<-EOF || die
+		[metadata]
+		version = ${PV}
+		description = ${DESCRIPTION}
+		maintainer =
+		long_description =
+	EOF
+
+	# tests for their overengineered setup
+	rm test/test_{setup,util_metadata}.py || die
+}
-- 
cgit v1.3.1