From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/nbval/Manifest            |  1 +
 dev-python/nbval/metadata.xml        | 21 ++++++++++++
 dev-python/nbval/nbval-0.11.0.ebuild | 62 ++++++++++++++++++++++++++++++++++++
 3 files changed, 84 insertions(+)
 create mode 100644 dev-python/nbval/Manifest
 create mode 100644 dev-python/nbval/metadata.xml
 create mode 100644 dev-python/nbval/nbval-0.11.0.ebuild

(limited to 'dev-python/nbval')

diff --git a/dev-python/nbval/Manifest b/dev-python/nbval/Manifest
new file mode 100644
index 000000000000..f91d157a70d6
--- /dev/null
+++ b/dev-python/nbval/Manifest
@@ -0,0 +1 @@
+DIST nbval-0.11.0.tar.gz 62718 BLAKE2B c1f82c1333dadc348dd53008c554a07783ff0031b96b48127adffba47195a0b7f5591531443e24846337806e071ff0fa6b1c66d516feddbc26119a3292fe52fd SHA512 f47cfce7261612e59d61d0f9e4bc51fcc5d0305377f830e09ddd8b4e9854cff801a626431b4014f470457d55824c0424d5fec9d104cd9b0f36adb44fa72db757
diff --git a/dev-python/nbval/metadata.xml b/dev-python/nbval/metadata.xml
new file mode 100644
index 000000000000..7b2be35b4bed
--- /dev/null
+++ b/dev-python/nbval/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <stabilize-allarches />
+  <longdescription>
+		The plugin adds functionality to py.test to recognise and collect Jupyter notebooks.
+		The intended purpose of the tests is to determine whether execution of the stored
+		inputs match the stored outputs of the .ipynb file. Whilst also ensuring that the
+		notebooks are running without errors.
+
+		The tests were designed to ensure that Jupyter notebooks (especially those for reference
+		and documentation), are executing consistently.
+
+		Each cell is taken as a test, a cell that doesn't reproduce the expected output will fail.
+	</longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/nbval/nbval-0.11.0.ebuild b/dev-python/nbval/nbval-0.11.0.ebuild
new file mode 100644
index 000000000000..fac4b55362fe
--- /dev/null
+++ b/dev-python/nbval/nbval-0.11.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A pytest plugin to validate Jupyter notebooks"
+HOMEPAGE="
+	https://github.com/computationalmodelling/nbval/
+	https://pypi.org/project/nbval/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv x86"
+
+RDEPEND="
+	dev-python/coverage[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/jupyter-client[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	doc? (
+		virtual/pandoc
+	)
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/sympy[${PYTHON_USEDEP}]
+		' python3_{10..12})
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx-rtd-theme \
+	dev-python/numpy \
+	dev-python/nbsphinx \
+	dev-python/matplotlib
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Mocker not packaged
+		tests/test_nbdime_reporter.py
+
+		tests/test_coverage.py
+	)
+	local EPYTEST_DESELECT=()
+
+	if ! has_version "dev-python/sympy[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			"tests/test_unit_tests_in_notebooks.py::test_print[${S}/tests/ipynb-test-samples/test-latex-pass-failsbutignoreoutput.ipynb]"
+			"tests/test_unit_tests_in_notebooks.py::test_print[${S}/tests/ipynb-test-samples/test-latex-pass-correctouput.ipynb]"
+		)
+	fi
+
+	PYTHONPATH=. epytest # 895258
+}
-- 
cgit v1.3