From b92800ff808bd9e8bb18292c49e7f11e6b6541df Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Thu, 13 Nov 2025 21:36:47 +0000
Subject: Adding metadata

---
 dev-python/pycairo/pycairo-1.29.0-r1.ebuild | 74 +++++++++++++++++++++++++++++
 dev-python/pycairo/pycairo-1.29.0.ebuild    | 64 -------------------------
 2 files changed, 74 insertions(+), 64 deletions(-)
 create mode 100644 dev-python/pycairo/pycairo-1.29.0-r1.ebuild
 delete mode 100644 dev-python/pycairo/pycairo-1.29.0.ebuild

(limited to 'dev-python/pycairo')

diff --git a/dev-python/pycairo/pycairo-1.29.0-r1.ebuild b/dev-python/pycairo/pycairo-1.29.0-r1.ebuild
new file mode 100644
index 000000000000..3e516ab29025
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.29.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# we aren't using meson-python, as that results in removing .pc file
+# https://bugs.gentoo.org/966038
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit meson distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="
+	https://www.cairographics.org/pycairo/
+	https://github.com/pygobject/pycairo/
+	https://pypi.org/project/pycairo/
+"
+SRC_URI="
+	https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz
+"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="X examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=x11-libs/cairo-1.15.10[svg(+),X?]
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+EPYTEST_PLUGINS=( hypothesis )
+distutils_enable_tests pytest
+
+python_compile() {
+	local emesonargs=(
+		# TODO: move that to the eclass?
+		-Dpython.bytecompile=2
+		-Dtests="$(usex test true false)"
+		-Dno-x11="$(usex X false true)"
+	)
+
+	meson_src_configure
+	meson_src_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	epytest
+}
+
+python_install() {
+	meson_src_install
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pycairo/pycairo-1.29.0.ebuild b/dev-python/pycairo/pycairo-1.29.0.ebuild
deleted file mode 100644
index c3aa5ffee964..000000000000
--- a/dev-python/pycairo/pycairo-1.29.0.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=meson-python
-# TODO: readd 3.13t & 3.14t (requires same in meson-python)
-PYTHON_COMPAT=( python3_{10..14} )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="Python bindings for the cairo library"
-HOMEPAGE="
-	https://www.cairographics.org/pycairo/
-	https://github.com/pygobject/pycairo/
-	https://pypi.org/project/pycairo/
-"
-SRC_URI="
-	https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz
-"
-
-LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
-IUSE="X examples test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=x11-libs/cairo-1.15.10[svg(+),X?]
-"
-DEPEND="
-	${RDEPEND}
-	x11-base/xorg-proto
-"
-BDEPEND="
-	virtual/pkgconfig
-"
-
-distutils_enable_sphinx docs \
-	dev-python/sphinx-rtd-theme
-EPYTEST_PLUGINS=( hypothesis )
-distutils_enable_tests pytest
-
-src_configure() {
-	DISTUTILS_ARGS=(
-		-Dtests="$(usex test true false)"
-		-Dno-x11="$(usex X false true)"
-	)
-}
-
-python_test() {
-	rm -rf cairo || die
-	epytest
-}
-
-python_install_all() {
-	if use examples; then
-		dodoc -r examples
-	fi
-
-	distutils-r1_python_install_all
-}
-- 
cgit v1.3