From a37088132ba08a680bbc5bbce95ce927251b9787 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Fri, 10 Jun 2022 17:12:20 +0000
Subject: Adding metadata

---
 dev-python/openapi-core/openapi-core-0.14.2.ebuild | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-python/openapi-core/openapi-core-0.14.2.ebuild

(limited to 'dev-python/openapi-core/openapi-core-0.14.2.ebuild')

diff --git a/dev-python/openapi-core/openapi-core-0.14.2.ebuild b/dev-python/openapi-core/openapi-core-0.14.2.ebuild
new file mode 100644
index 000000000000..e7a0d56d1c67
--- /dev/null
+++ b/dev-python/openapi-core/openapi-core-0.14.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Client-side and server-side support for the OpenAPI Specification v3"
+HOMEPAGE="
+	https://github.com/p1c2u/openapi-core/
+	https://pypi.org/project/openapi-core/
+"
+SRC_URI="
+	https://github.com/p1c2u/openapi-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/isodate[${PYTHON_USEDEP}]
+	dev-python/dictpath[${PYTHON_USEDEP}]
+	dev-python/openapi-schema-validator[${PYTHON_USEDEP}]
+	dev-python/openapi-spec-validator[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+
+BDEPEND="test? (
+	dev-python/django[${PYTHON_USEDEP}]
+	dev-python/djangorestframework[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/responses[${PYTHON_USEDEP}]
+	dev-python/webob[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# falcon not packaged
+	rm -r tests/integration/contrib/falcon || die
+
+	# Theses tests fail to collect
+	rm tests/integration/validation/test_security_override.py || die
+	rm tests/integration/validation/test_read_only_write_only.py || die
+
+	# There's a problem in the test suite here
+	rm tests/unit/unmarshalling/test_unmarshal.py || die
+	rm tests/integration/contrib/django/test_django_rest_framework_apiview.py || die
+
+	sed -i -e '/--cov/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
-- 
cgit v1.3.1