From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/pytest-bdd/Manifest                     |  1 +
 .../files/pytest-bdd-8.1.0-gherkin-bounds.patch    | 12 ++++++
 dev-python/pytest-bdd/metadata.xml                 | 10 +++++
 dev-python/pytest-bdd/pytest-bdd-8.1.0-r1.ebuild   | 50 ++++++++++++++++++++++
 4 files changed, 73 insertions(+)
 create mode 100644 dev-python/pytest-bdd/Manifest
 create mode 100644 dev-python/pytest-bdd/files/pytest-bdd-8.1.0-gherkin-bounds.patch
 create mode 100644 dev-python/pytest-bdd/metadata.xml
 create mode 100644 dev-python/pytest-bdd/pytest-bdd-8.1.0-r1.ebuild

(limited to 'dev-python/pytest-bdd')

diff --git a/dev-python/pytest-bdd/Manifest b/dev-python/pytest-bdd/Manifest
new file mode 100644
index 000000000000..ed6d832096fb
--- /dev/null
+++ b/dev-python/pytest-bdd/Manifest
@@ -0,0 +1 @@
+DIST pytest-bdd-8.1.0.gh.tar.gz 116529 BLAKE2B b282f42dbde9394f37e41682d44352d5895a30e2b88c20c46f8d9344f8069e25e2a7a2b6225ebd34a43b60d2392c7bc515f2ebd94bb26a0d350b7d188dd4d77e SHA512 6b03a509a8026ac242a4446caffc019b264f3528322eab8aa0ca2ce4c099bbc45640d63087a756d0d1d0daacdd2f396f121823ca500cef38391e9313a0f898ab
diff --git a/dev-python/pytest-bdd/files/pytest-bdd-8.1.0-gherkin-bounds.patch b/dev-python/pytest-bdd/files/pytest-bdd-8.1.0-gherkin-bounds.patch
new file mode 100644
index 000000000000..0a1087211c96
--- /dev/null
+++ b/dev-python/pytest-bdd/files/pytest-bdd-8.1.0-gherkin-bounds.patch
@@ -0,0 +1,12 @@
+Unknown how long until next release, and meanwhile `pip check`
+reporting errors has a tendency to break random things.
+
+Backport from:
+https://github.com/pytest-dev/pytest-bdd/commit/8ce79eafa6ac4
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -43,3 +43,3 @@
+ packaging = "*"
+-gherkin-official = "^29.0.0"
++gherkin-official = ">=29.0.0"
+ 
diff --git a/dev-python/pytest-bdd/metadata.xml b/dev-python/pytest-bdd/metadata.xml
new file mode 100644
index 000000000000..5fb88ec82f25
--- /dev/null
+++ b/dev-python/pytest-bdd/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>ionen@gentoo.org</email>
+    <name>Ionen Wolkens</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pytest-bdd/pytest-bdd-8.1.0-r1.ebuild b/dev-python/pytest-bdd/pytest-bdd-8.1.0-r1.ebuild
new file mode 100644
index 000000000000..8bc9fb0f5127
--- /dev/null
+++ b/dev-python/pytest-bdd/pytest-bdd-8.1.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{13..14} )
+inherit distutils-r1
+
+DESCRIPTION="BDD library for the pytest runner"
+HOMEPAGE="https://pytest-bdd.readthedocs.io/"
+SRC_URI="
+	https://github.com/pytest-dev/pytest-bdd/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm64"
+
+RDEPEND="
+	dev-python/gherkin-official[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/parse-type[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/pytest[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=( ${PN} )
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.rst CHANGES.rst README.rst )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gherkin-bounds.patch
+)
+
+src_test() {
+	local -x COLUMNS=80
+
+	local EPYTEST_DESELECT=(
+		# https://github.com/pytest-dev/pytest-bdd/issues/779
+		tests/parser/test_errors.py::test_step_outside_scenario_or_background_error
+	)
+
+	distutils-r1_src_test
+}
-- 
cgit v1.3.1