From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/pycdio/Manifest               |  1 +
 dev-python/pycdio/metadata.xml           | 12 +++++++
 dev-python/pycdio/pycdio-2.1.1-r1.ebuild | 58 ++++++++++++++++++++++++++++++++
 3 files changed, 71 insertions(+)
 create mode 100644 dev-python/pycdio/Manifest
 create mode 100644 dev-python/pycdio/metadata.xml
 create mode 100644 dev-python/pycdio/pycdio-2.1.1-r1.ebuild

(limited to 'dev-python/pycdio')

diff --git a/dev-python/pycdio/Manifest b/dev-python/pycdio/Manifest
new file mode 100644
index 000000000000..3b5fdc0a5f1e
--- /dev/null
+++ b/dev-python/pycdio/Manifest
@@ -0,0 +1 @@
+DIST pycdio-2.1.1.tar.gz 246562 BLAKE2B 7dbbf384f9d70aade922172c6dd070229c1ffc65a76a491c45f91ec176bced9af0dc0e08f50f8ad78828273de14166eae886b402f282a10bdad3f8302276ef01 SHA512 4c756b1c2f39332add86e01af129ccb608178306be42c9719c163b6bad0ba4de3916ac477c6866450890e094b14a2689a24e7d19bcf13846330555c2bb1feaa7
diff --git a/dev-python/pycdio/metadata.xml b/dev-python/pycdio/metadata.xml
new file mode 100644
index 000000000000..efce27c611d0
--- /dev/null
+++ b/dev-python/pycdio/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">The pycdio (and libcdio) libraries encapsulate CD-ROM reading and
+		control. Python programs wishing to be oblivious of the OS- and
+		device-dependent properties of a CD-ROM can use this library.</longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/pycdio/pycdio-2.1.1-r1.ebuild b/dev-python/pycdio/pycdio-2.1.1-r1.ebuild
new file mode 100644
index 000000000000..593b9fcdb5c5
--- /dev/null
+++ b/dev-python/pycdio/pycdio-2.1.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python OO interface to libcdio (CD Input and Control library)"
+HOMEPAGE="
+	https://savannah.gnu.org/projects/libcdio/
+	https://github.com/rocky/pycdio/
+	https://pypi.org/project/pycdio/
+"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND="
+	>=dev-libs/libcdio-2.0.0
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-lang/swig
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Remove obsolete sys.path and adjust 'data' paths in examples.
+	sed -i \
+		-e "s:^sys.path.insert.*::" \
+		-e "s:\.\./data:./data:g" \
+		example/*.py || die
+	# https://github.com/rocky/pycdio/pull/5
+	sed -i -e 's:assertEquals:assertEqual:' test/test-*.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest -opython_files='test-*.py'
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.3