From c6e6588bafac78d585ece24e4dabdf99f3af211d Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Sat, 27 Jun 2026 03:04:42 -0500
Subject: Adding metadata

---
 dev-python/libpass/Manifest             |  1 +
 dev-python/libpass/libpass-1.9.3.ebuild | 62 +++++++++++++++++++++++++++++++++
 dev-python/libpass/metadata.xml         | 18 ++++++++++
 3 files changed, 81 insertions(+)
 create mode 100644 dev-python/libpass/Manifest
 create mode 100644 dev-python/libpass/libpass-1.9.3.ebuild
 create mode 100644 dev-python/libpass/metadata.xml

(limited to 'dev-python/libpass')

diff --git a/dev-python/libpass/Manifest b/dev-python/libpass/Manifest
new file mode 100644
index 000000000000..2d4236e2ca9b
--- /dev/null
+++ b/dev-python/libpass/Manifest
@@ -0,0 +1 @@
+DIST libpass-1.9.3.tar.gz 692901 BLAKE2B b7b19ae4a9e7e2d65062d8d51e11fb8caec1da7bedacf88b9b2114013d2a578e64a5ca195d168982a52f7ca143eea5adbc5b33c955e175b7f2dda07bd93e24a2 SHA512 2581412ed18d3b2953f2679a05ce7158095850fb37e16a744a1c80bd1afbcf2d0852619ff9b06322b38004ff01e0d335cefaecb49cf9552a6a478566067aa0bc
diff --git a/dev-python/libpass/libpass-1.9.3.ebuild b/dev-python/libpass/libpass-1.9.3.ebuild
new file mode 100644
index 000000000000..9e7c6e00e34a
--- /dev/null
+++ b/dev-python/libpass/libpass-1.9.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Fork of passlib, a password hashing framework"
+HOMEPAGE="
+	https://github.com/notypecheck/passlib/
+	https://pypi.org/project/libpass/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~x64-macos"
+IUSE="doc test-rust"
+
+BDEPEND="
+	test? (
+		dev-python/scrypt[${PYTHON_USEDEP}]
+		test-rust? (
+			>=dev-python/bcrypt-3.1.0[${PYTHON_USEDEP}]
+			>=dev-python/cryptography-43.0.1[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# bcrypt now disallows implicit password truncation
+		# https://github.com/notypecheck/passlib/pull/25
+		tests/test_handlers_bcrypt.py::bcrypt_bcrypt_test::test_70_hashes
+		tests/test_handlers_bcrypt.py::bcrypt_bcrypt_test::test_secret_w_truncate_size
+		tests/test_handlers_django.py::django_bcrypt_test::test_secret_w_truncate_size
+
+		# assumes scrypt dep is not installed
+		tests/test_crypto_scrypt.py::BuiltinScryptTest::test_missing_backend
+	)
+
+	# skip fuzzing tests, they are very slow
+	epytest -k "not fuzz_input"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use doc && dodoc docs/{*.rst,requirements.txt,lib/*.rst}
+}
+
+pkg_postinst() {
+	optfeature "Argon2 support" dev-python/argon2-cffi
+	optfeature "bcrypt support" dev-python/bcrypt
+	optfeature "scrypt support" dev-python/scrypt
+	optfeature "Time-based One-Time Password (TOTP) support" dev-python/cryptography
+}
diff --git a/dev-python/libpass/metadata.xml b/dev-python/libpass/metadata.xml
new file mode 100644
index 000000000000..606c1115c64a
--- /dev/null
+++ b/dev-python/libpass/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>prometheanfire@gentoo.org</email>
+    <name>Matthew Thode</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>openstack@gentoo.org</email>
+    <name>Openstack</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3