From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/frozenlist/Manifest                |  1 +
 dev-python/frozenlist/frozenlist-1.8.0.ebuild | 53 +++++++++++++++++++++++++++
 dev-python/frozenlist/metadata.xml            | 14 +++++++
 3 files changed, 68 insertions(+)
 create mode 100644 dev-python/frozenlist/Manifest
 create mode 100644 dev-python/frozenlist/frozenlist-1.8.0.ebuild
 create mode 100644 dev-python/frozenlist/metadata.xml

(limited to 'dev-python/frozenlist')

diff --git a/dev-python/frozenlist/Manifest b/dev-python/frozenlist/Manifest
new file mode 100644
index 000000000000..41028ae73937
--- /dev/null
+++ b/dev-python/frozenlist/Manifest
@@ -0,0 +1 @@
+DIST frozenlist-1.8.0.gh.tar.gz 51937 BLAKE2B e7f3948385cea658ec0fd3a348092aa17b74f01c0ab3bb712a90353032ae011636fa5089da57495640f8b9ab8668f49b227576aba973e6521d7224bcf9914825 SHA512 dc1ae0bdec79a02de81adfbf280c26126dc5c8cdae22eb80b28d1ca65445f945cd71ce9bfdbf03d5aef8f36af13862c57ce5d1f159d0177889f403b871744118
diff --git a/dev-python/frozenlist/frozenlist-1.8.0.ebuild b/dev-python/frozenlist/frozenlist-1.8.0.ebuild
new file mode 100644
index 000000000000..7352ddcecaf8
--- /dev/null
+++ b/dev-python/frozenlist/frozenlist-1.8.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A list-like structure which implements collections.abc.MutableSequence"
+HOMEPAGE="
+	https://pypi.org/project/frozenlist/
+	https://github.com/aio-libs/frozenlist/
+"
+SRC_URI="
+	https://github.com/aio-libs/frozenlist/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	native-extensions? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_compile() {
+	# pypy is not using the C extension
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		local -x FROZENLIST_NO_EXTENSIONS=1
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	rm -rf frozenlist || die
+	epytest -o addopts=
+}
diff --git a/dev-python/frozenlist/metadata.xml b/dev-python/frozenlist/metadata.xml
new file mode 100644
index 000000000000..41c540b8ee15
--- /dev/null
+++ b/dev-python/frozenlist/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+  </maintainer>
+  <use>
+    <flag name="native-extensions">
+			Compile native C extensions (speedups, instead of using Python
+			fallback code).
+		</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3