From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/mpmath/Manifest            |  1 +
 dev-python/mpmath/metadata.xml        | 23 ++++++++++++++
 dev-python/mpmath/mpmath-1.4.1.ebuild | 58 +++++++++++++++++++++++++++++++++++
 3 files changed, 82 insertions(+)
 create mode 100644 dev-python/mpmath/Manifest
 create mode 100644 dev-python/mpmath/metadata.xml
 create mode 100644 dev-python/mpmath/mpmath-1.4.1.ebuild

(limited to 'dev-python/mpmath')

diff --git a/dev-python/mpmath/Manifest b/dev-python/mpmath/Manifest
new file mode 100644
index 000000000000..b37ac1814841
--- /dev/null
+++ b/dev-python/mpmath/Manifest
@@ -0,0 +1 @@
+DIST mpmath-1.4.1.tar.gz 2093211 BLAKE2B e023f23cc37a7670ab55bc803b453c2ab1257c47e1de63eb00809228831936573138355acb1aa6650640ed73fb7ada25aa65d3a35a86c71f236d3748101175c1 SHA512 aef995ece7db9168142d2041e7bad1596713de0de4dcfde1d7ea173cd628edd791335db68bb6d73cda7bece78e42e1fb4c595bac69d084afaca59a6e3a22af16
diff --git a/dev-python/mpmath/metadata.xml b/dev-python/mpmath/metadata.xml
new file mode 100644
index 000000000000..8ac03ee028bd
--- /dev/null
+++ b/dev-python/mpmath/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>grozin@gentoo.org</email>
+    <name>Andrey Grozin</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci-mathematics@gentoo.org</email>
+    <name>Gentoo Mathematics Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <use>
+    <flag name="test-full">
+			Run test suite in full via additional (large) test
+			dependencies, like dev-python/matplotlib.
+		</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/mpmath/mpmath-1.4.1.ebuild b/dev-python/mpmath/mpmath-1.4.1.ebuild
new file mode 100644
index 000000000000..ae9b37594856
--- /dev/null
+++ b/dev-python/mpmath/mpmath-1.4.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_FULLY_TESTED=( pypy3_11 python3_{11..14} )
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python library for arbitrary-precision floating-point arithmetic"
+HOMEPAGE="
+	https://mpmath.org/
+	https://github.com/mpmath/mpmath/
+	https://pypi.org/project/mpmath/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86 ~x64-macos"
+IUSE="test-full"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/gmpy2-2.3[${PYTHON_USEDEP}]
+		' 'python3*')
+		test-full? (
+			$(python_gen_cond_dep '
+				dev-python/matplotlib[${PYTHON_USEDEP}]
+			' "${PYTHON_FULLY_TESTED[@]}")
+		)
+	)
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-timeout )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Slow and often needs a re-run to pass
+	mpmath/tests/test_cli.py::test_bare_console_bare_division
+	mpmath/tests/test_cli.py::test_bare_console_no_bare_division
+	mpmath/tests/test_cli.py::test_bare_console_pretty
+	mpmath/tests/test_cli.py::test_bare_console_without_ipython
+	mpmath/tests/test_cli.py::test_bare_console_wrap_floats
+)
+
+pkg_postinst() {
+	optfeature "gmp support" dev-python/gmpy2
+	optfeature "matplotlib support" dev-python/matplotlib
+}
-- 
cgit v1.3.1