From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/objgraph/Manifest              |  1 +
 dev-python/objgraph/metadata.xml          | 14 ++++++++
 dev-python/objgraph/objgraph-3.6.2.ebuild | 55 +++++++++++++++++++++++++++++++
 3 files changed, 70 insertions(+)
 create mode 100644 dev-python/objgraph/Manifest
 create mode 100644 dev-python/objgraph/metadata.xml
 create mode 100644 dev-python/objgraph/objgraph-3.6.2.ebuild

(limited to 'dev-python/objgraph')

diff --git a/dev-python/objgraph/Manifest b/dev-python/objgraph/Manifest
new file mode 100644
index 000000000000..eddec17ad646
--- /dev/null
+++ b/dev-python/objgraph/Manifest
@@ -0,0 +1 @@
+DIST objgraph-3.6.2.tar.gz 759524 BLAKE2B 23d1154a613ca417c332871c7905571f48aea4ef6ff24a236e58fdc76d74254490f04b7e50c1ee7fd190864448f4bb83c05127d438d2d72c4bb5c9a0dd247491 SHA512 7a1edaddb6bc7c57d77d8631019c183a198bb570725b71ddc49ee54fc1be8f54471175957899794ff2c51a57fd68ee8b856ced661f7efc1023dd7f5b0f5b714f
diff --git a/dev-python/objgraph/metadata.xml b/dev-python/objgraph/metadata.xml
new file mode 100644
index 000000000000..df800698f9dd
--- /dev/null
+++ b/dev-python/objgraph/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>heroxbd@gentoo.org</email>
+    <name>Benda Xu</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/objgraph/objgraph-3.6.2.ebuild b/dev-python/objgraph/objgraph-3.6.2.ebuild
new file mode 100644
index 000000000000..8674ef13e562
--- /dev/null
+++ b/dev-python/objgraph/objgraph-3.6.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Draws Python object reference graphs with graphviz"
+HOMEPAGE="
+	https://github.com/mgedmin/objgraph/
+	https://pypi.org/project/objgraph/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+IUSE="doc"
+
+RDEPEND="
+	media-gfx/graphviz
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# unhappy about pytest
+		tests.py::AtAddrsTest::test_at_addrs
+	)
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# CPython GC
+				tests.py::ByTypeTest::test_new_garbage
+
+				# repr() mismatch
+				tests.py::StringRepresentationTest::test_short_repr_mocked_instance_method_bound
+				tests.py::StringRepresentationTest::test_short_repr_mocked_instance_method_bound_with_mocked_name
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# TODO: figure out how to run doctests
+	epytest tests.py
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/* )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.3.1