From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/metakernel/Manifest                |  1 +
 dev-python/metakernel/metadata.xml            | 14 ++++++
 dev-python/metakernel/metakernel-1.0.0.ebuild | 63 +++++++++++++++++++++++++++
 3 files changed, 78 insertions(+)
 create mode 100644 dev-python/metakernel/Manifest
 create mode 100644 dev-python/metakernel/metadata.xml
 create mode 100644 dev-python/metakernel/metakernel-1.0.0.ebuild

(limited to 'dev-python/metakernel')

diff --git a/dev-python/metakernel/Manifest b/dev-python/metakernel/Manifest
new file mode 100644
index 000000000000..496f0c414c3a
--- /dev/null
+++ b/dev-python/metakernel/Manifest
@@ -0,0 +1 @@
+DIST metakernel-1.0.0.tar.gz 229742 BLAKE2B 4508337e3679e9b502402569472187d23c61e3622dc79748b13e32d865af28efde2e219264646150eb404fd093a659a656cdb76e4b0881ee0b81574d7fc81513 SHA512 d76b25c1842958503156aee83ae01c15de7dc80acc7ed6fce616bfb93143275ad90284c43b9fb521c4a1a61cef7b8ec69a990ccbbd241cdfd0d4d3c479da8a4b
diff --git a/dev-python/metakernel/metadata.xml b/dev-python/metakernel/metadata.xml
new file mode 100644
index 000000000000..1b7d3d473db4
--- /dev/null
+++ b/dev-python/metakernel/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription>
+    A Jupyter/IPython kernel template which includes core magic
+    functions (including help, command and file path completion,
+    parallel and distributed processing, downloads, and much more).
+  </longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/metakernel/metakernel-1.0.0.ebuild b/dev-python/metakernel/metakernel-1.0.0.ebuild
new file mode 100644
index 000000000000..0777e143c995
--- /dev/null
+++ b/dev-python/metakernel/metakernel-1.0.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Metakernel for Jupyter"
+HOMEPAGE="
+	https://github.com/Calysto/metakernel/
+	https://pypi.org/project/metakernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.22.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.19.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.9.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/ipython-9.0[${PYTHON_USEDEP}]
+		>=dev-python/ipywidgets-8.0.5[${PYTHON_USEDEP}]
+		>=dev-python/jupyter-kernel-test-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.29.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-timeout )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile
+		tests/test_parser.py::test_path_completions
+		# broken by color codes in output
+		# https://github.com/Calysto/metakernel/issues/266
+		tests/test_replwrap.py::REPLWrapTestCase::test_bash
+		# requires starting ipycluster
+		tests/magics/test_parallel_magic.py::test_parallel_magic
+	)
+
+	case ${EPYTHON} in
+		python3.1[34])
+			EPYTEST_DESELECT+=(
+				# "not stdin handler available"
+				tests/test_replwrap.py::REPLWrapTestCase::test_spawn_args
+				tests/test_replwrap.py::REPLWrapTestCase::test_spawn_no_args
+			)
+			;;
+	esac
+
+	epytest
+}
-- 
cgit v1.3