From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/ipywidgets/Manifest                |  1 +
 dev-python/ipywidgets/ipywidgets-8.1.8.ebuild | 57 +++++++++++++++++++++++++++
 dev-python/ipywidgets/metadata.xml            | 14 +++++++
 3 files changed, 72 insertions(+)
 create mode 100644 dev-python/ipywidgets/Manifest
 create mode 100644 dev-python/ipywidgets/ipywidgets-8.1.8.ebuild
 create mode 100644 dev-python/ipywidgets/metadata.xml

(limited to 'dev-python/ipywidgets')

diff --git a/dev-python/ipywidgets/Manifest b/dev-python/ipywidgets/Manifest
new file mode 100644
index 000000000000..c42ff0e7bcd9
--- /dev/null
+++ b/dev-python/ipywidgets/Manifest
@@ -0,0 +1 @@
+DIST ipywidgets-8.1.8.tar.gz 116739 BLAKE2B 6de9ec7d8f7ecc6f8b734c4731e0eecdcc19be5238063b061ae851fa7a61a38400fadc0b01f2c8f56d204179b8f9eae43dea37f9096a34d920d4317d30f466cb SHA512 a05fa56a17aefcb62c91816e7bad54dec6f3219f1de8ad3d8dbb7680093f05ee149277d84a4fd77f6c6dfa903e9d8a49330708950ec39c6517cc4d22d385d3da
diff --git a/dev-python/ipywidgets/ipywidgets-8.1.8.ebuild b/dev-python/ipywidgets/ipywidgets-8.1.8.ebuild
new file mode 100644
index 000000000000..4af3e2b471b5
--- /dev/null
+++ b/dev-python/ipywidgets/ipywidgets-8.1.8.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="IPython HTML widgets for Jupyter"
+HOMEPAGE="
+	https://ipywidgets.readthedocs.io/
+	https://github.com/jupyter-widgets/ipywidgets/
+	https://pypi.org/project/ipywidgets/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/ipython-genutils-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/widgetsnbextension-4.0.14[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-widgets-3.0.15[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	>=dev-python/ipython-6.1.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# https://github.com/pypy/pypy/issues/4892
+				ipywidgets/widgets/tests/test_interaction.py::test_interact_noinspect
+			)
+			;;
+	esac
+
+	epytest
+}
diff --git a/dev-python/ipywidgets/metadata.xml b/dev-python/ipywidgets/metadata.xml
new file mode 100644
index 000000000000..b79a884f5527
--- /dev/null
+++ b/dev-python/ipywidgets/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3.1