From f5ff65e5d8b2105f7a940daed6002b1ea99d2151 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sun, 8 Feb 2026 19:21:01 +0000
Subject: Adding metadata

---
 dev-python/nautilus-python/Manifest                |  1 +
 .../nautilus-python/nautilus-python-4.1.0.ebuild   | 52 ++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 dev-python/nautilus-python/nautilus-python-4.1.0.ebuild

(limited to 'dev-python/nautilus-python')

diff --git a/dev-python/nautilus-python/Manifest b/dev-python/nautilus-python/Manifest
index 8c2e9d658ae1..49097677b478 100644
--- a/dev-python/nautilus-python/Manifest
+++ b/dev-python/nautilus-python/Manifest
@@ -1 +1,2 @@
 DIST nautilus-python-4.0.1.tar.xz 32236 BLAKE2B 822812ac86bbfa9e3978468968ec9291cf2f95ab4954cffeebe62f4d297b5816ad1a59cf04bbc31a146c0858e45509a4b5988789f17e7b76c4221e9c6fb1e285 SHA512 24e64af1c1cb8c70a4ea53bb064baf681d8848b2e8b549f682913a4883260b3f2384f985285d17e03736e414503ab82ea79bade9bcbe482a2cbecbb0a8356cea
+DIST nautilus-python-4.1.0.tar.xz 31700 BLAKE2B 34a15430b67bd8c2fee9ef070b982fd850f4f9f743f48dbceda173a06adcc1ea1801d5704aec462bce9da79088a9da5ef4c63b909f694499f4dd45ae9bf0e4e7 SHA512 410694f37b2bafb22afe21301a86211ada547973a17505b3a3f6f7370e7d22e2a5590c4bdde5b68fa3e1232fd9b4bae4ccf1aa21fc7119eb4d43905fb1747c26
diff --git a/dev-python/nautilus-python/nautilus-python-4.1.0.ebuild b/dev-python/nautilus-python/nautilus-python-4.1.0.ebuild
new file mode 100644
index 000000000000..6591bf5cb1f3
--- /dev/null
+++ b/dev-python/nautilus-python/nautilus-python-4.1.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit gnome2 meson python-single-r1
+
+DESCRIPTION="Python bindings for the Nautilus file manager"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/nautilus-python"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="gtk-doc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Require pygobject:3 and USE=introspection on nautilus for sanity,
+# because no (user) plugins could work without them; meson.build
+# requires pygobject:3 and >=nautilus-43.0
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=gnome-base/nautilus-43.0[introspection]
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( dev-util/gtk-doc )
+	>=dev-build/gtk-doc-am-1.14
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gtk-doc docs)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}/usr/share/doc/${PN}/"* "${ED}/usr/share/doc/${P}" || die
+	rm -d "${ED}/usr/share/doc/${PN}" || die
+
+	# Directory for systemwide extensions
+	keepdir /usr/share/nautilus-python/extensions
+}
-- 
cgit v1.3.1