From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/keyring/Manifest              |  1 +
 dev-python/keyring/keyring-25.7.0.ebuild | 52 ++++++++++++++++++++++++++++++++
 dev-python/keyring/metadata.xml          | 21 +++++++++++++
 3 files changed, 74 insertions(+)
 create mode 100644 dev-python/keyring/Manifest
 create mode 100644 dev-python/keyring/keyring-25.7.0.ebuild
 create mode 100644 dev-python/keyring/metadata.xml

(limited to 'dev-python/keyring')

diff --git a/dev-python/keyring/Manifest b/dev-python/keyring/Manifest
new file mode 100644
index 000000000000..fd8a013d6885
--- /dev/null
+++ b/dev-python/keyring/Manifest
@@ -0,0 +1 @@
+DIST keyring-25.7.0.tar.gz 63516 BLAKE2B eee3fdc919fb0d403c92653b62a644d15ddf3473debb86c577cd6819e32d2cdce60767e2f4af4664efc606f55a07081c5b470333673d906fb938dcc768461ae0 SHA512 24471413c4980c2bde3b4d1e4f8e4e196656f8898882cd5f9f3b3e088561ee4a365a54556c243bc1d0be5e85438113545ff6809791dbe3ed38998984e00227a5
diff --git a/dev-python/keyring/keyring-25.7.0.ebuild b/dev-python/keyring/keyring-25.7.0.ebuild
new file mode 100644
index 000000000000..722f27401ddd
--- /dev/null
+++ b/dev-python/keyring/keyring-25.7.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="
+	https://github.com/jaraco/keyring/
+	https://pypi.org/project/keyring/
+"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/secretstorage-3.2[${PYTHON_USEDEP}]
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/jaraco-context[${PYTHON_USEDEP}]
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+	>=dev-python/jeepney-0.4.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-4.11.4[${PYTHON_USEDEP}]
+	' 3.11)
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=( pyfakefs )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# this test fails if importlib-metadata returns more than one
+		# entry, i.e. when keyring is installed already
+		tests/test_packaging.py::test_entry_point
+	)
+	local EPYTEST_IGNORE=(
+		# apparently does not unlock the keyring properly
+		tests/backends/test_libsecret.py
+		# hangs
+		tests/backends/test_kwallet.py
+	)
+
+	epytest -o addopts=
+}
diff --git a/dev-python/keyring/metadata.xml b/dev-python/keyring/metadata.xml
new file mode 100644
index 000000000000..6e61c003a324
--- /dev/null
+++ b/dev-python/keyring/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>prometheanfire@gentoo.org</email>
+    <name>Matthew Thode</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>openstack@gentoo.org</email>
+    <name>Openstack</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <upstream>
+    <remote-id type="cpe">cpe:/a:python:keyring</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3