From e84575c2249ea735f0910278a9e20c4e24016ed9 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sun, 29 May 2022 10:53:53 +0000
Subject: Adding metadata

---
 dev-python/ipython/Manifest              |   2 +-
 dev-python/ipython/ipython-7.31.1.ebuild | 157 ------------------------------
 dev-python/ipython/ipython-8.4.0.ebuild  | 162 +++++++++++++++++++++++++++++++
 3 files changed, 163 insertions(+), 158 deletions(-)
 delete mode 100644 dev-python/ipython/ipython-7.31.1.ebuild
 create mode 100644 dev-python/ipython/ipython-8.4.0.ebuild

(limited to 'dev-python/ipython')

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index d3a1cf86b2ac..b1898af15d71 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,3 +1,3 @@
-DIST ipython-7.31.1.tar.gz 5156314 BLAKE2B e6528c9d3920078918180c4c2fae5d0ac20cd377e012691fee4c0cfa6c3056c739efc1ab9cc6231f55034d70619e501ff30e31b929bd5f1f623c89075abfb02d SHA512 7bd1378f7b2bd2146d8c2cf15c958b08f286b0163ca3e267bcd92c3f988d2d20cf48fd6e3c185eed6d30baceb195aeb0170280900e587c898d0812c4ffdee3a0
 DIST ipython-8.2.0.tar.gz 5400583 BLAKE2B 6af50e671823005b035a8463e65463b06dacb3bf4d43c4d3bd9720d1747ebda8abe3d73a49f59ae0e6e2651035db20bcfa1e82dbb0a73e40b4e2507e63118921 SHA512 0bf93527bcafe5dfbfe034b901dff2f002e0fc732159073f0371263e23784f45eb6c9e3f7f2cb9567e93ea4ee313773f836157afe9d23256e71bc4b2fcac15af
 DIST ipython-8.3.0.tar.gz 5314400 BLAKE2B 8f06dcaf32cea70ba9f19fb218d4ea6ca3e42651da065521133b1c7163f80324244f59b3c4d85039f1aa5ed363acad0dae11615ae4927d6c9a24197cc9640349 SHA512 95a3d50a5cffe9d4ed3f072c7fa8920c96beccdb15a7437836daa5f38f1ba228b4ebc4c3313d4c5016b77ed7d6f3787af727487ea379c9dc3b3de90eafa4d1c3
