From ecdac123787b96ce6649f0f91da12ea6458cc2b1 Mon Sep 17 00:00:00 2001
From: Palica <palica+gitlab@liguros.net>
Date: Tue, 23 Jun 2020 22:35:08 +0200
Subject: Updating liguros repo

---
 dev-python/ipyparallel/Manifest                    |  2 +
 .../ipyparallel-6.2.3-disable-broken-test.patch    | 28 ++++++++
 dev-python/ipyparallel/ipyparallel-6.2.3.ebuild    | 76 ++++++++++++++++++++++
 dev-python/ipyparallel/ipyparallel-6.3.0.ebuild    | 62 ++++++++++++++++++
 dev-python/ipyparallel/metadata.xml                | 17 +++++
 5 files changed, 185 insertions(+)
 create mode 100644 dev-python/ipyparallel/Manifest
 create mode 100644 dev-python/ipyparallel/files/ipyparallel-6.2.3-disable-broken-test.patch
 create mode 100644 dev-python/ipyparallel/ipyparallel-6.2.3.ebuild
 create mode 100644 dev-python/ipyparallel/ipyparallel-6.3.0.ebuild
 create mode 100644 dev-python/ipyparallel/metadata.xml

(limited to 'dev-python/ipyparallel')

diff --git a/dev-python/ipyparallel/Manifest b/dev-python/ipyparallel/Manifest
new file mode 100644
index 000000000000..abcf93dbc6fc
--- /dev/null
+++ b/dev-python/ipyparallel/Manifest
@@ -0,0 +1,2 @@
+DIST ipyparallel-6.2.3.tar.gz 2371030 BLAKE2B 73f96bbed280def33ae243e592ecf2e298afe92287cf3a7edb966859c38c6dcb1f1a43082ab83907aa00e06d571f4b750df28e6885a1c2d1fd1489fd4472a7fc SHA512 ddf479a7776c2ca9fd37aa5b7dd402c136ce62a479333f5f56dce413649f9b928daed56c173ad5325268eaa58667d611257b20c8269899cc06ae2829f973b4c1
+DIST ipyparallel-6.3.0.tar.gz 2380153 BLAKE2B b8312102e1d2b5fc963491ebe8530e2fd73e9f941f7912fbc72a8db51e7255f5cac95a853d15a57e384926ab1aff27f2a3ad13cc45130a8b612be5dc623538ab SHA512 fe621854b9cc3e5f88aeca2b06b63bb689dd2feee0da451a0a90800d8832f4b44b23bb9a15033029cc33179276f31e982a10fc7540e6d13b04f15d96c348a295
diff --git a/dev-python/ipyparallel/files/ipyparallel-6.2.3-disable-broken-test.patch b/dev-python/ipyparallel/files/ipyparallel-6.2.3-disable-broken-test.patch
new file mode 100644
index 000000000000..b578cd7f73e1
--- /dev/null
+++ b/dev-python/ipyparallel/files/ipyparallel-6.2.3-disable-broken-test.patch
@@ -0,0 +1,28 @@
+diff --git a/ipyparallel/tests/test_util.py b/ipyparallel/tests/test_util.py
+index 06fde46..e685a88 100644
+--- a/ipyparallel/tests/test_util.py
++++ b/ipyparallel/tests/test_util.py
+@@ -3,7 +3,8 @@ from ipyparallel import util
+ from jupyter_client.localinterfaces import localhost, public_ips
+ 
+ 
+-def test_disambiguate_ip():
++# This test is broken in gentoo's testing environment
++def xtest_disambiguate_ip():
+     # garbage in, garbage out
+     public_ip = public_ips()[0]
+     assert util.disambiguate_ip_address('garbage') == 'garbage'
+diff --git a/ipyparallel/tests/test_view.py b/ipyparallel/tests/test_view.py
+index 45cb669..dd335b1 100644
+--- a/ipyparallel/tests/test_view.py
++++ b/ipyparallel/tests/test_view.py
+@@ -823,7 +823,8 @@ class TestView(ClusterTestCase):
+         assert view.apply_sync(find_ipython)
+ 
+     @skip_without('cloudpickle')
+-    def test_use_cloudpickle(self):
++    # Broken on Gentoo
++    def xtest_use_cloudpickle(self):
+         view = self.client[:]
+         view['_a'] = 'engine'
+         sys.modules['__main__']._a = 'client'
diff --git a/dev-python/ipyparallel/ipyparallel-6.2.3.ebuild b/dev-python/ipyparallel/ipyparallel-6.2.3.ebuild
new file mode 100644
index 000000000000..074fd315ca02
--- /dev/null
+++ b/dev-python/ipyparallel/ipyparallel-6.2.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="threads(+)"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Interactive Parallel Computing with IPython"
+HOMEPAGE="https://ipyparallel.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+# About tests and tornado
+# Upstreams claims to work fine with tornado 5, and it's indeed possible to
+# launch a cluster with tornado 5 installed, but tests definitely don't run with
+# tornado 5 installed. Upstreams CI runs with tornado 4. This is why we limit
+# ourselves to <tornado-5 when running tests.
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-14.4.0[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/ipython[test]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		<www-servers/tornado-5
+	)
+	"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.2.3-disable-broken-test.patch"
+)
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	pytest -vs ipyparallel/tests || die
+}
+
+pkg_postinst() {
+	optfeature "Jupyter Notebook integration" dev-python/notebook
+}
diff --git a/dev-python/ipyparallel/ipyparallel-6.3.0.ebuild b/dev-python/ipyparallel/ipyparallel-6.3.0.ebuild
new file mode 100644
index 000000000000..e567a97df1c1
--- /dev/null
+++ b/dev-python/ipyparallel/ipyparallel-6.3.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE="threads(+)"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Interactive Parallel Computing with IPython"
+HOMEPAGE="https://ipyparallel.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+# About tests and tornado
+# Upstreams claims to work fine with tornado 5, and it's indeed possible to
+# launch a cluster with tornado 5 installed, but tests definitely don't run with
+# tornado 5 installed. Upstreams CI runs with tornado 4. This is why we limit
+# ourselves to <tornado-5 when running tests.
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-14.4.0[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+	"
+BDEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/ipython[test]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	"
+
+distutils_enable_sphinx docs/source
+distutils_enable_tests pytest
+
+src_prepare() {
+	# TODO: investigate
+	sed -e 's:test_unicode:_&:' \
+		-e 's:test_temp_flags:_&:' \
+		-i ipyparallel/tests/test_view.py || die
+
+	distutils-r1_src_prepare
+}
+
+pkg_postinst() {
+	optfeature "Jupyter Notebook integration" dev-python/notebook
+}
diff --git a/dev-python/ipyparallel/metadata.xml b/dev-python/ipyparallel/metadata.xml
new file mode 100644
index 000000000000..65e452cb691e
--- /dev/null
+++ b/dev-python/ipyparallel/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">ipyparallel</remote-id>
+    <remote-id type="github">ipython/ipyparallel</remote-id>
+  </upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>
-- 
cgit v1.3.1