From 3dcea994f58dfe4db86604be3c5297939916a9fd Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [feature/flatten]" <gitlab@liguros.net>
Date: Wed, 16 Sep 2020 00:26:37 +0000
Subject: Updating liguros repo

---
 .../protobuf-python/protobuf-python-3.13.0.ebuild  | 69 ++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 dev-python/protobuf-python/protobuf-python-3.13.0.ebuild

(limited to 'dev-python/protobuf-python/protobuf-python-3.13.0.ebuild')

diff --git a/dev-python/protobuf-python/protobuf-python-3.13.0.ebuild b/dev-python/protobuf-python/protobuf-python-3.13.0.ebuild
new file mode 100644
index 000000000000..4870905f496f
--- /dev/null
+++ b/dev-python/protobuf-python/protobuf-python-3.13.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2008-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS="manual"
+
+inherit distutils-r1
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/protocolbuffers/protobuf"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="Google's Protocol Buffers - Python bindings"
+HOMEPAGE="https://developers.google.com/protocol-buffers/ https://github.com/protocolbuffers/protobuf"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/protocolbuffers/protobuf/archive/v${PV}.tar.gz -> protobuf-${PV}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/24"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${PYTHON_DEPS}
+	~dev-libs/protobuf-${PV}"
+RDEPEND="${BDEPEND}
+	!<dev-libs/protobuf-3[python(-)]"
+
+S="${WORKDIR}/protobuf-${PV}/python"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_CHECKOUT_DIR="${WORKDIR}/protobuf-${PV}"
+fi
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	sed -e "/^[[:space:]]*setup_requires = \['wheel'\],$/d" -i setup.py || die
+}
+
+python_configure_all() {
+	mydistutilsargs=(--cpp_implementation)
+}
+
+python_compile() {
+	python_is_python3 || local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name "*.pth" -type f -delete || die
+}
-- 
cgit v1.3.1