From a3ceca1b4c0d9bdb550dc23f06ffbb5a8e033bc7 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 16:24:49 -0500
Subject: Adding metadata

---
 dev-python/pycuda/Manifest             |  1 -
 dev-python/pycuda/metadata.xml         | 12 -----
 dev-python/pycuda/pycuda-2024.1.ebuild | 90 ----------------------------------
 3 files changed, 103 deletions(-)
 delete mode 100644 dev-python/pycuda/Manifest
 delete mode 100644 dev-python/pycuda/metadata.xml
 delete mode 100644 dev-python/pycuda/pycuda-2024.1.ebuild

(limited to 'dev-python/pycuda')

diff --git a/dev-python/pycuda/Manifest b/dev-python/pycuda/Manifest
deleted file mode 100644
index dc24e1c75e92..000000000000
--- a/dev-python/pycuda/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST pycuda-2024.1.tar.gz 1683163 BLAKE2B b464f47d86b77d492322f28364756cd25a28a11e6dcc802c9c930fad20de74d217660782f82a2a020753fcbb6000a9d659555be6220c57229226ac7fc118c793 SHA512 70a3f27488077e1176aa26b4bc8785277917cc1884126de45c732f393e5e38224b4c4c67999eb1776c08a930333f718d1af3463154d89291b3294bf303a3c471
diff --git a/dev-python/pycuda/metadata.xml b/dev-python/pycuda/metadata.xml
deleted file mode 100644
index a0f336da0a4a..000000000000
--- a/dev-python/pycuda/metadata.xml
+++ /dev/null
@@ -1,12 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-  <maintainer type="project">
-    <email>sci@gentoo.org</email>
-    <name>Gentoo Science Project</name>
-  </maintainer>
-  <upstream>
-    <remote-id type="pypi">pycuda</remote-id>
-    <remote-id type="github">inducer/pycuda</remote-id>
-  </upstream>
-</pkgmetadata>
diff --git a/dev-python/pycuda/pycuda-2024.1.ebuild b/dev-python/pycuda/pycuda-2024.1.ebuild
deleted file mode 100644
index abba698a2669..000000000000
--- a/dev-python/pycuda/pycuda-2024.1.ebuild
+++ /dev/null
@@ -1,90 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{13..14} )
-inherit cuda distutils-r1 pypi
-
-DESCRIPTION="Python wrapper for NVIDIA CUDA"
-HOMEPAGE="https://mathema.tician.de/software/pycuda/ https://pypi.org/project/pycuda/ https://github.com/inducer/pycuda"
-
-LICENSE="Apache-2.0 MIT"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="examples test"
-
-RDEPEND="
-	dev-libs/boost:=[python,${PYTHON_USEDEP}]
-	dev-python/appdirs[${PYTHON_USEDEP}]
-	dev-python/decorator[${PYTHON_USEDEP}]
-	dev-python/mako[${PYTHON_USEDEP}]
-	dev-python/numpy[${PYTHON_USEDEP}]
-	dev-python/pytools[${PYTHON_USEDEP}]
-	dev-util/nvidia-cuda-toolkit[profiler]
-	x11-drivers/nvidia-drivers
-"
-DEPEND="${RDEPEND}"
-
-# We need write acccess /dev/nvidia0 and /dev/nvidiactl and the portage
-# user is (usually) not in the video group
-RESTRICT="test? ( userpriv ) !test? ( test )"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	cuda_sanitize
-
-	sed "s|\"--preprocess\"|&,\"--compiler-bindir=$(cuda_gccdir)\"|" \
-		-i pycuda/compiler.py || die
-
-	> siteconf.py || die
-
-	distutils-r1_src_prepare
-}
-
-python_configure() {
-	mkdir -p "${BUILD_DIR}" || die
-	cd "${BUILD_DIR}" || die
-
-	local conf=(
-		"${EPYTHON}" "${S}"/configure.py
-		--boost-inc-dir="${ESYSROOT}"/usr/include
-		--boost-lib-dir="${ESYSROOT}"/usr/$(get_libdir)
-		--boost-python-libname=boost_${EPYTHON/./}.so
-		--boost-thread-libname=boost_thread
-		--cuda-inc-dir="${ESYSROOT}"/opt/cuda/include
-		--cuda-root="${ESYSROOT}"/opt/cuda
-		--cudadrv-lib-dir="${ESYSROOT}"/usr/$(get_libdir)
-		--cudart-lib-dir="${ESYSROOT}"/opt/cuda/$(get_libdir)
-	)
-	echo ${conf[*]}
-	"${conf[@]}" || die
-}
-
-python_test() {
-	# we need write access to this to run the tests
-	addwrite /dev/nvidia0
-	addwrite /dev/nvidiactl
-	addwrite /dev/nvidia-uvm
-	addwrite /dev/nvidia-uvm-tools
-
-	EPYTEST_DESELECT=(
-		# needs investigation, perhaps failure is hardware-specific
-		test/test_driver.py::test_pass_cai_array
-		test/test_driver.py::test_pointer_holder_base
-	)
-
-	cd "${T}" || die
-	epytest "${S}"/test
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}
-- 
cgit v1.3