+DIST ipython-8.4.0.tar.gz 5314601 BLAKE2B 4a5804ad115b45568ddbc0b8fcd181ae0088690ae2d7dda8580588d1e1caa087582a279449142e0144568815270b3a9476893525c0e90320f9ec580a06126d1d SHA512 975915ee64ce6f3fc9bcda383c784759dd8b19151428b10ef92020097718c6e2a9804a00fe02bd541b845eca146c63a672f25ad4f00ec5302b3c61ae0c6935ce
diff --git a/dev-python/ipython/ipython-7.31.1.ebuild b/dev-python/ipython/ipython-7.31.1.ebuild
deleted file mode 100644
index f12f2cdae07b..000000000000
--- a/dev-python/ipython/ipython-7.31.1.ebuild
+++ /dev/null
@@ -1,157 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_SETUPTOOLS=no
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-PYTHON_REQ_USE='readline,sqlite,threads(+)'
-
-inherit distutils-r1 optfeature virtualx
-
-DESCRIPTION="Advanced interactive shell for Python"
-HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/backcall[${PYTHON_USEDEP}]
-	dev-python/decorator[${PYTHON_USEDEP}]
-	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
-	dev-python/pickleshare[${PYTHON_USEDEP}]
-	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
-	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
-	dev-python/pygments[${PYTHON_USEDEP}]
-	dev-python/traitlets[${PYTHON_USEDEP}]
-	matplotlib? (
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
-	)
-"
-
-BDEPEND="
-	test? (
-		app-text/dvipng[truetype]
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
-		dev-python/nbformat[${PYTHON_USEDEP}]
-		dev-python/nose[${PYTHON_USEDEP}]
-		>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/testpath[${PYTHON_USEDEP}]
-	)
-	doc? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
-		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest
-
-RDEPEND+="
-	nbconvert? (
-		dev-python/nbconvert[${PYTHON_USEDEP}]
-	)"
-PDEPEND="
-	notebook? (
-		dev-python/notebook[${PYTHON_USEDEP}]
-		dev-python/ipywidgets[${PYTHON_USEDEP}]
-		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
-	)
-	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
-	smp? (
-		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
-		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
-	)"
-
-PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
-
-DISTUTILS_IN_SOURCE_BUILD=1
-
-python_prepare_all() {
-	# Remove out of date insource files
-	rm IPython/extensions/cythonmagic.py || die
-	rm IPython/extensions/rmagic.py || die
-
-	# Prevent un-needed download during build
-	if use doc; then
-		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
-	fi
-
-	# Rename the test directory to reduce sys.path pollution
-	# https://github.com/ipython/ipython/issues/12892
-	mv IPython/extensions/{,ipython_}tests || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	if use doc; then
-		emake -C docs html_noapi
-		HTML_DOCS=( docs/build/html/. )
-	fi
-}
-
-python_test() {
-	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
-	local EPYTEST_DESELECT=(
-		# TODO: looks to be a regression due to a newer dep
-		IPython/core/tests/test_oinspect.py::test_class_signature
-		IPython/core/tests/test_oinspect.py::test_render_signature_long
-	)
-	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
-		# TODO
-		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
-		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
-		IPython/core/tests/test_oinspect.py::test_pinfo_docstring_if_detail_and_no_source
-		# fails due to changed argparse output
-		IPython/core/tests/test_magic_arguments.py::test_magic_arguments
-		# py3.10 API incompat, doesn't look important
-		IPython/lib/tests/test_pretty.py::test_pprint_heap_allocated_type
-	)
-	virtx epytest
-}
-
-python_install() {
-	distutils-r1_python_install
-
-	# Create ipythonX.Y symlinks.
-	# TODO:
-	# 1. do we want them for pypy? No.  pypy has no numpy
-	# 2. handle it in the eclass instead (use _python_ln_rel).
-	# With pypy not an option the dosym becomes unconditional
-	dosym ../lib/python-exec/${EPYTHON}/ipython \
-		/usr/bin/ipython${EPYTHON#python}
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-}
-
-pkg_postinst() {
-	optfeature "sympyprinting" dev-python/sympy
-	optfeature "cythonmagic" dev-python/cython
-	optfeature "%lprun magic command" dev-python/line_profiler
-	optfeature "%mprun magic command" dev-python/memory_profiler
-
-	if use nbconvert; then
-		if ! has_version app-text/pandoc ; then
-			einfo "Node.js will be used to convert notebooks to other formats"
-			einfo "like HTML. Support for that is still experimental. If you"
-			einfo "encounter any problems, please use app-text/pandoc instead."
-		fi
-	fi
-}
diff --git a/dev-python/ipython/ipython-8.4.0.ebuild b/dev-python/ipython/ipython-8.4.0.ebuild
new file mode 100644
index 000000000000..ef5f9e4f2c54
--- /dev/null
+++ b/dev-python/ipython/ipython-8.4.0.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/stack_data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# Internet
+		IPython/core/display.py::IPython.core.display.Image.__init__
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+		# TODO
+		IPython/extensions/ipython_tests/test_autoreload.py::TestAutoreload::test_smoketest_aimport
+		IPython/extensions/ipython_tests/test_autoreload.py::TestAutoreload::test_smoketest_autoreload
+	)
+	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
+		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
+	)
+	# nonfatal implied by virtx
+	nonfatal epytest || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
-- 
cgit v1.3.1